adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld.org.pl>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  13
  14 BEGIN {
  15         preamble = 1            # Is it part of preamble? Default - yes
  16         boc = 4                 # Beggining of %changelog
  17         bod = 0                 # Beggining of %description
  18         tw = 70                 # Descriptions width
  19
  20         # If variable removed, then 1 (for removing it from export)
  21         removed["LDFLAGS"] = 0
  22         removed["CFLAGS"] = 0
  23         removed["CXXFLAGS"] = 0
  24
  25         # If 1, we are inside of comment block (started with /^#%/)
  26         comment_block = 0
  27
  28         # File with rpm groups
  29         "rpm --eval %_sourcedir" | getline groups_file
  30         groups_file = groups_file "/rpm.groups"
  31         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  32
  33         # Temporary file for changelog section
  34         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  35
  36         # Load rpm macros
  37         "rpm --eval %_prefix"   | getline prefix
  38         "rpm --eval %_bindir"   | getline bindir
  39         "rpm --eval %_sbindir"  | getline sbindir
  40         "rpm --eval %_libdir"   | getline libdir
  41         "rpm --eval %_sysconfdir" | getline sysconfdir
  42         "rpm --eval %_datadir"  | getline datadir
  43         "rpm --eval %_includedir" | getline includedir
  44         "rpm --eval %_mandir"   | getline mandir
  45         "rpm --eval %_infodir"  | getline infodir
  46 }
  47
  48 # There should be a comment with CVS keywords on the first line of file.
  49 FNR == 1 {
  50         if (!/# \$Revision:/)   # If this line is already OK?
  51                 print "# $" "Revision:$, " "$" "Date:$" # No
  52         else {
  53                 print $0                                # Yes
  54                 next            # It is enough for first line
  55         }
  56 }
  57
  58 # If the latest line matched /%files/
  59 defattr == 1 {
  60         if ($0 !~ /defattr/)    # If no %defattr
  61                 print "%defattr(644,root,root,755)"     # Add it
  62         else
  63                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  64         defattr = 0
  65 }
  66
  67 # Comments
  68 /^#/ && (description == 0) {
  69         if (/This file does not like to be adapterized!/) {
  70                 print                   # print this message
  71                 while (getline)         # print the rest of spec as it is
  72                         print
  73                 do_not_touch_anything = 1 # do not touch anything in END()
  74                 exit 0
  75         }
  76
  77         # Generally, comments are printed without touching
  78         sub(/[ \t]+$/, "")
  79         print $0
  80         next
  81 }
  82
  83 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
  84 /^%define/ {
  85         if ($2 == "_applnkdir")
  86                 next
  87         if ($2 == "date")
  88                 date = 1
  89 }
  90
  91 ################
  92 # %description #
  93 ################
  94 /^%description/, (/^%[a-z]+/ && !/^%description/) {
  95         preamble = 0
  96
  97         if (/^%description/) {
  98                 bod++
  99                 format_line = ""
 100                 format_indent = -1
 101         }
 102
 103         # Format description
 104         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 105                 if (/^[ \t]*$/) {
 106                         format_flush(format_line, format_indent)
 107                         print ""
 108                         format_line = ""
 109                         format_indent = -1
 110                 } else if (/^[ \t]*[-\*][ \t]*/) {
 111                         format_flush(format_line, format_indent)
 112                         match($0, /^[ \t]*/)
 113                         format_indent = RLENGTH
 114                         match($0, /^[ \t]*[-\*][ \t]/)
 115                         format_line = substr($0, RLENGTH)
 116                 } else
 117                         format_line = format_line " " $0
 118                 next
 119         }
 120
 121         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 122                 if (NF > 3 && $2 == "-l") {
 123                         ll = $1
 124                         for (i = 4; i <= NF; i++)
 125                                 ll = ll " " $i
 126                         $0 = ll " -l " $3
 127                 }
 128                 format_flush(format_line, format_indent)
 129                 if (bod == 2) {
 130                         bod = 1
 131                         description = 1
 132                 } else {
 133                         bod = 0
 134                         description = 0
 135                 }
 136         } else
 137                 description = 1
 138 }
 139
 140 #########
 141 # %prep #
 142 #########
 143 /^%prep/, (/^%[a-z]+$/ && !/^%prep/) {
 144         preamble = 0
 145
 146         # Add '-q' to %setup
 147         if (/^%setup/ && !/-q/)
 148                 sub(/^%setup/, "%setup -q")
 149 }
 150
 151 ##########
 152 # %build #
 153 ##########
 154 /^%build/, (/^%[a-z]+$/ && !/^%build/) {
 155         preamble = 0
 156
 157         use_macros()
 158
 159         if (/^automake$/)
 160                 sub(/$/, " -a -c")
 161
 162         if (/LDFLAGS/) {
 163                 if (/LDFLAGS="-s"/) {
 164                         removed["LDFLAGS"] = 1
 165                         next
 166                 } else {
 167                         split($0, tmp, "LDFLAGS=")
 168                         count = split(tmp[2], flags, "\"")
 169                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 170                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 171                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 172                                 for (i = 2; i < count; i++)
 173                                         $0 = $0 flags[i] "\""
 174                         }
 175                 }
 176         }
 177
 178         if (/CFLAGS=/)
 179                 if (cflags("CFLAGS") == 0)
 180                         next
 181
 182         if (/CXXFLAGS=/)
 183                 if (cflags("CXXFLAGS") == 0)
 184                         next
 185
 186         if (/^export /) {
 187                 if (removed["LDFLAGS"])
 188                         sub(" LDFLAGS", "")
 189                 if (removed["CFLAGS"])
 190                         sub(" CFLAGS", "")
 191                 if (removed["CXXFLAGS"])
 192                         sub(" CXXFLAGS", "")
 193                 # Is there still something?
 194                 if (/^export[ ]*$/)
 195                         next
 196         }
 197
 198 }
 199
 200 ##########
 201 # %clean #
 202 ##########
 203 /^%clean/, (/^%[a-z]+$/ && !/^%clean/) {
 204         did_clean = 1
 205 }
 206
 207 ############
 208 # %install #
 209 ############
 210 /^%install/, (/^%[a-z]+$/ && !/^%install/) {
 211
 212         preamble = 0
 213
 214         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 215                 did_rmroot=1
 216                 print "rm -rf $RPM_BUILD_ROOT"
 217                 next
 218         }
 219
 220         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 221                 print "rm -rf $RPM_BUILD_ROOT"
 222                 did_rmroot=1
 223         }
 224
 225         use_macros()
 226
 227         # 'install -d' instead 'mkdir -p'
 228         if (/mkdir -p/)
 229                 sub(/mkdir -p/, "install -d")
 230
 231         # 'install' instead 'cp -p'
 232         if (/cp -p/)
 233                 sub(/cp -p/, "install")
 234
 235         # No '-u root' or '-g root' for 'install'
 236         if (/^install/ && /-[ug][ \t]*root/)
 237                 gsub(/-[ug][ \t]*root /, "")
 238
 239         if (/^install/ && /-m[ \t]*644/)
 240                 gsub(/-m[ \t]*644 /, "")
 241
 242         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 243         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 244                 next
 245
 246         # No lines contain 'chmod' if it sets the modes to '644'
 247         if ($1 ~ /chmod/ && $2 ~ /644/)
 248                 next
 249 }
 250
 251 ##########
 252 # %files #
 253 ##########
 254 /^%files/, (/^%[a-z \-]+$/ && !/^%files/) {
 255         preamble = 0
 256
 257         if ($0 ~ /^%files/)
 258                 defattr = 1
 259
 260         use_macros()
 261         use_files_macros()
 262 }
 263
 264 ##############
 265 # %changelog #
 266 ##############
 267 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 268         preamble = 0
 269         has_changelog = 1
 270         skip = 0
 271         # There should be some CVS keywords on the first line of %changelog.
 272         if (boc == 3) {
 273                 if (!/PLD Team/)
 274                         print "* %{date} PLD Team <feedback@pld-linux.org>" > changelog_file
 275                 else
 276                         skip = 1
 277                 boc = 2
 278         }
 279         if (boc == 2 && !skip) {
 280                 if (!/All persons listed below/) {
 281                         printf "All persons listed below can be reached at " > changelog_file
 282                         print "<cvs_login>@pld-linux.org\n" > changelog_file
 283                 } else
 284                         skip = 1
 285                 boc = 1
 286         }
 287         if (boc == 1 && !skip) {
 288                 if (!/^$/) {
 289                         if (!/\$.*Log:.*\$/)
 290                                 print "$" "Log:$" > changelog_file
 291                         boc = 0
 292                 }
 293         }
 294         # Define date macro.
 295         if (boc == 4) {
 296                 if (date == 0) {
 297                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 298                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 299                         date = 1
 300                 }
 301                 boc = 3
 302         }
 303
 304         sub(/[ \t]+$/, "")
 305         if (!/^%[a-z]+$/ || /changelog/)
 306                 print > changelog_file
 307         else
 308                 print
 309         next
 310 }
 311
 312 ###########
 313 # SCRIPTS #
 314 ###########
 315 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 316         preamble = 0
 317 }
 318 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 319         preamble = 0
 320 }
 321 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 322         preamble = 0
 323 }
 324 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 325         preamble = 0
 326 }
 327
 328 #############
 329 # PREAMBLES #
 330 #############
 331 preamble == 1 {
 332         # There should not be a space after the name of field
 333         # and before the colon.
 334         sub(/[ \t]*:/, ":")
 335
 336         field = tolower($1)
 337         fieldnlower = $1
 338         if (field ~ /group(\([^)]+\)):/)
 339                 next
 340         if (field ~ /group:/) {
 341                 format_preamble()
 342                 sub(/^Utilities\//,"Applications/",$2)
 343                 sub(/^Games/,"Applications/Games",$2)
 344                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 345                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 346                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 347                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 348                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 349                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 350                 sub(/^Shells/,"Applications/Shells",$2)
 351
 352                 sub(/^[^ \t]*[ \t]*/,"")
 353                 Grupa = $0
 354
 355                 print "Group:\t\t" Grupa
 356                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 357                         x11 = 1
 358
 359                 byl_plik_z_grupami = 0
 360                 byl_opis_grupy = 0
 361                 while ((getline linia_grup < groups_file) > 0) {
 362                         byl_plik_z_grupami = 1
 363                         if (linia_grup == Grupa) {
 364                                 byl_opis_grupy = 1
 365                                 break
 366                         }
 367                 }
 368
 369                 if (!byl_plik_z_grupami)
 370                         print "######\t\t" groups_file ": no such file"
 371                 else if (!byl_opis_grupy)
 372                         print "######\t\t" "Unknown group!"
 373
 374                 close(groups_file)
 375                 next
 376         }
 377
 378         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 379                 next
 380
 381         if (field ~ /buildroot:/)
 382                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 383
 384         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 385         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 386                 $1 = "License:"
 387
 388         if (field ~ /name:/)
 389                 name = $2
 390
 391         if (field ~ /version:/)
 392                 version = $2
 393
 394         if (field ~ /serial:/)
 395                 $1 = "Epoch:"
 396
 397         # Use %{name} and %{version} in the filenames in "Source:"
 398         if (field ~ /^source/ || field ~ /patch/) {
 399                 n = split($2, url, /\//)
 400                 if (url[n] ~ /\.gz$/) {
 401                         url[n+1] = ".gz" url[n+1]
 402                         sub(/\.gz$/,"",url[n])
 403                 }
 404                 if (url[n] ~ /\.zip$/) {
 405                         url[n+1] = ".zip" url[n+1]
 406                         sub(/\.zip$/,"",url[n])
 407                 }
 408                 if (url[n] ~ /\.tar$/) {
 409                         url[n+1] = ".tar" url[n+1]
 410                         sub(/\.tar$/,"",url[n])
 411                 }
 412                 if (url[n] ~ /\.patch$/) {
 413                         url[n+1] = ".patch" url[n+1]
 414                         sub(/\.patch$/,"",url[n])
 415                 }
 416                 if (url[n] ~ /\.bz2$/) {
 417                         url[n+1] = ".bz2" url[n+1]
 418                         sub(/\.bz2$/,"",url[n])
 419                 }
 420                 if (url[n] ~ /\.logrotate$/) {
 421                         url[n+1] = ".logrotate" url[n+1]
 422                         sub(/\.logrotate$/,"",url[n])
 423                 }
 424                 if (url[n] ~ /\.pamd$/) {
 425                         url[n+1] = ".pamd" url[n+1]
 426                         sub(/\.pamd$/,"",url[n])
 427                 }
 428
 429                 filename = url[n]
 430                 url[n] = fixedsub(name, "%{name}", url[n])
 431                 if (field ~ /source/)
 432                         url[n] = fixedsub(version, "%{version}", url[n])
 433                 $2 = fixedsub(filename, url[n], $2)
 434         }
 435
 436         if (field ~ /^source:/)
 437                 $1 = "Source0:"
 438
 439         if (field ~ /patch:/)
 440                 $1 = "Patch0:"
 441
 442         format_preamble()
 443
 444         if ($1 ~ /%define/) {
 445                 # Do not add %define of _prefix if it already is.
 446                 if ($2 ~ /^_prefix/) {
 447                         sub("^"prefix, $3, bindir)
 448                         sub("^"prefix, $3, sbindir)
 449                         sub("^"prefix, $3, libdir)
 450                         sub("^"prefix, $3, datadir)
 451                         sub("^"prefix, $3, includedir)
 452                         prefix = $3
 453                 }
 454                 if ($2 ~ /_bindir/ && !/_sbindir/)
 455                         bindir = $3
 456                 if ($2 ~ /_sbindir/)
 457                         sbindir = $3
 458                 if ($2 ~ /_libdir/)
 459                         libdir = $3
 460                 if ($2 ~ /_sysconfdir/)
 461                         sysconfdir = $3
 462                 if ($2 ~ /_datadir/)
 463                         datadir = $3
 464                 if ($2 ~ /_includedir/)
 465                         includedir = $3
 466                 if ($2 ~ /_mandir/)
 467                         mandir = $3
 468                 if ($2 ~ /_infodir/)
 469                         infodir = $3
 470         }
 471 }
 472
 473
 474 # main() ;-)
 475 {
 476         preamble = 1
 477
 478         sub(/[ \t]+$/, "")
 479         print
 480 }
 481
 482
 483 END {
 484         if (do_not_touch_anything)
 485                 exit 0
 486
 487         close(changelog_file)
 488         while ((getline < changelog_file) > 0)
 489                 print
 490         system("rm -f " changelog_file)
 491
 492         if (did_clean == 0) {
 493                 print ""
 494                 print "%clean"
 495                 print "rm -rf $RPM_BUILD_ROOT"
 496         }
 497
 498         if (date == 0) {
 499                 print ""
 500                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 501         }
 502
 503         if (has_changelog == 0)
 504                 print "%changelog"
 505
 506         if (boc > 2)
 507                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 508         if (boc > 1) {
 509                 printf "All persons listed below can be reached at "
 510                 print "<cvs_login>@pld-linux.org\n"
 511         }
 512         if (boc > 0)
 513                 print "$" "Log:$"
 514 }
 515
 516 function fixedsub(s1,s2,t, ind) {
 517 # substitutes fixed strings (not regexps)
 518         if (ind = index(t,s1))
 519                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 520         return t
 521 }
 522
 523 # There should be one or two tabs after the colon.
 524 function format_preamble()
 525 {
 526         sub(/:[ \t]*/, ":")
 527         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 528                 if (RLENGTH < 8)
 529                         sub(/:/, ":\t\t")
 530                 else
 531                         sub(/:/, ":\t")
 532         }
 533 }
 534
 535 # Replace directly specified directories with macros
 536 function use_macros()
 537 {
 538         gsub(bindir, "%{_bindir}")
 539         gsub("%{prefix}/bin", "%{_bindir}")
 540         if(prefix"/bin" == bindir)
 541                 gsub("%{_prefix}/bin", "%{_bindir}")
 542
 543         for (c = 1; c <= NF; c++) {
 544                 if ($c ~ sbindir "/fix-info-dir")
 545                         continue;
 546                 gsub(sbindir, "%{_sbindir}", $c)
 547         }
 548
 549         gsub("%{prefix}/sbin", "%{_sbindir}")
 550         if(prefix"/sbin" == sbindir)
 551                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 552
 553         for (c = 1; c <= NF; c++) {
 554                 if ($c ~ sysconfdir "/{?cron.")
 555                         continue;
 556                 if ($c ~ sysconfdir "/{?crontab.d")
 557                         continue;
 558                 if ($c ~ sysconfdir "/{?logrotate.d")
 559                         continue;
 560                 if ($c ~ sysconfdir "/{?pam.d")
 561                         continue;
 562                 if ($c ~ sysconfdir "/{?profile.d")
 563                         continue;
 564                 if ($c ~ sysconfdir "/{?rc.d")
 565                         continue;
 566                 if ($c ~ sysconfdir "/{?security")
 567                         continue;
 568                 if ($c ~ sysconfdir "/{?skel")
 569                         continue;
 570                 if ($c ~ sysconfdir "/{?sysconfig")
 571                         continue;
 572                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 573         }
 574
 575         gsub(datadir, "%{_datadir}")
 576         gsub("%{prefix}/share", "%{_datadir}")
 577         if(prefix"/share" == datadir)
 578                 gsub("%{_prefix}/share", "%{_datadir}")
 579
 580         gsub(includedir, "%{_includedir}")
 581         gsub("%{prefix}/include", "%{_includedir}")
 582         if(prefix"/include" == includedir)
 583                 gsub("%{_prefix}/include", "%{_includedir}")
 584
 585         gsub(mandir, "%{_mandir}")
 586         if ($0 !~ "%{_datadir}/manual")
 587                 gsub("%{_datadir}/man", "%{_mandir}")
 588         gsub("%{_prefix}/share/man", "%{_mandir}")
 589         gsub("%{prefix}/share/man", "%{_mandir}")
 590         gsub("%{prefix}/man", "%{_mandir}")
 591         gsub("%{_prefix}/man", "%{_mandir}")
 592
 593         gsub(infodir, "%{_infodir}")
 594         gsub("%{prefix}/info", "%{_infodir}")
 595         gsub("%{_prefix}/info", "%{_infodir}")
 596
 597         if (prefix !~ "/X11R6") {
 598                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 599         }
 600
 601         if (prefix != "/") {
 602                 for (c = 1; c <= NF; c++) {
 603                         if ($c ~ prefix "/sbin/fix-info-dir")
 604                                 continue;
 605                         gsub(prefix, "%{_prefix}", $c)
 606                 }
 607                 gsub("%{prefix}", "%{_prefix}")
 608         }
 609
 610         gsub("%{PACKAGE_VERSION}", "%{version}")
 611         gsub("%{PACKAGE_NAME}", "%{name}")
 612
 613         # we can move files between the dirs below
 614         if ($0 !~ "%{_applnkdir}") {
 615                 gsub("%{_datadir}/gnome/apps", "%{_applnkdir}")
 616         }
 617
 618         gsub("^make$", "%{__make}")
 619         gsub("^make ", "%{__make} ")
 620
 621         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 622         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 623 }
 624
 625 function use_files_macros()
 626 {
 627         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 628         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 629 }
 630
 631 function fill(ch, n, i) {
 632         for (i = 0; i < n; i++)
 633                 printf("%c", ch)
 634 }
 635
 636 function format_flush(line, indent, newline, word, first_word) {
 637         first_word = 1
 638         if (format_indent == -1)
 639                 newline = ""
 640         else
 641                 newline = fill(" ", format_indent) "- "
 642
 643         while (match(line, /[^\t ]+/)) {
 644                 word = substr(line, RSTART, RLENGTH)
 645                 if (length(newline) + length(word) + 1 > tw) {
 646                         print newline
 647
 648                         if (format_indent == -1)
 649                                 newline = ""
 650                         else
 651                                 newline = fill(" ", format_indent + 2)
 652                         first_word = 1
 653                 }
 654
 655                 if (first_word) {
 656                         newline = newline word
 657                         first_word = 0
 658                 } else
 659                         newline = newline " " word
 660
 661                 line = substr(line, RSTART + RLENGTH)
 662         }
 663         if (newline ~ /[^\t ]/) {
 664                 print newline
 665         }
 666 }
 667
 668 function cflags(var)
 669 {
 670         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
 671                 removed[var] = 1
 672                 return 0
 673         }
 674
 675         if (!/!\?debug/)
 676                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
 677         return 1
 678 }
 679