adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD Linux.
   4 #
   5 # Copyright (C) 1999-2005 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld-linux.org>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 #       Elan Ruusamä¤e <glen@pld-linux.org>
  13 #
  14 # See cvs log adapter{,.awk} for list of contributors
  15 #
  16 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  17
  18 # TODO
  19 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  20 # - add "-nc" option to skip CVS interaction
  21 # - sort Summary(XX)
  22 # - sort Requires, BuildRequires
  23 # - check if %description (lang=C) contains 8bit
  24 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  25
  26 BEGIN {
  27         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun"
  28         SECTIONS = "^%(" RPM_SECTIONS ")"
  29
  30         PREAMBLE_TAGS = "(Summary|Name|Version|Release|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|PreReq|(Build)?Requires)"
  31
  32         preamble = 1            # Is it part of preamble? Default - yes
  33         boc = 4                 # Beginning of %changelog
  34         bod = 0                 # Beginning of %description
  35         tw = 70                 # Descriptions width
  36
  37         b_idx = 0               # index of BR/R arrays
  38
  39         # If variable removed, then 1 (for removing it from export)
  40         removed["LDFLAGS"] = 0
  41         removed["CFLAGS"] = 0
  42         removed["CXXFLAGS"] = 0
  43
  44         # get cvsaddress for changelog section
  45         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  46         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  47         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  48
  49         # If 1, we are inside of comment block (started with /^#%/)
  50         comment_block = 0
  51
  52         # File with rpm groups
  53         "rpm --eval %_sourcedir" | getline groups_file
  54         groups_file = groups_file "/rpm.groups"
  55         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  56
  57         # Temporary file for changelog section
  58         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  59
  60         # Load rpm macros
  61         "rpm --eval %_prefix"   | getline prefix
  62         "rpm --eval %_bindir"   | getline bindir
  63         "rpm --eval %_sbindir"  | getline sbindir
  64         "rpm --eval %_libdir"   | getline libdir
  65         "rpm --eval %_sysconfdir" | getline sysconfdir
  66         "rpm --eval %_datadir"  | getline datadir
  67         "rpm --eval %_includedir" | getline includedir
  68         "rpm --eval %_mandir"   | getline mandir
  69         "rpm --eval %_infodir"  | getline infodir
  70         "rpm --eval %_examplesdir"      | getline examplesdir
  71         "rpm --eval %_defaultdocdir"    | getline docdir
  72
  73         "rpm --eval %perl_sitearch" | getline perl_sitearch
  74         "rpm --eval %perl_archlib" | getline perl_archlib
  75         "rpm --eval %perl_privlib" | getline perl_privlib
  76         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  77         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  78         "rpm --eval %perl_sitelib" | getline perl_sitelib
  79
  80         "rpm --eval %py_sitescriptdir" | getline py_sitescriptdir
  81 }
  82
  83 # There should be a comment with CVS keywords on the first line of file.
  84 FNR == 1 {
  85         if (!/# \$Revision:/)   # If this line is already OK?
  86                 print "# $" "Revision:$, " "$" "Date:$" # No
  87         else {
  88                 print $0                                # Yes
  89                 next            # It is enough for first line
  90         }
  91 }
  92
  93 # If the latest line matched /%files/
  94 defattr == 1 {
  95         if (ENVIRON["SKIP_DEFATTR"] != 1) {
  96                 if ($0 !~ /defattr/) {  # If no %defattr
  97                         print "%defattr(644,root,root,755)"     # Add it
  98                 } else {
  99                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 100                 }
 101         }
 102         defattr = 0
 103 }
 104
 105 function b_makekey(a, b,        s) {
 106         s = a "" b;
 107         # kill bcond
 108     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 109
 110         # kill commented out items
 111     gsub(/^#[ \t]*/, "", s);
 112
 113         # force order
 114     gsub(/^Summary\(/, "11Summary(", s);
 115     gsub(/^Summary/, "10Summary", s);
 116     gsub(/^Name/, "2Name", s);
 117     gsub(/^Version/, "3Version", s);
 118     gsub(/^Release/, "4Release", s);
 119     gsub(/^License/, "5License", s);
 120     gsub(/^Group/, "6Group", s);
 121     gsub(/^URL/, "7URL", s);
 122
 123     gsub(/^BuildRequires/, "B1BuildRequires", s);
 124     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 125     gsub(/^Provides/, "X1Provides", s);
 126     gsub(/^Obsoletes/, "X2Obsoletes", s);
 127     gsub(/^Conflicts/, "X3Conflicts", s);
 128     gsub(/^BuildArch/, "X4BuildArch", s);
 129     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 130     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 131     gsub(/^BuildRoot/, "X9BuildRoot", s);
 132
 133 #       printf("%s -> %s\n", a""b, s);
 134         return s;
 135 }
 136
 137 # Comments
 138 /^#/ && (description == 0) {
 139         if (/This file does not like to be adapterized!/) {
 140                 print                   # print this message
 141                 while (getline)         # print the rest of spec as it is
 142                         print
 143                 do_not_touch_anything = 1 # do not touch anything in END()
 144                 exit 0
 145         }
 146
 147         # Generally, comments are printed without touching
 148         sub(/[ \t]+$/, "")
 149
 150         if (/Source.*md5/) {
 151                 print $0
 152                 next
 153         }
 154 }
 155
 156 /^%define/ {
 157         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 158         if ($2 == "_applnkdir") {
 159                 next
 160         }
 161         if ($2 == "date") {
 162                 date = 1
 163         }
 164
 165         # Do not add %define of _prefix if it already is.
 166         if ($2 ~ /^_prefix/) {
 167                 sub("^"prefix, $3, bindir)
 168                 sub("^"prefix, $3, sbindir)
 169                 sub("^"prefix, $3, libdir)
 170                 sub("^"prefix, $3, datadir)
 171                 sub("^"prefix, $3, includedir)
 172                 prefix = $3
 173         }
 174
 175         if ($2 ~ /_bindir/ && !/_sbindir/)
 176                 bindir = $3
 177         if ($2 ~ /_sbindir/)
 178                 sbindir = $3
 179         if ($2 ~ /_libdir/)
 180                 libdir = $3
 181         if ($2 ~ /_sysconfdir/) {
 182                 if ($3 ~ /^%\(/) {
 183                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 184                         sysconfdir = "%%%%%%%%%%%%%%"
 185                 } else {
 186                         sysconfdir = $3
 187                 }
 188         }
 189         if ($2 ~ /_datadir/)
 190                 datadir = $3
 191         if ($2 ~ /_includedir/)
 192                 includedir = $3
 193         if ($2 ~ /_mandir/)
 194                 mandir = $3
 195         if ($2 ~ /_infodir/)
 196                 infodir = $3
 197         if ($2 ~ /_docdir/)
 198                 docdir = $3
 199
 200         # version related macros
 201         if ($2 ~ /^_beta$/)
 202                 _beta = $3
 203         if ($2 ~ /^_rc$/)
 204                 _rc = $3
 205         if ($2 ~ /^_snap$/)
 206                 _snap = $3
 207
 208         # these are used usually when adapterizing external spec
 209         if ($2 ~ /^name$/)
 210                 name = $3
 211         if ($2 ~ /^version$/)
 212                 version = $3
 213         if ($2 ~ /^release$/)
 214                 release = $3
 215
 216         if ($2 ~ /^mod_name$/)
 217                 mod_name = $3
 218
 219         # do nothing further, otherwise adapter thinks we're at preamble
 220         print
 221         next
 222 }
 223
 224 # Obsolete
 225 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 226         next
 227 }
 228
 229 ################
 230 # %description #
 231 ################
 232 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 233         preamble = 0
 234
 235         if (/^%description/) {
 236                 bod++
 237                 format_line = ""
 238                 format_indent = -1
 239         }
 240
 241         # Format description
 242         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 243                 if (/^[ \t]*$/) {
 244                         format_flush(format_line, format_indent)
 245                         print ""
 246                         format_line = ""
 247                         format_indent = -1
 248                 } else if (/^[ \t]*[-\*][ \t]*/) {
 249                         format_flush(format_line, format_indent)
 250                         match($0, /^[ \t]*/)
 251                         format_indent = RLENGTH
 252                         match($0, /^[ \t]*[-\*][ \t]/)
 253                         format_line = substr($0, RLENGTH)
 254                 } else
 255                         format_line = format_line " " $0
 256                 next
 257         }
 258
 259         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 260                 if (NF > 3 && $2 == "-l") {
 261                         ll = $1
 262                         for (i = 4; i <= NF; i++)
 263                                 ll = ll " " $i
 264                         $0 = ll " -l " $3
 265                 }
 266                 format_flush(format_line, format_indent)
 267                 if (bod == 2) {
 268                         bod = 1
 269                         description = 1
 270                 } else {
 271                         bod = 0
 272                         description = 0
 273                 }
 274         } else
 275                 description = 1
 276 }
 277
 278 #########
 279 # %prep #
 280 #########
 281 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 282         preamble = 0
 283
 284         use_macros()
 285
 286         # Add '-q' to %setup
 287         if (/^%setup/ && !/-q/) {
 288                 sub(/^%setup/, "%setup -q")
 289         }
 290
 291         if (/^%setup/) {
 292                 $0 = fixedsub(name, "%{name}", $0);
 293                 $0 = fixedsub(version, "%{version}", $0);
 294                 if (_beta) {
 295                         $0 = fixedsub(_beta, "%{_beta}", $0);
 296                 }
 297                 if (_rc) {
 298                         $0 = fixedsub(_rc, "%{_rc}", $0);
 299                 }
 300                 if (_snap) {
 301                         $0 = fixedsub(_snap, "%{_snap}", $0);
 302                 }
 303         }
 304
 305         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 306                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 307         }
 308
 309         # invalid in %prep
 310         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 311 }
 312
 313 ##########
 314 # %build #
 315 ##########
 316 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 317         preamble = 0
 318
 319         use_macros()
 320
 321         if (/^automake$/)
 322                 sub(/$/, " -a -c")
 323
 324         if (/LDFLAGS/) {
 325                 if (/LDFLAGS="-s"/) {
 326                         removed["LDFLAGS"] = 1
 327                         next
 328                 } else {
 329                         split($0, tmp, "LDFLAGS=")
 330                         count = split(tmp[2], flags, "\"")
 331                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 332                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 333                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 334                                 for (i = 2; i < count; i++)
 335                                         $0 = $0 flags[i] "\""
 336                         }
 337                 }
 338         }
 339
 340         if (/CFLAGS=/)
 341                 if (cflags("CFLAGS") == 0)
 342                         next
 343
 344         if (/CXXFLAGS=/)
 345                 if (cflags("CXXFLAGS") == 0)
 346                         next
 347
 348         if (/^export /) {
 349                 if (removed["LDFLAGS"])
 350                         sub(" LDFLAGS", "")
 351                 if (removed["CFLAGS"])
 352                         sub(" CFLAGS", "")
 353                 if (removed["CXXFLAGS"])
 354                         sub(" CXXFLAGS", "")
 355                 # Is there still something?
 356                 if (/^export[ ]*$/)
 357                         next
 358         }
 359
 360         # quote CC
 361         if (/CC=%{__cc} /) {
 362                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 363         }
 364
 365         # use PLD Linux macros
 366         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 367         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 368         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 369         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 370         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 371
 372         sub(/^aclocal$/, "%{__aclocal}");
 373         sub(/^autoheader$/, "%{__autoheader}");
 374         sub(/^autoconf$/, "%{__autoconf}");
 375         sub(/^automake$/, "%{__automake}");
 376
 377         # atrpms
 378         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 379         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 380 }
 381
 382 ##########
 383 # %clean #
 384 ##########
 385 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 386         did_clean = 1
 387
 388         # prevent next section header like "%post -p /sbin/ldconfig" being adapterized
 389         if (!/^%/) {
 390                 use_macros()
 391         }
 392 }
 393
 394 ############
 395 # %install #
 396 ############
 397 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 398
 399         preamble = 0
 400
 401         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 402                 did_rmroot=1
 403                 print "rm -rf $RPM_BUILD_ROOT"
 404                 next
 405         }
 406
 407         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 408                 print "rm -rf $RPM_BUILD_ROOT"
 409                 did_rmroot=1
 410         }
 411
 412         use_macros()
 413
 414         # 'install -d' instead 'mkdir -p'
 415         if (/mkdir -p/)
 416                 sub(/mkdir -p/, "install -d")
 417
 418         # 'install' instead 'cp -p'
 419         if (/cp -p\b/)
 420                 sub(/cp -p/, "install")
 421
 422         # No '-u root' or '-g root' for 'install'
 423         if (/^install/ && /-[ug][ \t]*root/)
 424                 gsub(/-[ug][ \t]*root /, "")
 425
 426         if (/^install/ && /-m[ \t]*[0-9]+/)
 427                 gsub(/-m[ \t]*[0-9]+ /, "")
 428
 429         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 430         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 431                 next
 432
 433         # No lines contain 'chmod' if it sets the modes to '644'
 434         if ($1 ~ /chmod/ && $2 ~ /644/)
 435                 next
 436
 437         # foreign rpms
 438         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
 439         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
 440
 441         # atrpms
 442         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 443 }
 444
 445 ##########
 446 # %files #
 447 ##########
 448 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 449         preamble = 0
 450
 451         if ($0 ~ /^%files/)
 452                 defattr = 1
 453
 454         use_files_macros()
 455 }
 456
 457 ##############
 458 # %changelog #
 459 ##############
 460 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 461         preamble = 0
 462         has_changelog = 1
 463         skip = 0
 464         # There should be some CVS keywords on the first line of %changelog.
 465         if (boc == 3) {
 466                 if ($0 !~ _cvsmailfeedback)
 467                         print "* %{date} " _cvsmailfeedback > changelog_file
 468                 else
 469                         skip = 1
 470                 boc = 2
 471         }
 472         if (boc == 2 && !skip) {
 473                 if (!/All persons listed below/) {
 474                         printf "All persons listed below can be reached at " > changelog_file
 475                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 476                 } else
 477                         skip = 1
 478                 boc = 1
 479         }
 480         if (boc == 1 && !skip) {
 481                 if (!/^$/) {
 482                         if (!/\$.*Log:.*\$/)
 483                                 print "$" "Log:$" > changelog_file
 484                         boc = 0
 485                 }
 486         }
 487         # Define date macro.
 488         if (boc == 4) {
 489                 if (date == 0) {
 490                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 491                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 492                         date = 1
 493                 }
 494                 boc = 3
 495         }
 496
 497         sub(/[ \t]+$/, "")
 498         if (!/^%[a-z]+$/ || /changelog/)
 499                 print > changelog_file
 500         else
 501                 print
 502         next
 503 }
 504
 505 ###########
 506 # SCRIPTS #
 507 ###########
 508 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 509         preamble = 0
 510
 511         # %useradd and %groupadd may not be wrapped
 512         if (/%(useradd|groupadd).*\\$/) {
 513                 a = $0; getline;
 514                 sub(/^[\s\t]*/, "");
 515                 $0 = substr(a, 1, length(a) - 1) $0;
 516         }
 517 }
 518
 519 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 520         preamble = 0
 521         use_macros()
 522 }
 523 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 524         preamble = 0
 525 }
 526 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 527         preamble = 0
 528 }
 529 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 530         preamble = 0
 531 }
 532 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 533         preamble = 0
 534 }
 535 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 536         preamble = 0
 537 }
 538 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 539         preamble = 0
 540 }
 541 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 542         preamble = 0
 543 }
 544
 545 #############
 546 # PREAMBLES #
 547 #############
 548 preamble == 1 {
 549         # There should not be a space after the name of field
 550         # and before the colon.
 551         sub(/[ \t]*:/, ":")
 552
 553         if (/^%perl_module_wo_prefix/) {
 554                 name = $2
 555                 version = $3
 556                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 557         }
 558
 559         field = tolower($1)
 560         fieldnlower = $1
 561         if (field ~ /summary:/ && !/etc\.$/) {
 562                 sub(/\.$/, "", $0);
 563         }
 564         if (field ~ /group(\([^)]+\)):/)
 565                 next
 566         if (field ~ /group:/) {
 567                 format_preamble()
 568                 group = $0;
 569                 sub(/^[^ \t]*[ \t]*/, "", group);
 570
 571                 sub(/^Utilities\//,"Applications/", group)
 572                 sub(/^Games/,"Applications/Games", group)
 573                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 574                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 575                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 576                 sub(/^X11\/GNOME/,"X11/Applications", group)
 577                 sub(/^X11\/Utilities/,"X11/Applications", group)
 578                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 579                 sub(/^Shells/,"Applications/Shells", group)
 580                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 581                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 582                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 583                 sub(/^Applications\/Daemons$/, "Daemons", group)
 584                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 585                 sub(/^System\/Servers$/, "Daemons", group)
 586                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 587                 sub(/^X11\/XFree86/, "X11", group)
 588                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 589                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 590                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 591                 sub(/^Development\/Docs$/, "Documentation", group)
 592
 593                 $0 = "Group:\t\t" group
 594
 595                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 596                         x11 = 1
 597
 598                 byl_plik_z_groupmi = 0
 599                 byl_opis_grupy = 0
 600                 while ((getline linia_grup < groups_file) > 0) {
 601                         byl_plik_z_groupmi = 1
 602                         if (linia_grup == group) {
 603                                 byl_opis_grupy = 1
 604                                 break
 605                         }
 606                 }
 607
 608                 if (!byl_plik_z_groupmi)
 609                         print "######\t\t" groups_file ": no such file"
 610                 else if (!byl_opis_grupy)
 611                         print "######\t\t" "Unknown group!"
 612
 613                 close(groups_file)
 614         }
 615
 616         if (field ~ /prereq:/) {
 617                 sub(/PreReq:/, "Requires:", $1);
 618         }
 619
 620         # split (build)requires, obsoletes on commas
 621         if (field ~ /(obsoletes|requires):/ && NF > 2) {
 622                 value = substr($0, index($0, $2));
 623                 $0 = format_requires($1, value);
 624         }
 625
 626         if (field ~ /packager:|distribution:|docdir:|prefix:/) {
 627                 next
 628         }
 629
 630         if (field ~ /buildroot:/)
 631                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 632
 633         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 634         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 635                 $1 = "License:"
 636
 637         if (field ~ /name:/) {
 638                 if ($2 == "%{name}" && name) {
 639                         $2 = name
 640                 }
 641                 name = $2
 642                 name_seen = 1;
 643         }
 644
 645         if (field ~ /version:/) {
 646                 if ($2 == "%{version}" && version) {
 647                         $2 = version
 648                 }
 649                 version = $2
 650                 version_seen = 1;
 651         }
 652
 653         if (field ~ /release:/) {
 654                 if ($2 == "%{release}" && release) {
 655                         $2 = release
 656                 }
 657                 release = $2
 658                 release_seen = 1;
 659         }
 660
 661         if (field ~ /serial:/)
 662                 $1 = "Epoch:"
 663
 664         # proper caps
 665         if (field ~ /^url:$/)
 666                 $1 = "URL:"
 667
 668         # Use %{name} and %{version} in the filenames in "Source:"
 669         if (field ~ /^source/ || field ~ /patch/) {
 670                 n = split($2, url, /\//)
 671                 if (url[n] ~ /\.gz$/) {
 672                         url[n+1] = ".gz" url[n+1]
 673                         sub(/\.gz$/,"",url[n])
 674                 }
 675                 if (url[n] ~ /\.zip$/) {
 676                         url[n+1] = ".zip" url[n+1]
 677                         sub(/\.zip$/,"",url[n])
 678                 }
 679                 if (url[n] ~ /\.tar$/) {
 680                         url[n+1] = ".tar" url[n+1]
 681                         sub(/\.tar$/,"",url[n])
 682                 }
 683                 if (url[n] ~ /\.patch$/) {
 684                         url[n+1] = ".patch" url[n+1]
 685                         sub(/\.patch$/,"",url[n])
 686                 }
 687                 if (url[n] ~ /\.bz2$/) {
 688                         url[n+1] = ".bz2" url[n+1]
 689                         sub(/\.bz2$/,"",url[n])
 690                 }
 691                 if (url[n] ~ /\.logrotate$/) {
 692                         url[n+1] = ".logrotate" url[n+1]
 693                         sub(/\.logrotate$/,"",url[n])
 694                 }
 695                 if (url[n] ~ /\.pamd$/) {
 696                         url[n+1] = ".pamd" url[n+1]
 697                         sub(/\.pamd$/,"",url[n])
 698                 }
 699
 700                 # allow %{name} only in last url component
 701                 s = ""
 702                 for (i = 1; i <= n; i++) {
 703                         url[i] = fixedsub("%{name}", name, url[i])
 704                         if (s) {
 705                                 s = s "/" url[i]
 706                         } else {
 707                                 s = url[i]
 708                         }
 709                 }
 710                 $2 = s url[n+1]
 711
 712                 filename = url[n]
 713                 if (name) {
 714                         url[n] = fixedsub(name, "%{name}", url[n])
 715                 }
 716                 if (field ~ /source/) {
 717                         if (version) {
 718                                 url[n] = fixedsub(version, "%{version}", url[n])
 719                         }
 720                         if (_beta) {
 721                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 722                         }
 723                         if (_rc) {
 724                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 725                         }
 726                         if (_snap) {
 727                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 728                         }
 729                 }
 730                 $2 = fixedsub(filename, url[n], $2)
 731
 732                 # sourceforge urls
 733                 sub("[?]use_mirror=.*$", "", $2);
 734                 sub("[?]download$", "", $2);
 735                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 736
 737                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 738                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 739                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 740         }
 741
 742
 743         if (field ~ /^source:/)
 744                 $1 = "Source0:"
 745
 746         if (field ~ /^patch:/)
 747                 $1 = "Patch0:"
 748
 749         kill_preamble_macros();
 750         format_preamble()
 751
 752         if (field ~ /requires/) {
 753                 # atrpms
 754                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 755         }
 756 }
 757
 758
 759 # sort BR/R!
 760 #
 761 # NOTES:
 762 # - mixing BR/R and anything else confuses this (all will be sorted together)
 763 #   so don't do that.
 764 # - comments leading the BR/R can not be associated,
 765 #   so don't adapterize when the BR/R are mixed with comments
 766 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 767         if ($1 ~ /PreReq:/) {
 768                 sub(/PreReq:/, "Requires:", $1);
 769         }
 770         format_preamble()
 771 #       kill_preamble_macros(); # breaks tabbing
 772
 773         b_idx++;
 774         l = substr($0, index($0, $2));
 775         b_ktmp = b_makekey($1, l);
 776         b_key[b_idx] = b_ktmp;
 777         b_val[b_ktmp] = $0;
 778
 779         next;
 780 }
 781
 782 /^%bcond_/ {
 783         # do nothing
 784         print
 785         next
 786 }
 787
 788 preamble == 1 {
 789         if (b_idx > 0) {
 790                 isort(b_key, b_idx);
 791                 for (i = 1; i <= b_idx; i++) {
 792                         print "" b_val[b_key[i]];
 793                 }
 794                 b_idx = 0
 795         }
 796 }
 797
 798 # main() ;-)
 799 {
 800         preamble = 1
 801
 802         sub(/[ \t]+$/, "")
 803         print
 804
 805         if (name_seen == 0 && name) {
 806                 print "Name:\t" name
 807                 name_seen = 1
 808         }
 809
 810         if (version_seen == 0 && version) {
 811                 print "Version:\t" version
 812                 version_seen = 1
 813         }
 814
 815         if (release_seen == 0 && release) {
 816                 print "Release:\t" release
 817                 release_seen = 1
 818         }
 819 }
 820
 821
 822 END {
 823         if (do_not_touch_anything)
 824                 exit 0
 825
 826         close(changelog_file)
 827         while ((getline < changelog_file) > 0)
 828                 print
 829         system("rm -f " changelog_file)
 830
 831         if (did_clean == 0) {
 832                 print ""
 833                 print "%clean"
 834                 print "rm -rf $RPM_BUILD_ROOT"
 835         }
 836
 837         if (date == 0) {
 838                 print ""
 839                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 840         }
 841
 842         if (has_changelog == 0)
 843                 print "%changelog"
 844
 845         if (boc > 2)
 846                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 847         if (boc > 1) {
 848                 printf "All persons listed below can be reached at "
 849                 print "<cvs_login>@pld-linux.org\n"
 850         }
 851         if (boc > 0)
 852                 print "$" "Log:$"
 853 }
 854
 855 function fixedsub(s1,s2,t, ind) {
 856 # substitutes fixed strings (not regexps)
 857         if (ind = index(t,s1))
 858                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 859         return t
 860 }
 861
 862 # There should be one or two tabs after the colon.
 863 function format_preamble()
 864 {
 865         sub(/:[ \t]*/, ":")
 866         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 867                 if (RLENGTH < 8)
 868                         sub(/:/, ":\t\t")
 869                 else
 870                         sub(/:/, ":\t")
 871         }
 872 }
 873
 874 # Replace directly specified directories with macros
 875 function use_macros()
 876 {
 877         # -m, --skip-macros, --no-macros -- skip macros subst
 878         if (ENVIRON["SKIP_MACROS"]) {
 879                 return
 880         }
 881
 882         gsub(perl_sitearch, "%{perl_sitearch}")
 883         gsub(perl_archlib, "%{perl_archlib}")
 884         gsub(perl_privlib, "%{perl_privlib}")
 885         gsub(perl_vendorlib, "%{perl_vendorlib}")
 886         gsub(perl_vendorarch, "%{perl_vendorarch}")
 887         gsub(perl_sitelib, "%{perl_sitelib}")
 888
 889         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
 890
 891         gsub(bindir, "%{_bindir}")
 892         gsub("%{prefix}/bin", "%{_bindir}")
 893         if(prefix"/bin" == bindir)
 894                 gsub("%{_prefix}/bin", "%{_bindir}")
 895
 896         for (c = 1; c <= NF; c++) {
 897                 if ($c ~ sbindir "/fix-info-dir")
 898                         continue;
 899                 if ($c ~ sbindir "/webapp")
 900                         continue;
 901                 if ($c ~ sbindir "/chsh")
 902                         continue;
 903                 if ($c ~ sbindir "/usermod")
 904                         continue;
 905                 gsub(sbindir, "%{_sbindir}", $c)
 906         }
 907
 908         gsub("%{prefix}/sbin", "%{_sbindir}")
 909         if (prefix"/sbin" == sbindir)
 910                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 911
 912         for (c = 1; c <= NF; c++) {
 913                 if ($c ~ sysconfdir "/{?cron.")
 914                         continue;
 915                 if ($c ~ sysconfdir "/{?crontab.d")
 916                         continue;
 917                 if ($c ~ sysconfdir "/{?env.d")
 918                         continue;
 919                 if ($c ~ sysconfdir "/{?logrotate.d")
 920                         continue;
 921                 if ($c ~ sysconfdir "/{?pam.d")
 922                         continue;
 923                 if ($c ~ sysconfdir "/{?profile.d")
 924                         continue;
 925                 if ($c ~ sysconfdir "/{?rc.d")
 926                         continue;
 927                 if ($c ~ sysconfdir "/{?security")
 928                         continue;
 929                 if ($c ~ sysconfdir "/{?skel")
 930                         continue;
 931                 if ($c ~ sysconfdir "/{?sysconfig")
 932                         continue;
 933                 if ($c ~ sysconfdir "/{?shrc.d")
 934                         continue;
 935                 if ($c ~ sysconfdir "/{?certs")
 936                         continue;
 937                 if ($c ~ sysconfdir "/{?X11")
 938                         continue;
 939                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
 940                         continue;
 941                 if ($c ~ sysconfdir "/{?httpd") # temp
 942                         continue;
 943                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 944         }
 945
 946         gsub(docdir, "%{_docdir}")
 947
 948         for (c = 1; c <= NF; c++) {
 949                 if ($c ~ datadir "/automake")
 950                         continue;
 951                 if ($c ~ datadir "/unsermake")
 952                         continue;
 953                 if ($c ~ datadir "/file/magic.mime")
 954                         continue;
 955                 gsub(datadir, "%{_datadir}", $c)
 956         }
 957
 958         gsub("%{prefix}/share", "%{_datadir}")
 959         if (prefix"/share" == datadir)
 960                 gsub("%{_prefix}/share", "%{_datadir}")
 961
 962         # CFLAGS="-I/usr/include/ncurses is usually correct.
 963         if (!/-I\/usr\/include/) {
 964                 gsub(includedir, "%{_includedir}")
 965         }
 966
 967         gsub("%{prefix}/include", "%{_includedir}")
 968         if (prefix"/include" == includedir) {
 969                 gsub("%{_prefix}/include", "%{_includedir}")
 970         }
 971
 972         gsub(mandir, "%{_mandir}")
 973         if ($0 !~ "%{_datadir}/manual") {
 974                 gsub("%{_datadir}/man", "%{_mandir}")
 975         }
 976         gsub("%{_prefix}/share/man", "%{_mandir}")
 977         gsub("%{prefix}/share/man", "%{_mandir}")
 978         gsub("%{prefix}/man", "%{_mandir}")
 979         gsub("%{_prefix}/man", "%{_mandir}")
 980
 981         gsub(infodir, "%{_infodir}")
 982         gsub("%{prefix}/info", "%{_infodir}")
 983         gsub("%{_prefix}/info", "%{_infodir}")
 984
 985         if (prefix !~ "/X11R6") {
 986                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 987         }
 988
 989         gsub(examplesdir, "%{_examplesdir}")
 990
 991         if (prefix != "/") {
 992                 # leave --with-foo=/usr alone
 993                 if ($0 !~ "--with.*=.*" prefix) {
 994                         for (c = 1; c <= NF; c++) {
 995                                 if ($c ~ prefix "/sbin/fix-info-dir")
 996                                         continue;
 997                                 if ($c ~ prefix "/sbin/webapp")
 998                                         continue;
 999                                 if ($c ~ prefix "/sbin/chsh")
1000                                         continue;
1001                                 if ($c ~ prefix "/sbin/usermod")
1002                                         continue;
1003                                 if ($c ~ prefix "/share/automake")
1004                                         continue;
1005                                 if ($c ~ prefix "/share/unsermake")
1006                                         continue;
1007                                 if ($c ~ prefix "/lib/sendmail")
1008                                         continue;
1009                                 if ($c ~ prefix "/lib/pkgconfig")
1010                                         continue;
1011
1012                                 # CFLAGS="-I/usr..." is usually correct.
1013                                 if (/-I\/usr/)
1014                                         continue;
1015                                 # same for LDFLAGS="-L/usr..."
1016                                 if (/-L\/usr/)
1017                                         continue;
1018
1019                                 gsub(prefix, "%{_prefix}", $c)
1020                         }
1021                 }
1022                 gsub("%{prefix}", "%{_prefix}")
1023         }
1024
1025         # replace back
1026         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1027         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1028
1029         gsub("%{PACKAGE_VERSION}", "%{version}")
1030         gsub("%{PACKAGE_NAME}", "%{name}")
1031
1032         gsub("^make$", "%{__make}")
1033         gsub("^make ", "%{__make} ")
1034         gsub("^gcc ", "%{__cc} ")
1035
1036         # mandrake specs
1037         gsub("^%make$", "%{__make}")
1038         gsub("^%make ", "%{__make} ")
1039         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1040         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1041         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1042         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1043         gsub("^%{__install}", "install")
1044         gsub("^%{__rm}", "rm")
1045         gsub("%optflags", "%{rpmcflags}")
1046         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1047
1048         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1049         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1050         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1051         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1052         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1053
1054         # split configure line to multiple lines
1055         if (/%configure / && !/\\$/) {
1056                 $0 = format_configure($0);
1057         }
1058
1059         gsub("%_bindir", "%{_bindir}")
1060         gsub("%_datadir", "%{_datadir}")
1061         gsub("%_iconsdir", "%{_iconsdir}")
1062         gsub("%_sbindir", "%{_sbindir}")
1063         gsub("%_mandir", "%{_mandir}")
1064         gsub("%name", "%{name}")
1065
1066         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1067         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1068 }
1069
1070 function format_configure(line,         n, a, s) {
1071         n = split(line, a, / /);
1072         s = a[1] " \\\n";
1073         for (i = 2; i <= n; i++) {
1074                 s = s "\t" a[i] " \\\n"
1075         }
1076         return s
1077 }
1078
1079
1080 # insertion sort of A[1..n]
1081 # copied from mawk manual
1082 function isort(A,n,             i,j,hold) {
1083         for (i = 2; i <= n; i++) {
1084                 hold = A[j = i]
1085                 while (A[j-1] > hold) {
1086                         j-- ; A[j+1] = A[j]
1087                 }
1088                 A[j] = hold
1089         }
1090         # sentinel A[0] = "" will be created if needed
1091 }
1092
1093
1094 function use_files_macros(      i, n, t, a)
1095 {
1096         use_macros()
1097
1098         # skip comments
1099         if (/^#/) {
1100                 return;
1101         }
1102
1103         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1104         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1105
1106         # uid/gid nobody is not valid in %files
1107         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1108                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1109         }
1110
1111         # s[gu]id programs with globs are evil
1112         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1113                 $0 = $0 " # FIXME no globs for suid/sgid files"
1114         }
1115
1116         # replace back
1117         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1118         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1119         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1120         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1121         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1122         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1123         gsub("%{_sysconfdir}/security", "/etc/security")
1124         gsub("%{_sysconfdir}/skel", "/etc/skel")
1125         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1126         gsub("%{_sysconfdir}/certs", "/etc/certs")
1127         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1128
1129         # /etc/init.d -> /etc/rc.d/init.d
1130         if (!/^\/etc\/init\.d$/) {
1131                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1132         }
1133
1134         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1135                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1136                         $0 = "%attr(754,root,root) " $0
1137                 }
1138                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1139                         gsub("^%attr\\(... *,", "%attr(754,");
1140                 }
1141         }
1142
1143         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1144                 $0 = "%attr(755,root,root) " $0
1145         }
1146
1147         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1148                 $0 = "%attr(755,root,root) " $0
1149         }
1150
1151         # /etc/sysconfig files
1152         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1153         # attr not required, allow default 644 attr
1154         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1155                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace\)/) {
1156                         gsub("%config", "%config(noreplace)")
1157                 }
1158
1159                 if (/\/etc\/sysconfig\// && !/%config\(noreplace\)/) {
1160                         $NF = "%config(noreplace) " $NF
1161                 }
1162
1163                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1164                         gsub("^%attr\\(... *,", "%attr(640,");
1165                 }
1166
1167                 if (/\/etc\/sysconfig\// && !/%verify/) {
1168                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1169                 }
1170         }
1171
1172         # kill leading zeros
1173         if (/%attr\(0[1-9]/) {
1174                 gsub("%attr\\(0", "%attr(")
1175         }
1176
1177         # sort %verify attrs
1178         if (match($0, /%verify\(not([^)]+)\)/)) {
1179                 t = substr($0, RSTART, RLENGTH)
1180                 # kill commas: %verify(not,md5,size,mtime)
1181                 gsub(/,/, " ", t);
1182
1183                 gsub(/^%verify\(not |\)$/, "", t)
1184                 n = split(t, a, / /)
1185                 isort(a, n)
1186
1187                 s = "%verify(not"
1188                 for (i = 1 ; i <= n; i++) {
1189                         s = s " " a[i]
1190                 }
1191                 s = s ")"
1192
1193                 gsub(/%verify\(not[^)]+\)/, s)
1194         }
1195
1196         if (/%{_mandir}/) {
1197                 gsub("\.gz$", "*")
1198         }
1199
1200         # locale dir and no %lang -> bad
1201         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1202                 $(NF + 1) = "# FIXME consider using %find_lang"
1203         }
1204
1205         # atrpms
1206         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1207         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1208         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1209
1210         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1211         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1212         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1213
1214         gsub("%{_datadir}/applications", "%{_desktopdir}");
1215         gsub("%{_datadir}/icons", "%{_iconsdir}");
1216         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1217 }
1218
1219 function fill(ch, n, i) {
1220         for (i = 0; i < n; i++)
1221                 printf("%c", ch)
1222 }
1223
1224 function format_flush(line, indent, newline, word, first_word) {
1225         first_word = 1
1226         if (format_indent == -1)
1227                 newline = ""
1228         else
1229                 newline = fill(" ", format_indent) "- "
1230
1231         while (match(line, /[^\t ]+/)) {
1232                 word = substr(line, RSTART, RLENGTH)
1233                 if (length(newline) + length(word) + 1 > tw) {
1234                         print newline
1235
1236                         if (format_indent == -1)
1237                                 newline = ""
1238                         else
1239                                 newline = fill(" ", format_indent + 2)
1240                         first_word = 1
1241                 }
1242
1243                 if (first_word) {
1244                         newline = newline word
1245                         first_word = 0
1246                 } else
1247                         newline = newline " " word
1248
1249                 line = substr(line, RSTART + RLENGTH)
1250         }
1251         if (newline ~ /[^\t ]/) {
1252                 print newline
1253         }
1254 }
1255
1256 function cflags(var)
1257 {
1258         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1259                 removed[var] = 1
1260                 return 0
1261         }
1262
1263         if (!/!\?debug/)
1264                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1265         return 1
1266 }
1267
1268 function demacroize(str)
1269 {
1270         if (mod_name) {
1271                 sub("%{mod_name}", mod_name, str);
1272         }
1273         if (name) {
1274                 sub("%{name}", name, str);
1275         }
1276         if (version) {
1277                 sub("%{version}", version, str);
1278         }
1279         if (_beta) {
1280                 sub("%{_beta}", _beta, str);
1281         }
1282         if (_rc) {
1283                 sub("%{_rc}", _rc, str);
1284         }
1285         if (_snap) {
1286                 sub("%{_snap}", _snap, str);
1287         }
1288         return str;
1289 }
1290
1291 function kill_preamble_macros()
1292 {
1293         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1294                 # NB! assigning $2 a value breaks tabbing
1295                 $2 = demacroize($2);
1296                 # unify sourceforge url
1297                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1298         }
1299 }
1300
1301 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1302         # skip any formatting for commented out items
1303         if (/^#/) {
1304                 return tag "\t" value
1305         }
1306         n = split(value, p, / *,? */);
1307         for (i = 1; i <= n; i++) {
1308                 if (p[i+1] ~ /[<=>]/) {
1309                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1310                         i += 2;
1311                 } else {
1312                         deps[ndeps++] = p[i];
1313                 }
1314         }
1315         s = ""
1316         for (i in deps) {
1317                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1318         }
1319         return substr(s, 1, length(s)-1);
1320 }