adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # This is adapter v0.28. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Michał Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Jakub Bogusz <qboosh@pld-linux.org>
  14 #       Elan Ruusamäe <glen@pld-linux.org>
  15 #
  16 # See cvs log adapter{,.awk} for list of contributors
  17 #
  18 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  19
  20 # TODO
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27
  28 BEGIN {
  29         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  30         SECTIONS = "^%(" RPM_SECTIONS ")"
  31
  32         PREAMBLE_TAGS = "(Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  33
  34         preamble = 1    # Is it part of preamble? Default - yes
  35         boc = 4                 # Beginning of %changelog
  36         bod = 0                 # Beginning of %description
  37         tw = 70                 # Descriptions width
  38
  39         b_idx = 0               # index of BR/R arrays
  40         BR_count = 0    # number of additional BuildRequires
  41
  42         # If variable removed, then 1 (for removing it from export)
  43         removed["LDFLAGS"] = 0
  44         removed["CFLAGS"] = 0
  45         removed["CXXFLAGS"] = 0
  46
  47         # get cvsaddress for changelog section
  48         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  49         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  50         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  51
  52         # If 1, we are inside of comment block (started with /^#%/)
  53         comment_block = 0
  54
  55         # File with rpm groups
  56         "rpm --eval %_sourcedir" | getline groups_file
  57         groups_file = groups_file "/rpm.groups"
  58         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  59         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  60
  61         # Temporary file for changelog section
  62         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  63
  64         # Load rpm macros
  65         "rpm --eval %_prefix"   | getline prefix
  66         "rpm --eval %_bindir"   | getline bindir
  67         "rpm --eval %_sbindir"  | getline sbindir
  68         "rpm --eval %_libdir"   | getline libdir
  69         "rpm --eval %_sysconfdir" | getline sysconfdir
  70         "rpm --eval %_datadir"  | getline datadir
  71         "rpm --eval %_includedir" | getline includedir
  72         "rpm --eval %_mandir"   | getline mandir
  73         "rpm --eval %_infodir"  | getline infodir
  74         "rpm --eval %_examplesdir"      | getline examplesdir
  75         "rpm --eval %_defaultdocdir"    | getline docdir
  76         "rpm --eval %_kdedocdir"        | getline kdedocdir
  77         "rpm --eval %_desktopdir" | getline desktopdir
  78         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  79
  80         "rpm --eval %perl_sitearch" | getline perl_sitearch
  81         "rpm --eval %perl_archlib" | getline perl_archlib
  82         "rpm --eval %perl_privlib" | getline perl_privlib
  83         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  84         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  85         "rpm --eval %perl_sitelib" | getline perl_sitelib
  86
  87         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  88         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  89         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  90
  91         "rpm --eval %ruby_archdir" | getline ruby_archdir
  92         "rpm --eval %ruby_ridir" | getline ruby_ridir
  93         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  94         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  95         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  96
  97         "rpm --eval %php_pear_dir" | getline php_pear_dir
  98         "rpm --eval %tmpdir" | getline tmpdir
  99 }
 100
 101 # There should be a comment with CVS keywords on the first line of file.
 102 FNR == 1 {
 103         if (!/# \$Revision:/)   # If this line is already OK?
 104                 print "# $" "Revision:$, " "$" "Date:$" # No
 105         else {
 106                 print $0                                # Yes
 107                 next            # It is enough for first line
 108         }
 109 }
 110
 111 # If the latest line matched /%files/
 112 defattr == 1 {
 113         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 114                 if ($0 !~ /defattr/) {  # If no %defattr
 115                         print "%defattr(644,root,root,755)"     # Add it
 116                 } else {
 117                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 118                 }
 119         }
 120         defattr = 0
 121 }
 122
 123 function b_makekey(a, b,        s) {
 124         s = a "" b;
 125         # kill bcond
 126         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 127
 128         # kill commented out items
 129         gsub(/^#[ \t]*/, "", s);
 130
 131         # force order
 132         gsub(/^Summary\(/, "11Summary(", s);
 133         gsub(/^Summary/, "10Summary", s);
 134         gsub(/^Name/, "2Name", s);
 135         gsub(/^Version/, "3Version", s);
 136         gsub(/^Release/, "4Release", s);
 137         gsub(/^Epoch/, "5Epoch", s);
 138         gsub(/^License/, "5License", s);
 139         gsub(/^Group/, "6Group", s);
 140         gsub(/^URL/, "7URL", s);
 141
 142         gsub(/^BuildRequires/, "B1BuildRequires", s);
 143         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 144         gsub(/^Provides/, "X1Provides", s);
 145         gsub(/^Obsoletes/, "X2Obsoletes", s);
 146         gsub(/^Conflicts/, "X3Conflicts", s);
 147         gsub(/^BuildArch/, "X4BuildArch", s);
 148         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 149         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 150         gsub(/^BuildRoot/, "X9BuildRoot", s);
 151
 152 #       printf("%s -> %s\n", a""b, s);
 153         return s;
 154 }
 155
 156 # Comments
 157 /^#/ && (description == 0) {
 158         if (/This file does not like to be adapterized!/) {
 159                 print                   # print this message
 160                 while (getline)         # print the rest of spec as it is
 161                         print
 162                 do_not_touch_anything = 1 # do not touch anything in END()
 163                 exit 0
 164         }
 165
 166         # Generally, comments are printed without touching
 167         sub(/[ \t]+$/, "")
 168
 169         if (/Source.*md5/) {
 170                 print $0
 171                 next
 172         }
 173 }
 174
 175 /^%define/ {
 176         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 177         if ($2 == "_applnkdir") {
 178                 next
 179         }
 180         if ($2 == "date") {
 181                 date = 1
 182                 if (did_files == 0) {
 183                         print "%files"
 184                         print ""
 185                         did_files = 1
 186                 }
 187         }
 188
 189         # Do not add %define of _prefix if it already is.
 190         if ($2 ~ /^_prefix/) {
 191                 sub("^"prefix, $3, bindir)
 192                 sub("^"prefix, $3, sbindir)
 193                 sub("^"prefix, $3, libdir)
 194                 sub("^"prefix, $3, datadir)
 195                 sub("^"prefix, $3, includedir)
 196                 prefix = $3
 197         }
 198
 199         if ($2 ~ /_bindir/ && !/_sbindir/)
 200                 bindir = $3
 201         if ($2 ~ /_sbindir/)
 202                 sbindir = $3
 203         if ($2 ~ /_libdir/) {
 204                 if ($3 ~ /^%\(/) {
 205                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 206                         libdir = "%%%%%%%%%%%%%%"
 207                 } else {
 208                         libdir = $3
 209                 }
 210         }
 211         if ($2 ~ /_sysconfdir/) {
 212                 if ($3 ~ /^%\(/) {
 213                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 214                         sysconfdir = "%%%%%%%%%%%%%%"
 215                 } else {
 216                         sysconfdir = $3
 217                 }
 218         }
 219         if ($2 ~ /_datadir/) {
 220                 if ($3 ~ /^%\(/) {
 221                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 222                         datadir = "%%%%%%%%%%%%%%"
 223                 } else {
 224                         datadir = $3
 225                 }
 226         }
 227         if ($2 ~ /_includedir/)
 228                 includedir = $3
 229         if ($2 ~ /_mandir/)
 230                 mandir = $3
 231         if ($2 ~ /_infodir/)
 232                 infodir = $3
 233         if ($2 ~ /_docdir/)
 234                 docdir = $3
 235
 236         # version related macros
 237         if ($2 ~ /^_beta$/)
 238                 _beta = $3
 239         if ($2 ~ /^_rc$/)
 240                 _rc = $3
 241         if ($2 ~ /^_pre$/)
 242                 _pre = $3
 243         if ($2 ~ /^_snap$/)
 244                 _snap = $3
 245
 246         # these are used usually when adapterizing external spec
 247         if ($2 ~ /^name$/)
 248                 name = $3
 249         if ($2 ~ /^version$/)
 250                 version = $3
 251         if ($2 ~ /^release$/)
 252                 release = $3
 253
 254         if ($2 ~ /^mod_name$/)
 255                 mod_name = $3
 256
 257         sub(/[ \t]+$/, "");
 258         # do nothing further, otherwise adapter thinks we're at preamble
 259         print
 260         next
 261 }
 262
 263 # Obsolete
 264 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 265         next
 266 }
 267
 268 ################
 269 # %description #
 270 ################
 271 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 272         preamble = 0
 273
 274         if (/^%description/) {
 275                 bod++
 276                 format_line = ""
 277                 format_indent = -1
 278         }
 279
 280         # Format description
 281         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 282                 if (/^[ \t]*$/) {
 283                         format_flush(format_line, format_indent)
 284                         print ""
 285                         format_line = ""
 286                         format_indent = -1
 287                 } else if (/^[ \t]*[-\*][ \t]*/) {
 288                         format_flush(format_line, format_indent)
 289                         match($0, /^[ \t]*/)
 290                         format_indent = RLENGTH
 291                         match($0, /^[ \t]*[-\*][ \t]/)
 292                         format_line = substr($0, RLENGTH)
 293                 } else
 294                         format_line = format_line " " $0
 295                 next
 296         }
 297
 298         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 299                 if (NF > 3 && $2 == "-l") {
 300                         ll = $1
 301                         for (i = 4; i <= NF; i++)
 302                                 ll = ll " " $i
 303                         $0 = ll " -l " $3
 304                 }
 305                 format_flush(format_line, format_indent)
 306                 if (bod == 2) {
 307                         bod = 1
 308                         description = 1
 309                 } else {
 310                         bod = 0
 311                         description = 0
 312                 }
 313         } else
 314                 description = 1
 315 }
 316
 317 #########
 318 # %prep #
 319 #########
 320 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 321         preamble = 0
 322         did_prep = 1
 323
 324         use_macros()
 325
 326         # Add '-q' to %setup
 327         if (/^%setup/ && !/-q/) {
 328                 sub(/^%setup/, "%setup -q")
 329         }
 330
 331         if (/^%setup/ && name != "setup") {
 332                 $0 = fixedsub(name, "%{name}", $0);
 333                 $0 = fixedsub(version, "%{version}", $0);
 334                 if (_beta) {
 335                         $0 = fixedsub(_beta, "%{_beta}", $0);
 336                 }
 337                 if (_rc) {
 338                         $0 = fixedsub(_rc, "%{_rc}", $0);
 339                 }
 340                 if (_pre) {
 341                         $0 = fixedsub(_pre, "%{_pre}", $0);
 342                 }
 343                 if (_snap) {
 344                         $0 = fixedsub(_snap, "%{_snap}", $0);
 345                 }
 346         }
 347
 348         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 349                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 350         }
 351         sub("^%patch ", "%patch0 ");
 352
 353         # invalid in %prep
 354         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 355 }
 356
 357 ##########
 358 # %build #
 359 ##########
 360 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 361         preamble = 0
 362
 363         if (did_prep == 0) {
 364                 print "%prep"
 365                 print ""
 366                 did_prep = 1
 367         }
 368
 369         use_macros()
 370         use_tabs()
 371
 372         if (/^automake$/)
 373                 sub(/$/, " -a -c")
 374
 375         if (/LDFLAGS/) {
 376                 if (/LDFLAGS="-s"/) {
 377                         removed["LDFLAGS"] = 1
 378                         next
 379                 } else {
 380                         split($0, tmp, "LDFLAGS=")
 381                         count = split(tmp[2], flags, "\"")
 382                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 383                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 384                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 385                                 for (i = 2; i < count; i++)
 386                                         $0 = $0 flags[i] "\""
 387                         }
 388                 }
 389         }
 390
 391         if (/CFLAGS=/)
 392                 if (cflags("CFLAGS") == 0)
 393                         next
 394
 395         if (/CXXFLAGS=/)
 396                 if (cflags("CXXFLAGS") == 0)
 397                         next
 398
 399         if (/^export /) {
 400                 if (removed["LDFLAGS"])
 401                         sub(" LDFLAGS", "")
 402                 if (removed["CFLAGS"])
 403                         sub(" CFLAGS", "")
 404                 if (removed["CXXFLAGS"])
 405                         sub(" CXXFLAGS", "")
 406                 # Is there still something?
 407                 if (/^export[ ]*$/)
 408                         next
 409         }
 410
 411         # quote CC
 412         if (/CC=%{__cc} /) {
 413                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 414         }
 415
 416         # use PLD Linux macros
 417         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 418         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 419         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 420         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 421         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 422         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 423         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 424         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 425
 426         sub(/^aclocal$/, "%{__aclocal}");
 427         sub(/^autoheader$/, "%{__autoheader}");
 428         sub(/^autoconf$/, "%{__autoconf}");
 429         sub(/^automake$/, "%{__automake}");
 430         sub(/^libtoolize$/, "%{__libtoolize}");
 431
 432         # atrpms
 433         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 434         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 435 }
 436
 437 ##########
 438 # %clean #
 439 ##########
 440 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 441         did_clean = 1
 442
 443         use_macros()
 444 }
 445
 446 ############
 447 # %install #
 448 ############
 449 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 450
 451         preamble = 0
 452
 453         # foreign rpms
 454         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 455         sub("%buildroot", "$RPM_BUILD_ROOT");
 456         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 457
 458         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 459                 did_rmroot=1
 460                 print "rm -rf $RPM_BUILD_ROOT"
 461                 next
 462         }
 463
 464         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 465                 print "rm -rf $RPM_BUILD_ROOT"
 466                 did_rmroot=1
 467         }
 468
 469         if (tmpdir) {
 470                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 471                 gsub(buildroot, "$RPM_BUILD_ROOT")
 472         }
 473
 474         if (!/%{_lib}/) {
 475                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 476         }
 477
 478         use_macros()
 479
 480         # 'install -d' instead 'mkdir -p'
 481         if (/mkdir -p/)
 482                 sub(/mkdir -p/, "install -d")
 483
 484         # cp -a already implies cp -r
 485         sub(/^cp -ar/, "cp -a")
 486
 487         # No '-u root' or '-g root' for 'install'
 488         if (/^install/ && /-[ug][ \t]*root/)
 489                 gsub(/-[ug][ \t]*root /, "")
 490
 491         if (/^install/ && /-m[ \t]*[0-9]+/)
 492                 gsub(/-m[ \t]*[0-9]+ /, "")
 493
 494         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 495         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 496                 next
 497
 498         # No lines contain 'chmod' if it sets the modes to '644'
 499         if ($1 ~ /chmod/ && $2 ~ /644/)
 500                 next
 501
 502         # atrpms
 503         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 504 }
 505
 506 ##########
 507 # %files #
 508 ##########
 509 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 510         preamble = 0
 511         did_files = 1
 512
 513         if ($0 ~ /^%files/)
 514                 defattr = 1
 515
 516         use_files_macros()
 517 }
 518
 519 ##############
 520 # %changelog #
 521 ##############
 522 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 523         preamble = 0
 524         has_changelog = 1
 525         skip = 0
 526         # There should be some CVS keywords on the first line of %changelog.
 527         if (boc == 3) {
 528                 if ($0 !~ _cvsmailfeedback) {
 529                         print "* %{date} " _cvsmailfeedback > changelog_file
 530                 } else {
 531                         skip = 1
 532                 }
 533                 boc = 2
 534         }
 535         if (boc == 2 && !skip) {
 536                 if (!/All persons listed below/) {
 537                         printf "All persons listed below can be reached at " > changelog_file
 538                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 539                 } else {
 540                         skip = 1
 541                 }
 542                 boc = 1
 543         }
 544         if (boc == 1 && !skip) {
 545                 if (!/^$/) {
 546                         if (!/\$.*Log:.*\$/) {
 547                                 print "$" "Log:$" > changelog_file
 548                         }
 549                         boc = 0
 550                 }
 551         }
 552         # Define date macro.
 553         if (boc == 4) {
 554                 if (date == 0) {
 555                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 556                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 557                         date = 1
 558                 }
 559                 boc = 3
 560         }
 561
 562         sub(/[ \t]+$/, "");
 563         if (!/^%[a-z]+$/ || /changelog/) {
 564                 # stop changelog if "real" changelog starts
 565                 if (boc == 0 && /^\* /) {
 566                         boc = -1
 567                 }
 568                 if (boc == -1) {
 569                         next;
 570                 }
 571                 print > changelog_file
 572         } else {
 573                 print
 574         }
 575         next
 576 }
 577
 578 ###########
 579 # SCRIPTS #
 580 ###########
 581 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 582         preamble = 0
 583
 584         if (gsub("/usr/sbin/useradd", "%useradd")) {
 585                 sub(" 2> /dev/null \|\| :", "");
 586                 sub(" >/dev/null 2>&1 \|\|:", "");
 587         }
 588
 589         # %useradd and %groupadd may not be wrapped
 590         if (/%(useradd|groupadd).*\\$/) {
 591                 a = $0; getline;
 592                 sub(/^[\s\t]*/, "");
 593                 $0 = substr(a, 1, length(a) - 1) $0;
 594         }
 595         use_script_macros()
 596 }
 597
 598 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 599         preamble = 0
 600         use_macros()
 601 }
 602 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 603         preamble = 0
 604         use_macros()
 605 }
 606 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_script_macros()
 609 }
 610 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_script_macros()
 613 }
 614 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 619         preamble = 0
 620         use_script_macros()
 621 }
 622 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 623         preamble = 0
 624         use_script_macros()
 625 }
 626 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 627         preamble = 0
 628         use_script_macros()
 629 }
 630 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 631         preamble = 0
 632         use_script_macros()
 633 }
 634 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 635         preamble = 0
 636         use_script_macros()
 637 }
 638
 639 #############
 640 # PREAMBLES #
 641 #############
 642 preamble == 1 {
 643         # There should not be a space after the name of field
 644         # and before the colon.
 645         sub(/[ \t]*:/, ":")
 646
 647         if (/^%perl_module_wo_prefix/) {
 648                 name = $2
 649                 version = $3
 650                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 651         }
 652
 653         field = tolower($1)
 654         fieldnlower = $1
 655         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 656                 sub(/\.$/, "", $0);
 657         }
 658         if (field ~ /group(\([^)]+\)):/)
 659                 next
 660         if (field ~ /group:/) {
 661                 format_preamble()
 662                 group = $0;
 663                 sub(/^[^ \t]*[ \t]*/, "", group);
 664
 665                 sub(/^Utilities\//,"Applications/", group)
 666                 sub(/^Games/,"Applications/Games", group)
 667                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 668                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 669                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 670                 sub(/^X11\/GNOME/,"X11/Applications", group)
 671                 sub(/^X11\/Utilities/,"X11/Applications", group)
 672                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 673                 sub(/^X11\/Library/,"X11/Libraries", group)
 674                 sub(/^Shells/,"Applications/Shells", group)
 675                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 676                 sub(/^Library\/Development$/, "Development/Libraries", group)
 677                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 678                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 679                 sub(/^Applications\/Daemons$/, "Daemons", group)
 680                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 681                 sub(/^System\/Servers$/, "Daemons", group)
 682                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 683                 sub(/^X11\/XFree86/, "X11", group)
 684                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 685                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 686                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 687                 sub(/^Development\/Docs$/, "Documentation", group)
 688                 sub(/^Development\/Documentation$/, "Documentation", group)
 689                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 690                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 691                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 692                 sub(/^Development\/Testing$/, "Development", group)
 693                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 694                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 695                 sub(/^Web\/Database$/, "Applications/WWW", group)
 696                 sub(/^System Environment\/Base$/, "Base", group)
 697                 sub(/^System$/, "Base", group)
 698                 sub(/^Applications\/Productivity$/, "X11/Applications", group)
 699                 sub(/^Database$/, "Applications/Databases", group)
 700                 sub(/^Development\/Code Generators$/, "Development", group)
 701
 702                 $0 = "Group:\t\t" group
 703
 704                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 705                         x11 = 1
 706
 707                 byl_plik_z_groupmi = 0
 708                 byl_opis_grupy = 0
 709                 while ((getline linia_grup < groups_file) > 0) {
 710                         byl_plik_z_groupmi = 1
 711                         if (linia_grup == group) {
 712                                 byl_opis_grupy = 1
 713                                 break
 714                         }
 715                 }
 716
 717                 if (!byl_plik_z_groupmi)
 718                         print "######\t\t" groups_file ": no such file"
 719                 else if (!byl_opis_grupy)
 720                         print "######\t\t" "Unknown group!"
 721
 722                 close(groups_file)
 723                 did_groups = 1
 724         }
 725
 726         if (field ~ /prereq:/) {
 727                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 728         }
 729
 730         # split (build)requires, obsoletes on commas
 731         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 732                 value = substr($0, index($0, $2));
 733                 $0 = format_requires($1, value);
 734         }
 735
 736         # BR: tar (and others) is to common (rpm-build requires it)
 737         if (field ~ /^buildrequires:/) {
 738                 l = substr($0, index($0, $2));
 739                 if (l == "awk" ||
 740                         l == "binutils" ||
 741                         l == "bzip2" ||
 742                         l == "cpio" ||
 743                         l == "diffutils" ||
 744                         l == "elfutils" ||
 745                         l == "fileutils" ||
 746                         l == "findutils" ||
 747                         l == "glibc-devel" ||
 748                         l == "grep" ||
 749                         l == "gzip" ||
 750                         l == "make" ||
 751                         l == "patch" ||
 752                         l == "sed" ||
 753                         l == "sh-utils" ||
 754                         l == "tar" ||
 755                         l == "textutils") {
 756                         next
 757                 }
 758
 759                 # perhaps we have common known name?
 760
 761                 # jpackages
 762                 sub(/^java-devel$/, "jdk", $2);
 763                 sub(/^log4j$/, "jakarta-log4j", $2);
 764                 sub(/^oro$/, "jakarta-oro", $2);
 765                 sub(/^jakarta-ant$/, "ant", $2);
 766                 sub(/^xerces-j2$/, "xerces-j", $2);
 767                 sub(/^ldapjdk$/, "ldapsdk", $2);
 768                 sub(/^saxon-scripts$/, "saxon", $2);
 769                 sub(/^xalan-j2$/, "xalan-j", $2);
 770                 sub(/^xerces-j2$/, "xerces-j", $2);
 771
 772                 replace_php_virtual_deps();
 773         }
 774
 775         if (field ~ /^requires:/) {
 776                 replace_php_virtual_deps();
 777         }
 778
 779
 780         # obsolete/unwanted tags
 781         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 782                 next
 783         }
 784
 785         if (field ~ /buildroot:/) {
 786                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 787                 did_build_root = 1
 788         }
 789
 790         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 791         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 792                 $1 = "License:"
 793         }
 794
 795         if (field ~ /license:/) {
 796                 l = substr($0, index($0, $2));
 797                 if (l == "Python Software Foundation License") {
 798                         l = "PSF"
 799                 }
 800                 $0 = "License:\t" l;
 801         }
 802
 803
 804         if (field ~ /name:/) {
 805                 if ($2 == "%{name}" && name) {
 806                         $2 = name
 807                 }
 808                 name = $2
 809                 name_seen = 1;
 810         }
 811
 812         if (field ~ /version:/) {
 813                 if ($2 == "%{version}" && version) {
 814                         $2 = version
 815                 }
 816                 version = $2
 817                 version_seen = 1;
 818         }
 819
 820         if (field ~ /release:/) {
 821                 if ($2 == "%{release}" && release) {
 822                         $2 = release
 823                 }
 824                 sub(/%atrelease /, "0.", $0)
 825                 release = $2
 826                 release_seen = 1;
 827         }
 828
 829
 830         if (field ~ /serial:/)
 831                 $1 = "Epoch:"
 832
 833         if (field ~ /home-page:/)
 834                 $1 = "URL:"
 835
 836         # proper caps
 837         if (field ~ /^url:$/)
 838                 $1 = "URL:"
 839
 840         if (field ~ /^description:$/)
 841                 $1 = "\n%description\n"
 842
 843         # Use %{name} and %{version} in the filenames in "Source:"
 844         if (field ~ /^source/ || field ~ /patch/) {
 845                 n = split($2, url, /\//)
 846                 if (url[n] ~ /\.gz$/) {
 847                         url[n+1] = ".gz" url[n+1]
 848                         sub(/\.gz$/,"",url[n])
 849                 }
 850                 if (url[n] ~ /\.zip$/) {
 851                         url[n+1] = ".zip" url[n+1]
 852                         sub(/\.zip$/,"",url[n])
 853                 }
 854                 if (url[n] ~ /\.tar$/) {
 855                         url[n+1] = ".tar" url[n+1]
 856                         sub(/\.tar$/,"",url[n])
 857                 }
 858                 if (url[n] ~ /\.patch$/) {
 859                         url[n+1] = ".patch" url[n+1]
 860                         sub(/\.patch$/,"",url[n])
 861                 }
 862                 if (url[n] ~ /\.bz2$/) {
 863                         url[n+1] = ".bz2" url[n+1]
 864                         sub(/\.bz2$/,"",url[n])
 865                 }
 866                 if (url[n] ~ /\.logrotate$/) {
 867                         url[n+1] = ".logrotate" url[n+1]
 868                         sub(/\.logrotate$/,"",url[n])
 869                 }
 870                 if (url[n] ~ /\.pamd$/) {
 871                         url[n+1] = ".pamd" url[n+1]
 872                         sub(/\.pamd$/,"",url[n])
 873                 }
 874
 875                 # allow %{name} only in last url component
 876                 s = ""
 877                 for (i = 1; i <= n; i++) {
 878                         url[i] = fixedsub("%{name}", name, url[i])
 879                         if (s) {
 880                                 s = s "/" url[i]
 881                         } else {
 882                                 s = url[i]
 883                         }
 884                 }
 885                 $2 = s url[n+1]
 886
 887                 filename = url[n]
 888                 if (name) {
 889                         url[n] = fixedsub(name, "%{name}", url[n])
 890                 }
 891                 if (field ~ /source/) {
 892                         if (version) {
 893                                 url[n] = fixedsub(version, "%{version}", url[n])
 894                         }
 895                         if (_beta) {
 896                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 897                         }
 898                         if (_rc) {
 899                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 900                         }
 901                         if (_pre) {
 902                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 903                         }
 904                         if (_snap) {
 905                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 906                         }
 907                 }
 908                 # assigning to $2 kills preamble formatting
 909                 $2 = fixedsub(filename, url[n], $2)
 910
 911                 # sourceforge urls
 912                 sub("[?&]big_mirror=.*$", "", $2);
 913                 sub("[?&]modtime=.*$", "", $2);
 914
 915                 sub("[?]use_mirror=.*$", "", $2);
 916                 sub("[?]download$", "", $2);
 917
 918                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 919                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 920                 sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 921
 922                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 923                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 924                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 925
 926                 sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", $2)
 927                 sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", $2)
 928         }
 929
 930
 931         if (field ~ /^source:/)
 932                 $1 = "Source0:"
 933
 934         if (field ~ /^patch:/)
 935                 $1 = "Patch0:"
 936
 937         kill_preamble_macros();
 938         format_preamble()
 939
 940         if (field ~ /requires/) {
 941                 # atrpms
 942                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 943         }
 944 }
 945
 946 /^%bcond_/ {
 947         # do nothing
 948         print
 949         next
 950 }
 951
 952 # sort BR/R!
 953 #
 954 # NOTES:
 955 # - mixing BR/R and anything else confuses this (all will be sorted together)
 956 #       so don't do that.
 957 # - comments leading the BR/R can not be associated,
 958 #       so don't adapterize when the BR/R are mixed with comments
 959 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 960         if ($1 ~ /Pre[Rr]eq:/) {
 961                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 962         }
 963         format_preamble()
 964 #       kill_preamble_macros(); # breaks tabbing
 965
 966         b_idx++;
 967         l = substr($0, index($0, $2));
 968         b_ktmp = b_makekey($1, l);
 969         b_key[b_idx] = b_ktmp;
 970         b_val[b_ktmp] = $0;
 971
 972         next;
 973 }
 974
 975 preamble == 1 {
 976         if (b_idx > 0) {
 977                 isort(b_key, b_idx);
 978                 for (i = 1; i <= b_idx; i++) {
 979                         v = b_val[b_key[i]];
 980                         sub(/[ \t]+$/, "", v);
 981                         print "" v;
 982                 }
 983                 b_idx = 0
 984         }
 985 }
 986
 987 # main() ;-)
 988 {
 989         preamble = 1
 990
 991         sub(/[ \t]+$/, "")
 992         print
 993
 994         if (name_seen == 0 && name) {
 995                 print "Name:\t\t" name
 996                 name_seen = 1
 997         }
 998
 999         if (version_seen == 0 && version) {
1000                 print "Version:\t" version
1001                 version_seen = 1
1002         }
1003
1004         if (release_seen == 0 && release) {
1005                 print "Release:\t" release
1006                 release_seen = 1
1007         }
1008
1009         if (did_build_root == 0) {
1010 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
1011                 did_build_root = 1
1012         }
1013         if (did_groups == 0) {
1014 #               print "Group:\t\tunknown"
1015                 did_groups = 1
1016         }
1017 }
1018
1019
1020 END {
1021         if (do_not_touch_anything)
1022                 exit 0
1023
1024         # TODO: need to output these in proper place
1025         if (BR_count > 0) {
1026                 for (i = 0; i <= BR_count; i++) {
1027                         print BR[i];
1028                 }
1029         }
1030
1031         close(changelog_file)
1032         while ((getline < changelog_file) > 0)
1033                 print
1034         system("rm -f " changelog_file)
1035
1036         if (did_clean == 0) {
1037                 print ""
1038                 print "%clean"
1039                 print "rm -rf $RPM_BUILD_ROOT"
1040         }
1041
1042         if (date == 0) {
1043                 print ""
1044                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1045         }
1046
1047         if (has_changelog == 0) {
1048                 print "%changelog"
1049         }
1050
1051         if (boc > 2) {
1052                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1053         }
1054         if (boc > 1) {
1055                 printf "All persons listed below can be reached at "
1056                 print "<cvs_login>@pld-linux.org\n"
1057         }
1058         if (boc > 0) {
1059                 print "$" "Log:$"
1060         }
1061 }
1062
1063 function fixedsub(s1,s2,t, ind) {
1064 # substitutes fixed strings (not regexps)
1065         if (ind = index(t,s1))
1066                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1067         return t
1068 }
1069
1070 # There should be one or two tabs after the colon.
1071 function format_preamble()
1072 {
1073         if (/^#/ || /^%bcond_with/) {
1074                 return;
1075         }
1076         sub(/:[ \t]*/, ":")
1077         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1078                 if (RLENGTH < 8) {
1079                         sub(/:/, ":\t\t")
1080                 } else {
1081                         sub(/:/, ":\t")
1082                 }
1083         }
1084 }
1085
1086 # Replace directly specified directories with macros
1087 function use_macros()
1088 {
1089         # -m, --skip-macros, --no-macros -- skip macros subst
1090         if (ENVIRON["SKIP_MACROS"]) {
1091                 return
1092         }
1093
1094         # leave inline sed lines alone
1095         if (/(%{__sed}|sed) -i -e/) {
1096                 return;
1097         }
1098
1099         sub("%{_defaultdocdir}", "%{_docdir}");
1100         sub("%{_bindir}/perl", "%{__perl}");
1101         sub("%{_bindir}/python", "%{__python}");
1102
1103         gsub(infodir, "%{_infodir}")
1104
1105         gsub(perl_sitearch, "%{perl_sitearch}")
1106         gsub(perl_archlib, "%{perl_archlib}")
1107         gsub(perl_privlib, "%{perl_privlib}")
1108         gsub(perl_vendorlib, "%{perl_vendorlib}")
1109         gsub(perl_vendorarch, "%{perl_vendorarch}")
1110         gsub(perl_sitelib, "%{perl_sitelib}")
1111
1112         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1113         gsub(py_sitedir, "%{py_sitedir}")
1114         gsub(py_scriptdir, "%{py_scriptdir}")
1115         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1116         gsub("%{python_sitelib}", "%{py_sitedir}")
1117
1118         gsub(ruby_archdir, "%{ruby_archdir}")
1119         gsub(ruby_ridir, "%{ruby_ridir}")
1120         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1121         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1122         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1123
1124         gsub("%{_datadir}/applications", "%{_desktopdir}")
1125         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1126
1127         gsub(libdir, "%{_libdir}")
1128
1129         gsub(bindir, "%{_bindir}")
1130         gsub("%{prefix}/bin", "%{_bindir}")
1131         if (prefix"/bin" == bindir)
1132                 gsub("%{_prefix}/bin", "%{_bindir}")
1133
1134         for (c = 1; c <= NF; c++) {
1135                 if ($c ~ sbindir "/fix-info-dir")
1136                         continue;
1137                 if ($c ~ sbindir "/webapp")
1138                         continue;
1139                 if ($c ~ sbindir "/ldconfig")
1140                         continue;
1141                 if ($c ~ sbindir "/chsh")
1142                         continue;
1143                 if ($c ~ sbindir "/usermod")
1144                         continue;
1145                 if ($c ~ sbindir "/chkconfig")
1146                         continue;
1147                 if ($c ~ sbindir "/installzope(product|3package)")
1148                         continue;
1149                 gsub(sbindir, "%{_sbindir}", $c)
1150         }
1151
1152         gsub("%{prefix}/sbin", "%{_sbindir}")
1153         if (prefix"/sbin" == sbindir) {
1154                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1155         }
1156
1157         for (c = 1; c <= NF; c++) {
1158                 if ($c ~ sysconfdir "/{?cron.")
1159                         continue;
1160                 if ($c ~ sysconfdir "/{?crontab.d")
1161                         continue;
1162                 if ($c ~ sysconfdir "/{?env.d")
1163                         continue;
1164                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1165                         continue;
1166                 if ($c ~ sysconfdir "/{?udev/rules.d")
1167                         continue;
1168                 if ($c ~ sysconfdir "/{?logrotate.d")
1169                         continue;
1170                 if ($c ~ sysconfdir "/{?pam.d")
1171                         continue;
1172                 if ($c ~ sysconfdir "/{?profile.d")
1173                         continue;
1174                 if ($c ~ sysconfdir "/{?rc.d")
1175                         continue;
1176                 if ($c ~ sysconfdir "/{?security")
1177                         continue;
1178                 if ($c ~ sysconfdir "/{?skel")
1179                         continue;
1180                 if ($c ~ sysconfdir "/{?sysconfig")
1181                         continue;
1182                 if ($c ~ sysconfdir "/{?shrc.d")
1183                         continue;
1184                 if ($c ~ sysconfdir "/{?certs")
1185                         continue;
1186                 if ($c ~ sysconfdir "/{?X11")
1187                         continue;
1188                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1189                         continue;
1190                 if ($c ~ sysconfdir "/{?rpm")
1191                         continue;
1192                 if ($c ~ sysconfdir "/{?bash_completion.d")
1193                         continue;
1194                 if ($c ~ sysconfdir "/{?samba")
1195                         continue;
1196                 if ($c ~ sysconfdir "/shells")
1197                         continue;
1198                 if ($c ~ sysconfdir "/ppp")
1199                         continue;
1200                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1201         }
1202
1203         gsub(kdedocdir, "%{_kdedocdir}")
1204         gsub(docdir, "%{_docdir}")
1205         gsub(php_pear_dir, "%{php_pear_dir}")
1206
1207         for (c = 1; c <= NF; c++) {
1208                 if ($c ~ datadir "/automake")
1209                         continue;
1210                 if ($c ~ datadir "/unsermake")
1211                         continue;
1212                 if ($c ~ datadir "/file/magic.mime")
1213                         continue;
1214                 gsub(datadir, "%{_datadir}", $c)
1215         }
1216
1217         gsub("%{prefix}/share", "%{_datadir}")
1218         if (prefix"/share" == datadir)
1219                 gsub("%{_prefix}/share", "%{_datadir}")
1220
1221         # CFLAGS="-I/usr/include/ncurses is usually correct.
1222         if (!/-I\/usr\/include/) {
1223                 gsub(includedir, "%{_includedir}")
1224         }
1225
1226         gsub("%{prefix}/include", "%{_includedir}")
1227         if (prefix"/include" == includedir) {
1228                 gsub("%{_prefix}/include", "%{_includedir}")
1229         }
1230
1231         gsub(mandir, "%{_mandir}")
1232         if ($0 !~ "%{_datadir}/manual") {
1233                 gsub("%{_datadir}/man", "%{_mandir}")
1234         }
1235         gsub("%{_prefix}/share/man", "%{_mandir}")
1236         gsub("%{prefix}/share/man", "%{_mandir}")
1237         gsub("%{prefix}/man", "%{_mandir}")
1238         gsub("%{_prefix}/man", "%{_mandir}")
1239
1240         gsub(infodir, "%{_infodir}")
1241         gsub("%{prefix}/info", "%{_infodir}")
1242         gsub("%{_prefix}/info", "%{_infodir}")
1243
1244         if (prefix !~ "/X11R6") {
1245                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1246         }
1247
1248         gsub(examplesdir, "%{_examplesdir}")
1249
1250         if (prefix != "/") {
1251                 # leave --with-foo=/usr alone
1252                 if ($0 !~ "--with.*=.*" prefix) {
1253                         for (c = 1; c <= NF; c++) {
1254                                 if ($c ~ prefix "/sbin/fix-info-dir")
1255                                         continue;
1256                                 if ($c ~ prefix "/sbin/webapp")
1257                                         continue;
1258                                 if ($c ~ prefix "/sbin/chsh")
1259                                         continue;
1260                                 if ($c ~ prefix "/sbin/usermod")
1261                                         continue;
1262                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1263                                         continue;
1264                                 if ($c ~ prefix "/share/automake")
1265                                         continue;
1266                                 if ($c ~ prefix "/share/unsermake")
1267                                         continue;
1268                                 if ($c ~ prefix "/lib/sendmail")
1269                                         continue;
1270                                 if ($c ~ prefix "/lib/pkgconfig")
1271                                         continue;
1272
1273                                 # CFLAGS="-I/usr..." is usually correct.
1274                                 if (/-I\/usr/)
1275                                         continue;
1276                                 # same for LDFLAGS="-L/usr..."
1277                                 if (/-L\/usr/)
1278                                         continue;
1279
1280                                 gsub(prefix, "%{_prefix}", $c)
1281                         }
1282                 }
1283                 gsub("%{prefix}", "%{_prefix}")
1284         }
1285
1286         # replace back
1287         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1288         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1289
1290         gsub("%{PACKAGE_VERSION}", "%{version}")
1291         gsub("%{PACKAGE_NAME}", "%{name}")
1292
1293         gsub("^make$", "%{__make}")
1294         gsub("^make ", "%{__make} ")
1295         gsub("^gcc ", "%{__cc} ")
1296
1297         # mandrake specs
1298         gsub("^%make$", "%{__make}")
1299         gsub("^%make ", "%{__make} ")
1300         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1301         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1302         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1303         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1304         gsub("^%{__install}", "install")
1305         gsub("^%{__rm}", "rm")
1306         gsub("%optflags", "%{rpmcflags}")
1307         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1308
1309         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1310         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1311         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1312         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1313         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1314
1315         # split configure line to multiple lines
1316         if (/%configure / && !/\\$/) {
1317                 $0 = format_configure($0);
1318         }
1319
1320         gsub("%_bindir", "%{_bindir}")
1321         gsub("%_datadir", "%{_datadir}")
1322         gsub("%_iconsdir", "%{_iconsdir}")
1323         gsub("%_sbindir", "%{_sbindir}")
1324         gsub("%_mandir", "%{_mandir}")
1325         gsub("%name", "%{name}")
1326         gsub(/%__rm/, "rm");
1327         gsub(/%__mkdir_p/, "install -d");
1328         gsub(/%__cp/, "cp");
1329         gsub(/%__ln_s/, "ln -s");
1330         gsub(/%__sed/, "%{__sed}");
1331         gsub(/%__cat/, "cat");
1332         gsub(/%__chmod/, "chmod");
1333
1334         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1335         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1336
1337         if (/^ant /) {
1338                 sub(/^ant/, "%ant")
1339                 add_br("BuildRequires:  jpackage-utils");
1340                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1341         }
1342
1343 }
1344
1345 function format_configure(line,         n, a, s) {
1346         n = split(line, a, / /);
1347         s = a[1] " \\\n";
1348         for (i = 2; i <= n; i++) {
1349                 s = s "\t" a[i] " \\\n"
1350         }
1351         return s
1352 }
1353
1354
1355 # insertion sort of A[1..n]
1356 # copied from mawk manual
1357 function isort(A,n,             i,j,hold) {
1358         for (i = 2; i <= n; i++) {
1359                 hold = A[j = i]
1360                 while (A[j-1] > hold) {
1361                         j-- ; A[j+1] = A[j]
1362                 }
1363                 A[j] = hold
1364         }
1365         # sentinel A[0] = "" will be created if needed
1366 }
1367
1368
1369 function use_files_macros(      i, n, t, a)
1370 {
1371         use_macros()
1372
1373         # skip comments
1374         if (/^#/) {
1375                 return;
1376         }
1377
1378         sub("^%doc %{_mandir}", "%{_mandir}")
1379
1380         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1381         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1382
1383         # uid/gid nobody is not valid in %files
1384         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1385                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1386         }
1387
1388         # s[gu]id programs with globs are evil
1389         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1390                 $0 = $0 " # FIXME no globs for suid/sgid files"
1391         }
1392
1393         # replace back
1394         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1395         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1396         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1397         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1398         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1399         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1400         gsub("%{_sysconfdir}/security", "/etc/security")
1401         gsub("%{_sysconfdir}/skel", "/etc/skel")
1402         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1403         gsub("%{_sysconfdir}/certs", "/etc/certs")
1404         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1405
1406         # /etc/init.d -> /etc/rc.d/init.d
1407         if (!/^\/etc\/init\.d$/) {
1408                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1409         }
1410
1411         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1412                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1413                         $0 = "%attr(754,root,root) " $0
1414                 }
1415                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1416                         gsub("^%attr\\(... *,", "%attr(754,");
1417                 }
1418         }
1419
1420         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1421                 $0 = "%attr(755,root,root) " $0
1422         }
1423
1424         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1425                 $0 = "%attr(755,root,root) " $0
1426         }
1427
1428         # /etc/sysconfig files
1429         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1430         # attr not required, allow default 644 attr
1431         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1432                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1433                         gsub("%config", "%config(noreplace)")
1434                 }
1435
1436                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1437                         $NF = "%config(noreplace) " $NF
1438                 }
1439
1440                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1441                         gsub("^%attr\\(... *,", "%attr(640,");
1442                 }
1443
1444                 if (/\/etc\/sysconfig\// && !/%verify/) {
1445                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1446                 }
1447         }
1448
1449         # kill leading zeros
1450         if (/%attr\(0[1-9]/) {
1451                 gsub("%attr\\(0", "%attr(")
1452         }
1453
1454         # kill leading whitespace
1455         gsub(/^ +/, "");
1456
1457         # kill default attrs
1458         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1459         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1460         if (!/%dir/) {
1461                 gsub(/%attr\(644,root,root\) /, "");
1462         }
1463
1464         # sort %verify attrs
1465         if (match($0, /%verify\(not([^)]+)\)/)) {
1466                 t = substr($0, RSTART, RLENGTH)
1467                 # kill commas: %verify(not,md5,size,mtime)
1468                 gsub(/,/, " ", t);
1469
1470                 gsub(/^%verify\(not |\)$/, "", t)
1471                 n = split(t, a, / /)
1472                 isort(a, n)
1473
1474                 s = "%verify(not"
1475                 for (i = 1 ; i <= n; i++) {
1476                         s = s " " a[i]
1477                 }
1478                 s = s ")"
1479
1480                 gsub(/%verify\(not[^)]+\)/, s)
1481         }
1482
1483         if (/%{_mandir}/) {
1484                 gsub("\.gz$", "*")
1485         }
1486
1487         # locale dir and no %lang -> bad
1488         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1489                 $(NF + 1) = "# FIXME consider using %find_lang"
1490         }
1491
1492         # atrpms
1493         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1494         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1495         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1496
1497         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1498         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1499         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1500
1501         gsub("%{_datadir}/applications", "%{_desktopdir}");
1502         gsub("%{_datadir}/icons", "%{_iconsdir}");
1503         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1504 }
1505
1506 function use_script_macros()
1507 {
1508         if (gsub("/sbin/service", "%service")) {
1509                 sub(" >/dev/null 2>&1 \|\|:", "");
1510                 sub(" 2> /dev/null \|\| :", "");
1511         }
1512 }
1513
1514 function fill(ch, n, i) {
1515         for (i = 0; i < n; i++)
1516                 printf("%c", ch)
1517 }
1518
1519 function format_flush(line, indent, newline, word, first_word) {
1520         first_word = 1
1521         if (format_indent == -1)
1522                 newline = ""
1523         else
1524                 newline = fill(" ", format_indent) "- "
1525
1526         while (match(line, /[^\t ]+/)) {
1527                 word = substr(line, RSTART, RLENGTH)
1528                 if (length(newline) + length(word) + 1 > tw) {
1529                         print newline
1530
1531                         if (format_indent == -1)
1532                                 newline = ""
1533                         else
1534                                 newline = fill(" ", format_indent + 2)
1535                         first_word = 1
1536                 }
1537
1538                 if (first_word) {
1539                         newline = newline word
1540                         first_word = 0
1541                 } else
1542                         newline = newline " " word
1543
1544                 line = substr(line, RSTART + RLENGTH)
1545         }
1546         if (newline ~ /[^\t ]/) {
1547                 print newline
1548         }
1549 }
1550
1551 function cflags(var)
1552 {
1553         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1554                 removed[var] = 1
1555                 return 0
1556         }
1557
1558         if (!/!\?debug/)
1559                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1560         return 1
1561 }
1562
1563 function demacroize(str)
1564 {
1565         if (mod_name) {
1566                 sub("%{mod_name}", mod_name, str);
1567         }
1568         if (name) {
1569                 sub("%{name}", name, str);
1570         }
1571         if (version) {
1572                 sub("%{version}", version, str);
1573         }
1574         if (_beta) {
1575                 sub("%{_beta}", _beta, str);
1576         }
1577         if (_rc) {
1578                 sub("%{_rc}", _rc, str);
1579         }
1580         if (_pre) {
1581                 sub("%{_pre}", _pre, str);
1582         }
1583         if (_snap) {
1584                 sub("%{_snap}", _snap, str);
1585         }
1586         return str;
1587 }
1588
1589 function kill_preamble_macros()
1590 {
1591         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1592                 # NB! assigning $2 a value breaks tabbing
1593                 $2 = demacroize($2);
1594                 # unify sourceforge url
1595                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1596         }
1597 }
1598
1599 function get_epoch(pkg, ver,    epoch)
1600 {
1601         return
1602 # should parse the BR lines more adequately:
1603 #       freetype = 2.0.0 -> correct
1604 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1605
1606         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1607         shell | getline epoch;
1608         return epoch;
1609 }
1610
1611 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1612         # skip any formatting for commented out items or some weird macros
1613         if (/^#/ || /%\(/) {
1614                 return tag "\t" value
1615         }
1616         n = split(value, p, / *,? */);
1617         for (i = 1; i <= n; i++) {
1618                 if (p[i+1] ~ /[<=>]/) {
1619                         # add epoch if the version doesn't have it but BuildRequires.txt has
1620                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1621                                 epoch = get_epoch(p[i], p[i+2])
1622                                 if (epoch) {
1623                                         p[i+2] = epoch ":" p[i+2];
1624                                 }
1625                         }
1626                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1627                         i += 2;
1628                 } else {
1629                         deps[ndeps++] = p[i];
1630                 }
1631         }
1632         s = ""
1633         for (i in deps) {
1634                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1635         }
1636         return substr(s, 1, length(s)-1);
1637 }
1638
1639 function use_tabs()
1640 {
1641         # reverse vim: ts=4 sw=4 et
1642         gsub(/    /, "\t");
1643 }
1644
1645 function add_br(br)
1646 {
1647         BR[BR_count++] = br
1648 }
1649
1650 # php virtual deps as discussed in devel-en
1651 function replace_php_virtual_deps()
1652 {
1653         pkg = $2
1654 #       if (pkg == "php-program") {
1655 #               $0 = $1 "\t/usr/bin/php"
1656 #               return
1657 #       }
1658
1659 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1660 #               sub(/^php-/, "php(", pkg);
1661 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1662 #               $2 = pkg
1663 #       }
1664
1665         if (pkg ~/^php$/) {
1666                 $2 = "webserver(php)";
1667                 if ($4 ~ /^[0-9]:/) {
1668                         $4 = substr($4, 3);
1669                 }
1670         }
1671
1672         if (pkg ~/^php4$/) {
1673                 $2 = "webserver(php)";
1674                 if ($4 ~ /^[0-9]:/) {
1675                         $4 = substr($4, 3);
1676                 }
1677         }
1678 }
1679
1680 # vim:ts=4:sw=4