adapter.awk

   1 #!/usr/bin/gawk -f
   2 #
   3 # This is adapter v0.28. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2007 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Michał Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz Kłoczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Jakub Bogusz <qboosh@pld-linux.org>
  14 #       Elan Ruusamäe <glen@pld-linux.org>
  15 #
  16 # See cvs log adapter{,.awk} for list of contributors
  17 #
  18 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  19
  20 # TODO
  21 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  22 # - add "-nc" option to skip CVS interaction
  23 # - sort Summary(XX)
  24 # - sort Requires, BuildRequires
  25 # - check if %description (lang=C) contains 8bit
  26 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  27
  28 BEGIN {
  29         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  30         SECTIONS = "^%(" RPM_SECTIONS ")"
  31
  32         PREAMBLE_TAGS = "(R|BR|Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires|Suggests)"
  33
  34         usedigest = 0   # Enable to switch to rpm 4.4.6+ md5 digests
  35
  36         preamble = 1    # Is it part of preamble? Default - yes
  37         boc = 4                 # Beginning of %changelog
  38         bod = 0                 # Beginning of %description
  39         tw = 70                 # Descriptions width
  40
  41         b_idx = 0               # index of BR/R arrays
  42         BR_count = 0    # number of additional BuildRequires
  43
  44         # If variable removed, then 1 (for removing it from export)
  45         removed["LDFLAGS"] = 0
  46         removed["CFLAGS"] = 0
  47         removed["CXXFLAGS"] = 0
  48
  49         # get cvsaddress for changelog section
  50         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  51         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  52         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  53
  54         # If 1, we are inside of comment block (started with /^#%/)
  55         comment_block = 0
  56
  57         # File with rpm groups
  58         "rpm --eval %_sourcedir" | getline groups_file
  59         groups_file = groups_file "/rpm.groups"
  60         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  61         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  62
  63         # Temporary file for changelog section
  64         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  65
  66         # Load rpm macros
  67         "rpm --eval %_prefix"   | getline prefix
  68         "rpm --eval %_bindir"   | getline bindir
  69         "rpm --eval %_sbindir"  | getline sbindir
  70         "rpm --eval %_libdir"   | getline libdir
  71         "rpm --eval %_sysconfdir" | getline sysconfdir
  72         "rpm --eval %_datadir"  | getline datadir
  73         "rpm --eval %_includedir" | getline includedir
  74         "rpm --eval %_mandir"   | getline mandir
  75         "rpm --eval %_infodir"  | getline infodir
  76         "rpm --eval %_examplesdir"      | getline examplesdir
  77         "rpm --eval %_defaultdocdir"    | getline docdir
  78         "rpm --eval %_kdedocdir"        | getline kdedocdir
  79         "rpm --eval %_desktopdir" | getline desktopdir
  80         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  81
  82         "rpm --eval %perl_sitearch" | getline perl_sitearch
  83         "rpm --eval %perl_archlib" | getline perl_archlib
  84         "rpm --eval %perl_privlib" | getline perl_privlib
  85         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  86         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  87         "rpm --eval %perl_sitelib" | getline perl_sitelib
  88
  89         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  90         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  91         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  92
  93         "rpm --eval %ruby_archdir" | getline ruby_archdir
  94         "rpm --eval %ruby_ridir" | getline ruby_ridir
  95         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  96         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  97         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  98
  99         "rpm --eval %php_pear_dir" | getline php_pear_dir
 100         "rpm --eval %tmpdir" | getline tmpdir
 101 }
 102
 103 # There should be a comment with CVS keywords on the first line of file.
 104 FNR == 1 {
 105         if (!/# \$Revision:/)   # If this line is already OK?
 106                 print "# $" "Revision:$, " "$" "Date:$" # No
 107         else {
 108                 print $0                                # Yes
 109                 next            # It is enough for first line
 110         }
 111 }
 112
 113 # If the latest line matched /%files/
 114 defattr == 1 {
 115         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 116                 if ($0 !~ /defattr/) {  # If no %defattr
 117                         print "%defattr(644,root,root,755)"     # Add it
 118                 } else {
 119                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 120                 }
 121         }
 122         defattr = 0
 123 }
 124
 125 function b_makekey(a, b,        s) {
 126         s = a "" b;
 127         # kill bcond
 128         gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 129
 130         # kill commented out items
 131         gsub(/^#[ \t]*/, "", s);
 132
 133         # force order
 134         gsub(/^Summary\(/, "11Summary(", s);
 135         gsub(/^Summary/, "10Summary", s);
 136         gsub(/^Name/, "2Name", s);
 137         gsub(/^Version/, "3Version", s);
 138         gsub(/^Release/, "4Release", s);
 139         gsub(/^Epoch/, "5Epoch", s);
 140         gsub(/^License/, "5License", s);
 141         gsub(/^Group/, "6Group", s);
 142         gsub(/^URL/, "7URL", s);
 143
 144         gsub(/^BuildRequires/, "B1BuildRequires", s);
 145         gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 146
 147         gsub(/^Suggests/, "X1Suggests", s);
 148         gsub(/^Provides/, "X2Provides", s);
 149         gsub(/^Obsoletes/, "X3Obsoletes", s);
 150         gsub(/^Conflicts/, "X4Conflicts", s);
 151         gsub(/^BuildArch/, "X5BuildArch", s);
 152         gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 153         gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 154         gsub(/^BuildRoot/, "X9BuildRoot", s);
 155
 156 #       printf("%s -> %s\n", a""b, s);
 157         return s;
 158 }
 159
 160 # Comments
 161 /^#/ && (description == 0) {
 162         if (/This file does not like to be adapterized!/) {
 163                 print                   # print this message
 164                 while (getline)         # print the rest of spec as it is
 165                         print
 166                 do_not_touch_anything = 1 # do not touch anything in END()
 167                 exit 0
 168         }
 169
 170         # Generally, comments are printed without touching
 171         sub(/[ \t]+$/, "")
 172
 173         if (/#[ \t]*Source.*md5/) {
 174                 if (usedigest == 1) {
 175                         sub(/^#[ \t]*Source/, "BuildRequires:\tdigest(%SOURCE", $0)
 176                         sub(/-md5[ \t]*:[ \t]*/, ") = ", $0)
 177                 }
 178                 print $0
 179                 next
 180         }
 181 }
 182
 183 /^%define/ {
 184         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 185         if ($2 == "_applnkdir") {
 186                 next
 187         }
 188         if ($2 == "date") {
 189                 date = 1
 190                 if (did_files == 0) {
 191                         print "%files"
 192                         print ""
 193                         did_files = 1
 194                 }
 195         }
 196
 197         # Do not add %define of _prefix if it already is.
 198         if ($2 ~ /^_prefix/) {
 199                 sub("^"prefix, $3, bindir)
 200                 sub("^"prefix, $3, sbindir)
 201                 sub("^"prefix, $3, libdir)
 202                 sub("^"prefix, $3, datadir)
 203                 sub("^"prefix, $3, includedir)
 204                 prefix = $3
 205         }
 206
 207         if ($2 ~ /_bindir/ && !/_sbindir/)
 208                 bindir = $3
 209         if ($2 ~ /_sbindir/)
 210                 sbindir = $3
 211         if ($2 ~ /_libdir/) {
 212                 if ($3 ~ /^%\(/) {
 213                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 214                         libdir = "%%%%%%%%%%%%%%"
 215                 } else {
 216                         libdir = $3
 217                 }
 218         }
 219         if ($2 ~ /_sysconfdir/) {
 220                 if ($3 ~ /^%\(/) {
 221                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 222                         sysconfdir = "%%%%%%%%%%%%%%"
 223                 } else {
 224                         sysconfdir = $3
 225                 }
 226         }
 227         if ($2 ~ /_datadir/) {
 228                 if ($3 ~ /^%\(/) {
 229                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 230                         datadir = "%%%%%%%%%%%%%%"
 231                 } else {
 232                         datadir = $3
 233                 }
 234         }
 235         if ($2 ~ /_includedir/)
 236                 includedir = $3
 237         if ($2 ~ /_mandir/)
 238                 mandir = $3
 239         if ($2 ~ /_infodir/)
 240                 infodir = $3
 241         if ($2 ~ /_docdir/)
 242                 docdir = $3
 243
 244         # version related macros
 245         if ($2 ~ /^_beta$/)
 246                 _beta = $3
 247         if ($2 ~ /^_rc$/)
 248                 _rc = $3
 249         if ($2 ~ /^_pre$/)
 250                 _pre = $3
 251         if ($2 ~ /^_snap$/)
 252                 _snap = $3
 253
 254         # these are used usually when adapterizing external spec
 255         if ($2 ~ /^name$/)
 256                 name = $3
 257         if ($2 ~ /^version$/)
 258                 version = $3
 259         if ($2 ~ /^release$/)
 260                 release = $3
 261
 262         if ($2 ~ /^mod_name$/)
 263                 mod_name = $3
 264
 265         sub(/[ \t]+$/, "");
 266         # do nothing further, otherwise adapter thinks we're at preamble
 267         print
 268         next
 269 }
 270
 271 # Obsolete
 272 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 273         next
 274 }
 275
 276 ################
 277 # %description #
 278 ################
 279 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 280         preamble = 0
 281
 282         if (/^%description/) {
 283                 bod++
 284                 format_line = ""
 285                 format_indent = -1
 286         }
 287
 288         # Format description
 289         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 290                 if (/^[ \t]*$/) {
 291                         format_flush(format_line, format_indent)
 292                         print ""
 293                         format_line = ""
 294                         format_indent = -1
 295                 } else if (/^[ \t]*[-\*][ \t]*/) {
 296                         format_flush(format_line, format_indent)
 297                         match($0, /^[ \t]*/)
 298                         format_indent = RLENGTH
 299                         match($0, /^[ \t]*[-\*][ \t]/)
 300                         format_line = substr($0, RLENGTH)
 301                 } else
 302                         format_line = format_line " " $0
 303                 next
 304         }
 305
 306         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 307                 if (NF > 3 && $2 == "-l") {
 308                         ll = $1
 309                         for (i = 4; i <= NF; i++)
 310                                 ll = ll " " $i
 311                         $0 = ll " -l " $3
 312                 }
 313                 format_flush(format_line, format_indent)
 314                 if (bod == 2) {
 315                         bod = 1
 316                         description = 1
 317                 } else {
 318                         bod = 0
 319                         description = 0
 320                 }
 321         } else
 322                 description = 1
 323 }
 324
 325 #########
 326 # %prep #
 327 #########
 328 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 329         preamble = 0
 330         did_prep = 1
 331
 332         use_macros()
 333
 334         # Add '-q' to %setup
 335         if (/^%setup/ && !/-q/) {
 336                 sub(/^%setup/, "%setup -q")
 337         }
 338
 339         if (/^%setup/ && name != "setup") {
 340                 $0 = fixedsub(name, "%{name}", $0);
 341                 $0 = fixedsub(version, "%{version}", $0);
 342                 if (_beta) {
 343                         $0 = fixedsub(_beta, "%{_beta}", $0);
 344                 }
 345                 if (_rc) {
 346                         $0 = fixedsub(_rc, "%{_rc}", $0);
 347                 }
 348                 if (_pre) {
 349                         $0 = fixedsub(_pre, "%{_pre}", $0);
 350                 }
 351                 if (_snap) {
 352                         $0 = fixedsub(_snap, "%{_snap}", $0);
 353                 }
 354         }
 355
 356         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 357                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 358         }
 359         sub("^%patch ", "%patch0 ");
 360
 361         # invalid in %prep
 362         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 363 }
 364
 365 ##########
 366 # %build #
 367 ##########
 368 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 369         preamble = 0
 370
 371         if (did_prep == 0) {
 372                 print "%prep"
 373                 print ""
 374                 did_prep = 1
 375         }
 376
 377         use_macros()
 378         use_tabs()
 379
 380         if (/^automake$/)
 381                 sub(/$/, " -a -c")
 382
 383         if (/LDFLAGS/) {
 384                 if (/LDFLAGS="-s"/) {
 385                         removed["LDFLAGS"] = 1
 386                         next
 387                 } else {
 388                         split($0, tmp, "LDFLAGS=")
 389                         count = split(tmp[2], flags, "\"")
 390                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 391                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 392                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 393                                 for (i = 2; i < count; i++)
 394                                         $0 = $0 flags[i] "\""
 395                         }
 396                 }
 397         }
 398
 399         if (/CFLAGS=/)
 400                 if (cflags("CFLAGS") == 0)
 401                         next
 402
 403         if (/CXXFLAGS=/)
 404                 if (cflags("CXXFLAGS") == 0)
 405                         next
 406
 407         if (/^export /) {
 408                 if (removed["LDFLAGS"])
 409                         sub(" LDFLAGS", "")
 410                 if (removed["CFLAGS"])
 411                         sub(" CFLAGS", "")
 412                 if (removed["CXXFLAGS"])
 413                         sub(" CXXFLAGS", "")
 414                 # Is there still something?
 415                 if (/^export[ ]*$/)
 416                         next
 417         }
 418
 419         # quote CC
 420         if (/CC=%{__cc} /) {
 421                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 422         }
 423
 424         # use PLD Linux macros
 425         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 426         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 427         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 428         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 429         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 430         $0 = fixedsub("automake -a -c", "%{__automake}", $0);
 431         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 432         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 433
 434         sub(/^aclocal$/, "%{__aclocal}");
 435         sub(/^autoheader$/, "%{__autoheader}");
 436         sub(/^autoconf$/, "%{__autoconf}");
 437         sub(/^automake$/, "%{__automake}");
 438         sub(/^libtoolize$/, "%{__libtoolize}");
 439
 440         # atrpms
 441         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 442         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 443 }
 444
 445 ##########
 446 # %clean #
 447 ##########
 448 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 449         did_clean = 1
 450
 451         use_macros()
 452 }
 453
 454 ############
 455 # %install #
 456 ############
 457 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 458
 459         preamble = 0
 460
 461         # foreign rpms
 462         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 463         sub("%buildroot", "$RPM_BUILD_ROOT");
 464         sub("%{buildroot}", "$RPM_BUILD_ROOT");
 465
 466         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 467                 did_rmroot=1
 468                 print "rm -rf $RPM_BUILD_ROOT"
 469                 next
 470         }
 471
 472         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 473                 print "rm -rf $RPM_BUILD_ROOT"
 474                 did_rmroot=1
 475         }
 476
 477         if (tmpdir) {
 478                 buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 479                 gsub(buildroot, "$RPM_BUILD_ROOT")
 480         }
 481
 482         if (!/%{_lib}/) {
 483                 sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 484         }
 485
 486         use_macros()
 487
 488         # 'install -d' instead 'mkdir -p'
 489         if (/mkdir -p/)
 490                 sub(/mkdir -p/, "install -d")
 491
 492         # cp -a already implies cp -r
 493         sub(/^cp -ar/, "cp -a")
 494
 495         # No '-u root' or '-g root' for 'install'
 496         if (/^install/ && /-[ug][ \t]*root/)
 497                 gsub(/-[ug][ \t]*root /, "")
 498
 499         if (/^install/ && /-m[ \t]*[0-9]+/)
 500                 gsub(/-m[ \t]*[0-9]+ /, "")
 501
 502         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 503         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 504                 next
 505
 506         # No lines contain 'chmod' if it sets the modes to '644'
 507         if ($1 ~ /chmod/ && $2 ~ /644/)
 508                 next
 509
 510         # atrpms
 511         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 512 }
 513
 514 ##########
 515 # %files #
 516 ##########
 517 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 518         preamble = 0
 519         did_files = 1
 520
 521         if ($0 ~ /^%files/)
 522                 defattr = 1
 523
 524         use_files_macros()
 525 }
 526
 527 ##############
 528 # %changelog #
 529 ##############
 530 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 531         preamble = 0
 532         has_changelog = 1
 533         skip = 0
 534         # There should be some CVS keywords on the first line of %changelog.
 535         if (boc == 3) {
 536                 if ($0 !~ _cvsmailfeedback) {
 537                         print "* %{date} " _cvsmailfeedback > changelog_file
 538                 } else {
 539                         skip = 1
 540                 }
 541                 boc = 2
 542         }
 543         if (boc == 2 && !skip) {
 544                 if (!/All persons listed below/) {
 545                         printf "All persons listed below can be reached at " > changelog_file
 546                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 547                 } else {
 548                         skip = 1
 549                 }
 550                 boc = 1
 551         }
 552         if (boc == 1 && !skip) {
 553                 if (!/^$/) {
 554                         if (!/\$.*Log:.*\$/) {
 555                                 print "$" "Log:$" > changelog_file
 556                         }
 557                         boc = 0
 558                 }
 559         }
 560         # Define date macro.
 561         if (boc == 4) {
 562                 if (date == 0) {
 563                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 564                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 565                         date = 1
 566                 }
 567                 boc = 3
 568         }
 569
 570         sub(/[ \t]+$/, "");
 571         if (!/^%[a-z]+$/ || /changelog/) {
 572                 # stop changelog if "real" changelog starts
 573                 if (boc == 0 && /^\* /) {
 574                         boc = -1
 575                 }
 576                 if (boc == -1) {
 577                         next;
 578                 }
 579                 print > changelog_file
 580         } else {
 581                 print
 582         }
 583         next
 584 }
 585
 586 ###########
 587 # SCRIPTS #
 588 ###########
 589 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 590         preamble = 0
 591
 592         if (gsub("/usr/sbin/useradd", "%useradd")) {
 593                 sub(" 2> /dev/null \|\| :", "");
 594                 sub(" >/dev/null 2>&1 \|\|:", "");
 595         }
 596
 597         # %useradd and %groupadd may not be wrapped
 598         if (/%(useradd|groupadd).*\\$/) {
 599                 a = $0; getline;
 600                 sub(/^[\s\t]*/, "");
 601                 $0 = substr(a, 1, length(a) - 1) $0;
 602         }
 603         use_script_macros()
 604 }
 605
 606 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 607         preamble = 0
 608         use_macros()
 609 }
 610 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 611         preamble = 0
 612         use_macros()
 613 }
 614 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 615         preamble = 0
 616         use_script_macros()
 617 }
 618 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 619         preamble = 0
 620         use_script_macros()
 621 }
 622 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 623         preamble = 0
 624         use_script_macros()
 625 }
 626 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 627         preamble = 0
 628         use_script_macros()
 629 }
 630 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 631         preamble = 0
 632         use_script_macros()
 633 }
 634 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 635         preamble = 0
 636         use_script_macros()
 637 }
 638 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 639         preamble = 0
 640         use_script_macros()
 641 }
 642 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 643         preamble = 0
 644         use_script_macros()
 645 }
 646
 647 #############
 648 # PREAMBLES #
 649 #############
 650 preamble == 1 {
 651         # There should not be a space after the name of field
 652         # and before the colon.
 653         sub(/[ \t]*:/, ":")
 654
 655         if (/^%perl_module_wo_prefix/) {
 656                 name = $2
 657                 version = $3
 658                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 659         }
 660
 661         field = tolower($1)
 662         fieldnlower = $1
 663         if (field ~ /summary:/ && !/etc\.$/ && !/Inc\.$/) {
 664                 sub(/\.$/, "", $0);
 665         }
 666         if (field ~ /group(\([^)]+\)):/)
 667                 next
 668         if (field ~ /group:/) {
 669                 format_preamble()
 670                 group = $0;
 671                 sub(/^[^ \t]*[ \t]*/, "", group);
 672
 673                 sub(/^Utilities\//,"Applications/", group)
 674                 sub(/^Games/,"Applications/Games", group)
 675                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 676                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 677                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 678                 sub(/^X11\/GNOME/,"X11/Applications", group)
 679                 sub(/^X11\/Utilities/,"X11/Applications", group)
 680                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 681                 sub(/^Amusements\/Games\/Strategy\/Real Time/, "X11/Applications/Games/Strategy", group)
 682                 sub(/^X11\/Library/,"X11/Libraries", group)
 683                 sub(/^Shells/,"Applications/Shells", group)
 684                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 685                 sub(/^Library\/Development$/, "Development/Libraries", group)
 686                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 687                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 688                 sub(/^Applications\/Daemons$/, "Daemons", group)
 689                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 690                 sub(/^System\/Servers$/, "Daemons", group)
 691                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 692                 sub(/^X11\/XFree86/, "X11", group)
 693                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 694                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 695                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 696                 sub(/^Development\/Docs$/, "Documentation", group)
 697                 sub(/^Development\/Documentation$/, "Documentation", group)
 698                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 699                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 700                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 701                 sub(/^Development\/Testing$/, "Development", group)
 702                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 703                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 704                 sub(/^Web\/Database$/, "Applications/WWW", group)
 705                 sub(/^System Environment\/Base$/, "Base", group)
 706                 sub(/^System$/, "Base", group)
 707                 sub(/^Applications\/Productivity$/, "X11/Applications", group)
 708                 sub(/^Database$/, "Applications/Databases", group)
 709                 sub(/^Development\/Code Generators$/, "Development", group)
 710                 sub(/^Emulators$/, "Applications/Emulators", group)
 711                 sub(/^System\/Libraries$/, "Libraries", group)
 712                 sub(/^Development\/Libraries\/C and C\+\+$/, "Development/Libraries", group)
 713
 714                 $0 = "Group:\t\t" group
 715
 716                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 717                         x11 = 1
 718
 719                 byl_plik_z_groupmi = 0
 720                 byl_opis_grupy = 0
 721                 while ((getline linia_grup < groups_file) > 0) {
 722                         byl_plik_z_groupmi = 1
 723                         if (linia_grup == group) {
 724                                 byl_opis_grupy = 1
 725                                 break
 726                         }
 727                 }
 728
 729                 if (!byl_plik_z_groupmi)
 730                         print "######\t\t" groups_file ": no such file"
 731                 else if (!byl_opis_grupy)
 732                         print "######\t\t" "Unknown group!"
 733
 734                 close(groups_file)
 735                 did_groups = 1
 736         }
 737
 738         if (field ~ /prereq:/) {
 739                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 740         }
 741
 742         # split (build)requires, obsoletes on commas
 743         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 744                 value = substr($0, index($0, $2));
 745                 $0 = format_requires($1, value);
 746         }
 747
 748         # BR: tar (and others) is to common (rpm-build requires it)
 749         if (field ~ /^buildrequires:/) {
 750                 l = substr($0, index($0, $2));
 751                 if (l == "awk" ||
 752                         l == "binutils" ||
 753                         l == "bzip2" ||
 754                         l == "cpio" ||
 755                         l == "diffutils" ||
 756                         l == "elfutils" ||
 757                         l == "fileutils" ||
 758                         l == "findutils" ||
 759                         l == "glibc-devel" ||
 760                         l == "grep" ||
 761                         l == "gzip" ||
 762                         l == "make" ||
 763                         l == "patch" ||
 764                         l == "sed" ||
 765                         l == "sh-utils" ||
 766                         l == "tar" ||
 767                         l == "textutils") {
 768                         next
 769                 }
 770
 771                 replace_requires();
 772         }
 773
 774         if (field ~ /^requires:/) {
 775                 replace_requires();
 776         }
 777
 778
 779         # obsolete/unwanted tags
 780         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 781                 next
 782         }
 783
 784         if (field ~ /buildroot:/) {
 785                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 786                 did_build_root = 1
 787         }
 788
 789         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 790         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 791                 $1 = "License:"
 792         }
 793
 794         if (field ~ /license:/) {
 795                 l = substr($0, index($0, $2));
 796                 if (l == "Python Software Foundation License") {
 797                         l = "PSF"
 798                 }
 799                 $0 = "License:\t" l;
 800         }
 801
 802
 803         if (field ~ /name:/) {
 804                 if ($2 == "%{name}" && name) {
 805                         $2 = name
 806                 }
 807                 name = $2
 808                 name_seen = 1;
 809         }
 810
 811         if (field ~ /version:/) {
 812                 if ($2 == "%{version}" && version) {
 813                         $2 = version
 814                 }
 815                 version = $2
 816                 version_seen = 1;
 817         }
 818
 819         if (field ~ /release:/) {
 820                 if ($2 == "%{release}" && release) {
 821                         $2 = release
 822                 }
 823                 sub(/%atrelease /, "0.", $0)
 824                 release = $2
 825                 release_seen = 1;
 826         }
 827
 828
 829         if (field ~ /serial:/)
 830                 $1 = "Epoch:"
 831
 832         if (field ~ /home-page:/)
 833                 $1 = "URL:"
 834
 835         # proper caps
 836         if (field ~ /^url:$/)
 837                 $1 = "URL:"
 838
 839         if (field ~ /^description:$/)
 840                 $1 = "\n%description\n"
 841
 842         # Use %{name} and %{version} in the filenames in "Source:"
 843         if (field ~ /^source/ || field ~ /patch/) {
 844                 n = split($2, url, /\//)
 845                 if (url[n] ~ /\.gz$/) {
 846                         url[n+1] = ".gz" url[n+1]
 847                         sub(/\.gz$/,"",url[n])
 848                 }
 849                 if (url[n] ~ /\.zip$/) {
 850                         url[n+1] = ".zip" url[n+1]
 851                         sub(/\.zip$/,"",url[n])
 852                 }
 853                 if (url[n] ~ /\.tar$/) {
 854                         url[n+1] = ".tar" url[n+1]
 855                         sub(/\.tar$/,"",url[n])
 856                 }
 857                 if (url[n] ~ /\.patch$/) {
 858                         url[n+1] = ".patch" url[n+1]
 859                         sub(/\.patch$/,"",url[n])
 860                 }
 861                 if (url[n] ~ /\.bz2$/) {
 862                         url[n+1] = ".bz2" url[n+1]
 863                         sub(/\.bz2$/,"",url[n])
 864                 }
 865                 if (url[n] ~ /\.logrotate$/) {
 866                         url[n+1] = ".logrotate" url[n+1]
 867                         sub(/\.logrotate$/,"",url[n])
 868                 }
 869                 if (url[n] ~ /\.pamd$/) {
 870                         url[n+1] = ".pamd" url[n+1]
 871                         sub(/\.pamd$/,"",url[n])
 872                 }
 873
 874                 # allow %{name} only in last url component
 875                 s = ""
 876                 for (i = 1; i <= n; i++) {
 877                         url[i] = fixedsub("%{name}", name, url[i])
 878                         if (s) {
 879                                 s = s "/" url[i]
 880                         } else {
 881                                 s = url[i]
 882                         }
 883                 }
 884                 $2 = s url[n+1]
 885
 886                 filename = url[n]
 887                 if (name) {
 888                         url[n] = fixedsub(name, "%{name}", url[n])
 889                 }
 890                 if (field ~ /source/) {
 891                         if (version) {
 892                                 url[n] = fixedsub(version, "%{version}", url[n])
 893                         }
 894                         if (_beta) {
 895                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 896                         }
 897                         if (_rc) {
 898                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 899                         }
 900                         if (_pre) {
 901                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 902                         }
 903                         if (_snap) {
 904                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 905                         }
 906                 }
 907                 # assigning to $2 kills preamble formatting
 908                 $2 = fixedsub(filename, url[n], $2)
 909
 910                 # sourceforge urls
 911                 sub("[?&]big_mirror=.*$", "", $2);
 912                 sub("[?&]modtime=.*$", "", $2);
 913
 914                 sub("[?]use_mirror=.*$", "", $2);
 915                 sub("[?]download$", "", $2);
 916
 917                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 918                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 919                 sub("^http://download\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 920                 sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 921
 922                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 923                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 924                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 925
 926                 sub("^ftp://ftp\.gnome\.org/", "http://ftp.gnome.org/", $2)
 927                 sub("^http://ftp\.gnome\.org/pub/gnome/", "http://ftp.gnome.org/pub/GNOME/", $2)
 928
 929                 # apache urls
 930                 sub("^http://apache.zone-h.org/", "http://www.apache.org/dist/", $2)
 931         }
 932
 933
 934         if (field ~ /^source:/)
 935                 $1 = "Source0:"
 936
 937         if (field ~ /^patch:/)
 938                 $1 = "Patch0:"
 939
 940         kill_preamble_macros();
 941         format_preamble()
 942
 943         if (field ~ /requires/) {
 944                 # atrpms
 945                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 946         }
 947 }
 948
 949 /^%bcond_/ {
 950         # do nothing
 951         print
 952         next
 953 }
 954
 955 # sort BR/R!
 956 #
 957 # NOTES:
 958 # - mixing BR/R and anything else confuses this (all will be sorted together)
 959 #       so don't do that.
 960 # - comments leading the BR/R can not be associated,
 961 #       so don't adapterize when the BR/R are mixed with comments
 962 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 963         if ($1 ~ /Pre[Rr]eq:/) {
 964                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 965         }
 966         if ($1 == "BR:" ) {
 967                 $1 = "BuildRequires:"
 968         }
 969         if ($1 == "R:" ) {
 970                 $1 = "Requires:"
 971         }
 972         format_preamble()
 973 #       kill_preamble_macros(); # breaks tabbing
 974
 975         b_idx++;
 976         l = substr($0, index($0, $2));
 977         b_ktmp = b_makekey($1, l);
 978         b_key[b_idx] = b_ktmp;
 979         b_val[b_ktmp] = $0;
 980
 981         next;
 982 }
 983
 984 preamble == 1 {
 985         if (b_idx > 0) {
 986                 isort(b_key, b_idx);
 987                 for (i = 1; i <= b_idx; i++) {
 988                         v = b_val[b_key[i]];
 989                         sub(/[ \t]+$/, "", v);
 990                         print "" v;
 991                 }
 992                 b_idx = 0
 993         }
 994 }
 995
 996 # main() ;-)
 997 {
 998         preamble = 1
 999
1000         sub(/[ \t]+$/, "")
1001         print
1002
1003         if (name_seen == 0 && name) {
1004                 print "Name:\t\t" name
1005                 name_seen = 1
1006         }
1007
1008         if (version_seen == 0 && version) {
1009                 print "Version:\t" version
1010                 version_seen = 1
1011         }
1012
1013         if (release_seen == 0 && release) {
1014                 print "Release:\t" release
1015                 release_seen = 1
1016         }
1017
1018         if (did_build_root == 0) {
1019 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
1020                 did_build_root = 1
1021         }
1022         if (did_groups == 0) {
1023 #               print "Group:\t\tunknown"
1024                 did_groups = 1
1025         }
1026 }
1027
1028
1029 END {
1030         if (do_not_touch_anything)
1031                 exit 0
1032
1033         # TODO: need to output these in proper place
1034         if (BR_count > 0) {
1035                 for (i = 0; i <= BR_count; i++) {
1036                         print BR[i];
1037                 }
1038         }
1039
1040         close(changelog_file)
1041         while ((getline < changelog_file) > 0)
1042                 print
1043         system("rm -f " changelog_file)
1044
1045         if (did_clean == 0) {
1046                 print ""
1047                 print "%clean"
1048                 print "rm -rf $RPM_BUILD_ROOT"
1049         }
1050
1051         if (date == 0) {
1052                 print ""
1053                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1054         }
1055
1056         if (has_changelog == 0) {
1057                 print "%changelog"
1058         }
1059
1060         if (boc > 2) {
1061                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1062         }
1063         if (boc > 1) {
1064                 printf "All persons listed below can be reached at "
1065                 print "<cvs_login>@pld-linux.org\n"
1066         }
1067         if (boc > 0) {
1068                 print "$" "Log:$"
1069         }
1070 }
1071
1072 function fixedsub(s1,s2,t, ind) {
1073 # substitutes fixed strings (not regexps)
1074         if (ind = index(t,s1))
1075                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1076         return t
1077 }
1078
1079 # There should be one or two tabs after the colon.
1080 function format_preamble()
1081 {
1082         if (/^#/ || /^%bcond_with/) {
1083                 return;
1084         }
1085         sub(/:[ \t]*/, ":")
1086         if (match($0, /[A-Za-z0-9(),#_ \t.-]+[ \t]*:[ \t]*/) == 1) {
1087                 if (RLENGTH < 8) {
1088                         sub(/:/, ":\t\t")
1089                 } else {
1090                         sub(/:/, ":\t")
1091                 }
1092         }
1093 }
1094
1095 # Replace directly specified directories with macros
1096 function use_macros()
1097 {
1098         # -m, --skip-macros, --no-macros -- skip macros subst
1099         if (ENVIRON["SKIP_MACROS"]) {
1100                 return
1101         }
1102
1103         # leave inline sed lines alone
1104         if (/(%{__sed}|sed) -i -e/) {
1105                 return;
1106         }
1107
1108         sub("%{_defaultdocdir}", "%{_docdir}");
1109         sub("%{_bindir}/perl", "%{__perl}");
1110         sub("%{_bindir}/python", "%{__python}");
1111
1112         gsub(infodir, "%{_infodir}")
1113
1114         gsub(perl_sitearch, "%{perl_sitearch}")
1115         gsub(perl_archlib, "%{perl_archlib}")
1116         gsub(perl_privlib, "%{perl_privlib}")
1117         gsub(perl_vendorlib, "%{perl_vendorlib}")
1118         gsub(perl_vendorarch, "%{perl_vendorarch}")
1119         gsub(perl_sitelib, "%{perl_sitelib}")
1120
1121         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1122         gsub(py_sitedir, "%{py_sitedir}")
1123         gsub(py_scriptdir, "%{py_scriptdir}")
1124         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1125         gsub("%{python_sitelib}", "%{py_sitedir}")
1126
1127         gsub(ruby_archdir, "%{ruby_archdir}")
1128         gsub(ruby_ridir, "%{ruby_ridir}")
1129         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1130         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1131         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1132
1133         gsub("%{_datadir}/applications", "%{_desktopdir}")
1134         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1135
1136         gsub(libdir, "%{_libdir}")
1137
1138         gsub(bindir, "%{_bindir}")
1139         gsub("%{prefix}/bin", "%{_bindir}")
1140         if (prefix"/bin" == bindir)
1141                 gsub("%{_prefix}/bin", "%{_bindir}")
1142
1143         for (c = 1; c <= NF; c++) {
1144                 if ($c ~ sbindir "/fix-info-dir")
1145                         continue;
1146                 if ($c ~ sbindir "/webapp")
1147                         continue;
1148                 if ($c ~ sbindir "/ldconfig")
1149                         continue;
1150                 if ($c ~ sbindir "/chsh")
1151                         continue;
1152                 if ($c ~ sbindir "/usermod")
1153                         continue;
1154                 if ($c ~ sbindir "/chkconfig")
1155                         continue;
1156                 if ($c ~ sbindir "/installzope(product|3package)")
1157                         continue;
1158                 gsub(sbindir, "%{_sbindir}", $c)
1159         }
1160
1161         gsub("%{prefix}/sbin", "%{_sbindir}")
1162         if (prefix"/sbin" == sbindir) {
1163                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1164         }
1165
1166         for (c = 1; c <= NF; c++) {
1167                 if ($c ~ sysconfdir "/{?cron.")
1168                         continue;
1169                 if ($c ~ sysconfdir "/{?crontab.d")
1170                         continue;
1171                 if ($c ~ sysconfdir "/{?env.d")
1172                         continue;
1173                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1174                         continue;
1175                 if ($c ~ sysconfdir "/{?udev/rules.d")
1176                         continue;
1177                 if ($c ~ sysconfdir "/{?logrotate.d")
1178                         continue;
1179                 if ($c ~ sysconfdir "/{?pam.d")
1180                         continue;
1181                 if ($c ~ sysconfdir "/{?profile.d")
1182                         continue;
1183                 if ($c ~ sysconfdir "/{?rc.d")
1184                         continue;
1185                 if ($c ~ sysconfdir "/{?security")
1186                         continue;
1187                 if ($c ~ sysconfdir "/{?skel")
1188                         continue;
1189                 if ($c ~ sysconfdir "/{?sysconfig")
1190                         continue;
1191                 if ($c ~ sysconfdir "/{?shrc.d")
1192                         continue;
1193                 if ($c ~ sysconfdir "/{?certs")
1194                         continue;
1195                 if ($c ~ sysconfdir "/{?X11")
1196                         continue;
1197                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1198                         continue;
1199                 if ($c ~ sysconfdir "/{?rpm")
1200                         continue;
1201                 if ($c ~ sysconfdir "/{?bash_completion.d")
1202                         continue;
1203                 if ($c ~ sysconfdir "/{?samba")
1204                         continue;
1205                 if ($c ~ sysconfdir "/shells")
1206                         continue;
1207                 if ($c ~ sysconfdir "/ppp")
1208                         continue;
1209                 if ($c ~ sysconfdir "/dbus-1")
1210                         continue;
1211                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1212         }
1213
1214         gsub(kdedocdir, "%{_kdedocdir}")
1215         gsub(docdir, "%{_docdir}")
1216         gsub(php_pear_dir, "%{php_pear_dir}")
1217
1218         for (c = 1; c <= NF; c++) {
1219                 if ($c ~ datadir "/automake")
1220                         continue;
1221                 if ($c ~ datadir "/unsermake")
1222                         continue;
1223                 if ($c ~ datadir "/file/magic.mime")
1224                         continue;
1225                 gsub(datadir, "%{_datadir}", $c)
1226         }
1227
1228         gsub("%{prefix}/share", "%{_datadir}")
1229         if (prefix"/share" == datadir)
1230                 gsub("%{_prefix}/share", "%{_datadir}")
1231
1232         # CFLAGS="-I/usr/include/ncurses is usually correct.
1233         if (!/-I\/usr\/include/) {
1234                 gsub(includedir, "%{_includedir}")
1235         }
1236
1237         gsub("%{prefix}/include", "%{_includedir}")
1238         if (prefix"/include" == includedir) {
1239                 gsub("%{_prefix}/include", "%{_includedir}")
1240         }
1241
1242         gsub(mandir, "%{_mandir}")
1243         if ($0 !~ "%{_datadir}/manual") {
1244                 gsub("%{_datadir}/man", "%{_mandir}")
1245         }
1246         gsub("%{_prefix}/share/man", "%{_mandir}")
1247         gsub("%{prefix}/share/man", "%{_mandir}")
1248         gsub("%{prefix}/man", "%{_mandir}")
1249         gsub("%{_prefix}/man", "%{_mandir}")
1250
1251         gsub(infodir, "%{_infodir}")
1252         gsub("%{prefix}/info", "%{_infodir}")
1253         gsub("%{_prefix}/info", "%{_infodir}")
1254
1255         if (prefix !~ "/X11R6") {
1256                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1257         }
1258
1259         gsub(examplesdir, "%{_examplesdir}")
1260
1261         if (prefix != "/") {
1262                 # leave --with-foo=/usr alone
1263                 if ($0 !~ "--with.*=.*" prefix) {
1264                         for (c = 1; c <= NF; c++) {
1265                                 if ($c ~ prefix "/sbin/fix-info-dir")
1266                                         continue;
1267                                 if ($c ~ prefix "/sbin/webapp")
1268                                         continue;
1269                                 if ($c ~ prefix "/sbin/chsh")
1270                                         continue;
1271                                 if ($c ~ prefix "/sbin/usermod")
1272                                         continue;
1273                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1274                                         continue;
1275                                 if ($c ~ prefix "/share/automake")
1276                                         continue;
1277                                 if ($c ~ prefix "/share/unsermake")
1278                                         continue;
1279                                 if ($c ~ prefix "/lib/sendmail")
1280                                         continue;
1281                                 if ($c ~ prefix "/lib/pkgconfig")
1282                                         continue;
1283
1284                                 # CFLAGS="-I/usr..." is usually correct.
1285                                 if (/-I\/usr/)
1286                                         continue;
1287                                 # same for LDFLAGS="-L/usr..."
1288                                 if (/-L\/usr/)
1289                                         continue;
1290
1291                                 gsub(prefix, "%{_prefix}", $c)
1292                         }
1293                 }
1294                 gsub("%{prefix}", "%{_prefix}")
1295         }
1296
1297         # replace back
1298         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1299         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1300
1301         gsub("%{PACKAGE_VERSION}", "%{version}")
1302         gsub("%{PACKAGE_NAME}", "%{name}")
1303
1304         gsub("^make$", "%{__make}")
1305         gsub("^make ", "%{__make} ")
1306         gsub("^gcc ", "%{__cc} ")
1307
1308         # mandrake specs
1309         gsub("^%make$", "%{__make}")
1310         gsub("^%make ", "%{__make} ")
1311         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1312         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1313         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1314         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1315         gsub("^%{__install}", "install")
1316         gsub("^%{__rm}", "rm")
1317         gsub("%optflags", "%{rpmcflags}")
1318         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1319
1320         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1321         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\\&1")
1322         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1323         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1324         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1325         $0 = fixedsub("%__install", "install", $0);
1326
1327         # split configure line to multiple lines
1328         if (/%configure / && !/\\$/) {
1329                 $0 = format_configure($0);
1330         }
1331
1332         gsub("%_bindir", "%{_bindir}")
1333         gsub("%_datadir", "%{_datadir}")
1334         gsub("%_iconsdir", "%{_iconsdir}")
1335         gsub("%_sbindir", "%{_sbindir}")
1336         gsub("%_mandir", "%{_mandir}")
1337         gsub("%name", "%{name}")
1338         gsub(/%__rm/, "rm");
1339         gsub(/%__mkdir_p/, "install -d");
1340         gsub(/%__cp/, "cp");
1341         gsub(/%__ln_s/, "ln -s");
1342         gsub(/%__sed/, "%{__sed}");
1343         gsub(/%__cat/, "cat");
1344         gsub(/%__chmod/, "chmod");
1345
1346         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1347         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1348
1349         if (/^ant /) {
1350                 sub(/^ant/, "%ant")
1351                 add_br("BuildRequires:  jpackage-utils");
1352                 add_br("BuildRequires:  rpmbuild(macros) >= 1.300");
1353         }
1354
1355 }
1356
1357 function format_configure(line,         n, a, s) {
1358         n = split(line, a, / /);
1359         s = a[1] " \\\n";
1360         for (i = 2; i <= n; i++) {
1361                 s = s "\t" a[i] " \\\n"
1362         }
1363         return s
1364 }
1365
1366
1367 # insertion sort of A[1..n]
1368 # copied from mawk manual
1369 function isort(A,n,             i,j,hold) {
1370         for (i = 2; i <= n; i++) {
1371                 hold = A[j = i]
1372                 while (A[j-1] > hold) {
1373                         j-- ; A[j+1] = A[j]
1374                 }
1375                 A[j] = hold
1376         }
1377         # sentinel A[0] = "" will be created if needed
1378 }
1379
1380
1381 function use_files_macros(      i, n, t, a)
1382 {
1383         use_macros()
1384
1385         # skip comments
1386         if (/^#/) {
1387                 return;
1388         }
1389
1390         sub("^%doc %{_mandir}", "%{_mandir}")
1391
1392         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1393         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1394
1395         # uid/gid nobody is not valid in %files
1396         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1397                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1398         }
1399
1400         # s[gu]id programs with globs are evil
1401         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1402                 $0 = $0 " # FIXME no globs for suid/sgid files"
1403         }
1404
1405         # replace back
1406         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1407         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1408         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1409         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1410         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1411         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1412         gsub("%{_sysconfdir}/security", "/etc/security")
1413         gsub("%{_sysconfdir}/skel", "/etc/skel")
1414         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1415         gsub("%{_sysconfdir}/certs", "/etc/certs")
1416         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1417         gsub("%{_sysconfdir}/dbus-1", "/etc/dbus-1")
1418
1419         # /etc/init.d -> /etc/rc.d/init.d
1420         if (!/^\/etc\/init\.d$/) {
1421                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1422         }
1423
1424         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1425                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1426                         $0 = "%attr(754,root,root) " $0
1427                 }
1428                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1429                         gsub("^%attr\\(... *,", "%attr(754,");
1430                 }
1431         }
1432
1433         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1434                 $0 = "%attr(755,root,root) " $0
1435         }
1436
1437         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1438                 $0 = "%attr(755,root,root) " $0
1439         }
1440
1441         # /etc/sysconfig files
1442         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1443         # attr not required, allow default 644 attr
1444         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1445                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1446                         gsub("%config", "%config(noreplace)")
1447                 }
1448
1449                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1450                         $NF = "%config(noreplace) " $NF
1451                 }
1452
1453                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1454                         gsub("^%attr\\(... *,", "%attr(640,");
1455                 }
1456
1457                 if (/\/etc\/sysconfig\// && !/%verify/) {
1458                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1459                 }
1460         }
1461
1462         # kill leading zeros
1463         if (/%attr\(0[1-9]/) {
1464                 gsub("%attr\\(0", "%attr(")
1465         }
1466
1467         # kill leading whitespace
1468         gsub(/^ +/, "");
1469
1470         # kill default attrs
1471         gsub(/%dir %attr\(755,root,root\)/, "%dir");
1472         gsub(/%attr\(755,root,root\) %dir/, "%dir");
1473         if (!/%dir/) {
1474                 gsub(/%attr\(644,root,root\) /, "");
1475         }
1476
1477         # sort %verify attrs
1478         if (match($0, /%verify\(not([^)]+)\)/)) {
1479                 t = substr($0, RSTART, RLENGTH)
1480                 # kill commas: %verify(not,md5,size,mtime)
1481                 gsub(/,/, " ", t);
1482
1483                 gsub(/^%verify\(not |\)$/, "", t)
1484                 n = split(t, a, / /)
1485                 isort(a, n)
1486
1487                 s = "%verify(not"
1488                 for (i = 1 ; i <= n; i++) {
1489                         s = s " " a[i]
1490                 }
1491                 s = s ")"
1492
1493                 gsub(/%verify\(not[^)]+\)/, s)
1494         }
1495
1496         if (/%{_mandir}/) {
1497                 gsub("\.gz$", "*")
1498         }
1499
1500         # locale dir and no %lang -> bad
1501         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1502                 $(NF + 1) = "# FIXME consider using %find_lang"
1503         }
1504
1505         # atrpms
1506         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1507         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1508         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1509
1510         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1511         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1512         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1513
1514         gsub("%{_datadir}/applications", "%{_desktopdir}");
1515         gsub("%{_datadir}/icons", "%{_iconsdir}");
1516         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1517 }
1518
1519 function use_script_macros()
1520 {
1521         if (gsub("/sbin/service", "%service")) {
1522                 sub(" >/dev/null 2>&1 \|\|:", "");
1523                 sub(" 2> /dev/null \|\| :", "");
1524         }
1525 }
1526
1527 function fill(ch, n, i) {
1528         for (i = 0; i < n; i++)
1529                 printf("%c", ch)
1530 }
1531
1532 function format_flush(line, indent, newline, word, first_word) {
1533         first_word = 1
1534         if (format_indent == -1)
1535                 newline = ""
1536         else
1537                 newline = fill(" ", format_indent) "- "
1538
1539         while (match(line, /[^\t ]+/)) {
1540                 word = substr(line, RSTART, RLENGTH)
1541                 if (length(newline) + length(word) + 1 > tw) {
1542                         print newline
1543
1544                         if (format_indent == -1)
1545                                 newline = ""
1546                         else
1547                                 newline = fill(" ", format_indent + 2)
1548                         first_word = 1
1549                 }
1550
1551                 if (first_word) {
1552                         newline = newline word
1553                         first_word = 0
1554                 } else
1555                         newline = newline " " word
1556
1557                 line = substr(line, RSTART + RLENGTH)
1558         }
1559         if (newline ~ /[^\t ]/) {
1560                 print newline
1561         }
1562 }
1563
1564 function cflags(var)
1565 {
1566         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1567                 removed[var] = 1
1568                 return 0
1569         }
1570
1571         if (!/!\?debug/)
1572                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1573         return 1
1574 }
1575
1576 function demacroize(str)
1577 {
1578         if (mod_name) {
1579                 sub("%{mod_name}", mod_name, str);
1580         }
1581         if (name) {
1582                 sub("%{name}", name, str);
1583         }
1584         if (version) {
1585                 sub("%{version}", version, str);
1586         }
1587         if (_beta) {
1588                 sub("%{_beta}", _beta, str);
1589         }
1590         if (_rc) {
1591                 sub("%{_rc}", _rc, str);
1592         }
1593         if (_pre) {
1594                 sub("%{_pre}", _pre, str);
1595         }
1596         if (_snap) {
1597                 sub("%{_snap}", _snap, str);
1598         }
1599         return str;
1600 }
1601
1602 function kill_preamble_macros()
1603 {
1604         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1605                 # NB! assigning $2 a value breaks tabbing
1606                 $2 = demacroize($2);
1607                 # unify sourceforge url
1608                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1609         }
1610 }
1611
1612 function get_epoch(pkg, ver,    epoch)
1613 {
1614         return
1615 # should parse the BR lines more adequately:
1616 #       freetype = 2.0.0 -> correct
1617 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1618
1619         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1620         shell | getline epoch;
1621         return epoch;
1622 }
1623
1624 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1625         # skip any formatting for commented out items or some weird macros
1626         if (/^#/ || /%\(/) {
1627                 return tag "\t" value
1628         }
1629         n = split(value, p, / *,? */);
1630         for (i = 1; i <= n; i++) {
1631                 if (p[i+1] ~ /[<=>]/) {
1632                         # add epoch if the version doesn't have it but BuildRequires.txt has
1633                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1634                                 epoch = get_epoch(p[i], p[i+2])
1635                                 if (epoch) {
1636                                         p[i+2] = epoch ":" p[i+2];
1637                                 }
1638                         }
1639                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1640                         i += 2;
1641                 } else {
1642                         deps[ndeps++] = p[i];
1643                 }
1644         }
1645         s = ""
1646         for (i in deps) {
1647                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1648         }
1649         return substr(s, 1, length(s)-1);
1650 }
1651
1652 function use_tabs()
1653 {
1654         # reverse vim: ts=4 sw=4 et
1655         gsub(/    /, "\t");
1656 }
1657
1658 function add_br(br)
1659 {
1660         BR[BR_count++] = br
1661 }
1662
1663 function replace_requires()
1664 {
1665
1666         # jpackages
1667         sub(/^java-devel$/, "jdk", $2);
1668         sub(/^log4j$/, "logging-log4j", $2);
1669         sub(/^jakarta-log4j$/, "logging-log4j", $2);
1670         sub(/^oro$/, "jakarta-oro", $2);
1671         sub(/^jakarta-ant$/, "ant", $2);
1672         sub(/^xerces-j2$/, "xerces-j", $2);
1673         sub(/^ldapjdk$/, "ldapsdk", $2);
1674         sub(/^saxon-scripts$/, "saxon", $2);
1675         sub(/^xalan-j2$/, "xalan-j", $2);
1676         sub(/^xerces-j2$/, "xerces-j", $2);
1677         sub(/^gnu-regexp$/, "gnu.regexp", $2);
1678
1679         # redhat virtual
1680         sub(/^tftp-server$/, "tftpdaemon", $2);
1681
1682         sub(/^gcc-c\+\+$/, "libstdc++-devel", $2);
1683
1684         replace_php_virtual_deps()
1685 }
1686
1687 # php virtual deps as discussed in devel-en
1688 function replace_php_virtual_deps()
1689 {
1690         pkg = $2
1691 #       if (pkg == "php-program") {
1692 #               $0 = $1 "\t/usr/bin/php"
1693 #               return
1694 #       }
1695
1696 #       if (pkg ~ /^php-[a-z]/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|pecl-)/) {
1697 #               sub(/^php-/, "php(", pkg);
1698 #               sub(/$/, ") # verify this correctness -- it may be wanted to use specific not virtual dep", pkg);
1699 #               $2 = pkg
1700 #       }
1701
1702         if (pkg ~/^php$/) {
1703                 $2 = "webserver(php)";
1704                 if ($4 ~ /^[0-9]:/) {
1705                         $4 = substr($4, 3);
1706                 }
1707         }
1708
1709         if (pkg ~/^php4$/) {
1710                 $2 = "webserver(php)";
1711                 if ($4 ~ /^[0-9]:/) {
1712                         $4 = substr($4, 3);
1713                 }
1714         }
1715 }
1716
1717 # vim:ts=4:sw=4