adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.27. Adapter adapts .spec files for PLD.
   4 #
   5 # Copyright (C) 1999-2003 PLD-Team <feedback@pld-linux.org>
   6 # Authors:
   7 #       Micha³ Kuratczyk <kura@pld.org.pl>
   8 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
   9 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  10 #       Artur Frysiak <wiget@pld.org.pl>
  11 #       Michal Kochanowicz <mkochano@pld.org.pl>
  12 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  13
  14 BEGIN {
  15         preamble = 1            # Is it part of preamble? Default - yes
  16         boc = 4                 # Beggining of %changelog
  17         bod = 0                 # Beggining of %description
  18         tw = 70                 # Descriptions width
  19
  20         # If variable removed, then 1 (for removing it from export)
  21         removed["LDFLAGS"] = 0
  22         removed["CFLAGS"] = 0
  23         removed["CXXFLAGS"] = 0
  24
  25         # If 1, we are inside of comment block (started with /^#%/)
  26         comment_block = 0
  27
  28         # File with rpm groups
  29         "rpm --eval %_sourcedir" | getline groups_file
  30         groups_file = groups_file "/rpm.groups"
  31         system("cd `rpm --eval %_sourcedir`; cvs up rpm.groups >/dev/null")
  32
  33         # Temporary file for changelog section
  34         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  35
  36         # Load rpm macros
  37         "rpm --eval %_prefix"   | getline prefix
  38         "rpm --eval %_bindir"   | getline bindir
  39         "rpm --eval %_sbindir"  | getline sbindir
  40         "rpm --eval %_libdir"   | getline libdir
  41         "rpm --eval %_sysconfdir" | getline sysconfdir
  42         "rpm --eval %_datadir"  | getline datadir
  43         "rpm --eval %_includedir" | getline includedir
  44         "rpm --eval %_mandir"   | getline mandir
  45         "rpm --eval %_infodir"  | getline infodir
  46 }
  47
  48 # There should be a comment with CVS keywords on the first line of file.
  49 FNR == 1 {
  50         if (!/# \$Revision:/)   # If this line is already OK?
  51                 print "# $" "Revision:$, " "$" "Date:$" # No
  52         else {
  53                 print $0                                # Yes
  54                 next            # It is enough for first line
  55         }
  56 }
  57
  58 # If the latest line matched /%files/
  59 defattr == 1 {
  60         if ($0 !~ /defattr/)    # If no %defattr
  61                 print "%defattr(644,root,root,755)"     # Add it
  62         else
  63                 $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
  64         defattr = 0
  65 }
  66
  67 # Comments
  68 /^#/ && (description == 0) {
  69         if (/This file does not like to be adapterized!/) {
  70                 print                   # print this message
  71                 while (getline)         # print the rest of spec as it is
  72                         print
  73                 do_not_touch_anything = 1 # do not touch anything in END()
  74                 exit 0
  75         }
  76
  77         # Generally, comments are printed without touching
  78         sub(/[ \t]+$/, "")
  79         print $0
  80         next
  81 }
  82
  83 # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
  84 /^%define/ {
  85         if ($2 == "_applnkdir")
  86                 next
  87         if ($2 == "date")
  88                 date = 1
  89 }
  90
  91 ################
  92 # %description #
  93 ################
  94 /^%description/, (/^%[a-z]+/ && !/^%description/) {
  95         preamble = 0
  96
  97         if (/^%description/) {
  98                 bod++
  99                 format_line = ""
 100                 format_indent = -1
 101         }
 102
 103         # Define _prefix and _mandir if it is X11 application
 104 #       if (/^%description$/ && x11 == 1) {
 105 #               print "%define\t\t_prefix\t\t/usr/X11R6"
 106 #               print "%define\t\t_mandir\t\t%{_prefix}/man\n"
 107 #               prefix = "/usr/X11R6"
 108 #               x11 = 2
 109 #       }
 110
 111         # Format description
 112         if (description == 1 && !/^%[a-z]+/ && !/^%description/) {
 113                 if (/^[ \t]*$/) {
 114                         format_flush(format_line, format_indent)
 115                         print ""
 116                         format_line = ""
 117                         format_indent = -1
 118                 } else if (/^[ \t]*[-\*][ \t]*/) {
 119                         format_flush(format_line, format_indent)
 120                         match($0, /^[ \t]*/)
 121                         format_indent = RLENGTH
 122                         match($0, /^[ \t]*[-\*][ \t]/)
 123                         format_line = substr($0, RLENGTH)
 124                 } else
 125                         format_line = format_line " " $0
 126                 next
 127         }
 128
 129         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 130                 if (NF > 3 && $2 == "-l") {
 131                         ll = $1
 132                         for (i = 4; i <= NF; i++)
 133                                 ll = ll " " $i
 134                         $0 = ll " -l " $3
 135                 }
 136                 format_flush(format_line, format_indent)
 137                 if (bod == 2) {
 138                         bod = 1
 139                         description = 1
 140                 } else {
 141                         bod = 0
 142                         description = 0
 143                 }
 144         } else
 145                 description = 1
 146 }
 147
 148 #########
 149 # %prep #
 150 #########
 151 /^%prep/, (/^%[a-z]+$/ && !/^%prep/) {
 152         preamble = 0
 153
 154         # Add '-q' to %setup
 155         if (/^%setup/ && !/-q/)
 156                 sub(/^%setup/, "%setup -q")
 157 }
 158
 159 ##########
 160 # %build #
 161 ##########
 162 /^%build/, (/^%[a-z]+$/ && !/^%build/) {
 163         preamble = 0
 164
 165         use_macros()
 166
 167         if (/^automake$/)
 168                 sub(/$/, " -a -c")
 169
 170         if (/LDFLAGS/) {
 171                 if (/LDFLAGS="-s"/) {
 172                         removed["LDFLAGS"] = 1
 173                         next
 174                 } else {
 175                         split($0, tmp, "LDFLAGS=")
 176                         count = split(tmp[2], flags, "\"")
 177                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 178                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 179                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 180                                 for (i = 2; i < count; i++)
 181                                         $0 = $0 flags[i] "\""
 182                         }
 183                 }
 184         }
 185
 186         if (/CFLAGS=/)
 187                 if (cflags("CFLAGS") == 0)
 188                         next
 189
 190         if (/CXXFLAGS=/)
 191                 if (cflags("CXXFLAGS") == 0)
 192                         next
 193
 194         if (/^export /) {
 195                 if (removed["LDFLAGS"])
 196                         sub(" LDFLAGS", "")
 197                 if (removed["CFLAGS"])
 198                         sub(" CFLAGS", "")
 199                 if (removed["CXXFLAGS"])
 200                         sub(" CXXFLAGS", "")
 201                 # Is there still something?
 202                 if (/^export[ ]*$/)
 203                         next
 204         }
 205
 206 }
 207
 208 ##########
 209 # %clean #
 210 ##########
 211 /^%clean/, (/^%[a-z]+$/ && !/^%clean/) {
 212         did_clean = 1
 213 }
 214
 215 ############
 216 # %install #
 217 ############
 218 /^%install/, (/^%[a-z]+$/ && !/^%install/) {
 219
 220         preamble = 0
 221
 222         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+\${?RPM_BUILD_ROOT}?/ && did_rmroot==0) {
 223                 did_rmroot=1
 224                 print "rm -rf $RPM_BUILD_ROOT"
 225                 next
 226         }
 227
 228         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 229                 print "rm -rf $RPM_BUILD_ROOT"
 230                 did_rmroot=1
 231         }
 232
 233         use_macros()
 234
 235         # 'install -d' instead 'mkdir -p'
 236         if (/mkdir -p/)
 237                 sub(/mkdir -p/, "install -d")
 238
 239         # No '-u root' or '-g root' for 'install'
 240         if (/^install/ && /-[ug][ \t]*root/)
 241                 gsub(/-[ug][ \t]*root /, "")
 242
 243         if (/^install/ && /-m[ \t]*644/)
 244                 gsub(/-m[ \t]*644 /, "")
 245
 246         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 247         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 248                 next
 249
 250         # No lines contain 'chmod' if it sets the modes to '644'
 251         if ($1 ~ /chmod/ && $2 ~ /644/)
 252                 next
 253 }
 254
 255 ##########
 256 # %files #
 257 ##########
 258 /^%files/, (/^%[a-z \-]+$/ && !/^%files/) {
 259         preamble = 0
 260
 261         if ($0 ~ /^%files/)
 262                 defattr = 1
 263
 264         use_macros()
 265         use_files_macros()
 266 }
 267
 268 ##############
 269 # %changelog #
 270 ##############
 271 /^%changelog/, (/^%[a-z]+$/ && !/^%changelog/) {
 272         preamble = 0
 273         has_changelog = 1
 274         skip = 0
 275         # There should be some CVS keywords on the first line of %changelog.
 276         if (boc == 3) {
 277                 if (!/PLD Team/)
 278                         print "* %{date} PLD Team <feedback@pld-linux.org>" > changelog_file
 279                 else
 280                         skip = 1
 281                 boc = 2
 282         }
 283         if (boc == 2 && !skip) {
 284                 if (!/All persons listed below/) {
 285                         printf "All persons listed below can be reached at " > changelog_file
 286                         print "<cvs_login>@pld-linux.org\n" > changelog_file
 287                 } else
 288                         skip = 1
 289                 boc = 1
 290         }
 291         if (boc == 1 && !skip) {
 292                 if (!/^$/) {
 293                         if (!/\$.*Log:.*\$/)
 294                                 print "$" "Log:$" > changelog_file
 295                         boc = 0
 296                 }
 297         }
 298         # Define date macro.
 299         if (boc == 4) {
 300                 if (date == 0) {
 301                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 302                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 303                         date = 1
 304                 }
 305                 boc = 3
 306         }
 307
 308         sub(/[ \t]+$/, "")
 309         if (!/^%[a-z]+$/ || /changelog/)
 310                 print > changelog_file
 311         else
 312                 print
 313         next
 314 }
 315
 316 ###########
 317 # SCRIPTS #
 318 ###########
 319 /^%pre/, (/^%[a-z]+$/ && !/^%pre/) {
 320         preamble = 0
 321 }
 322 /^%post/, (/^%[a-z]+$/ && !/^%post/) {
 323         preamble = 0
 324 }
 325 /^%preun/, (/^%[a-z]+$/ && !/^%preun/) {
 326         preamble = 0
 327 }
 328 /^%postun/, (/^%[a-z]+$/ && !/^%postun/) {
 329         preamble = 0
 330 }
 331
 332 #############
 333 # PREAMBLES #
 334 #############
 335 preamble == 1 {
 336         # There should not be a space after the name of field
 337         # and before the colon.
 338         sub(/[ \t]*:/, ":")
 339
 340         field = tolower($1)
 341         fieldnlower = $1
 342         if (field ~ /group(\([^)]+\)):/)
 343                 next
 344         if (field ~ /group:/) {
 345                 format_preamble()
 346                 sub(/^Utilities\//,"Applications/",$2)
 347                 sub(/^Games/,"Applications/Games",$2)
 348                 sub(/^X11\/Games/,"X11/Applications/Games",$2)
 349                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries",$2)
 350                 sub(/^X11\/GNOME\/Applications/,"X11/Applications",$2)
 351                 sub(/^X11\/GNOME/,"X11/Applications",$2)
 352                 sub(/^X11\/Utilities/,"X11/Applications",$2)
 353                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy",$2)
 354                 sub(/^Shells/,"Applications/Shells",$2)
 355
 356                 sub(/^[^ \t]*[ \t]*/,"")
 357                 Grupa = $0
 358
 359                 print "Group:\t\t" Grupa
 360                 if (Grupa ~ /^X11/ && x11 == 0) # Is it X11 application?
 361                        x11 = 1
 362
 363                 byl_plik_z_grupami = 0
 364                 byl_opis_grupy = 0
 365                 while ((getline linia_grup < groups_file) > 0) {
 366                         byl_plik_z_grupami = 1
 367                         if (linia_grup == Grupa) {
 368                                 byl_opis_grupy = 1
 369                                 break
 370                         }
 371                 }
 372
 373                 if (!byl_plik_z_grupami)
 374                         print "######\t\t" groups_file ": no such file"
 375                 else if (!byl_opis_grupy)
 376                         print "######\t\t" "Unknown group!"
 377
 378                 close(groups_file)
 379                 next
 380         }
 381
 382         if (field ~ /packager:|distribution:|docdir:|prefix:/)
 383                 next
 384
 385         if (field ~ /buildroot:/)
 386                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 387
 388         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 389         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/)
 390                 $1 = "License:"
 391
 392         if (field ~ /name:/)
 393                 name = $2
 394
 395         if (field ~ /version:/)
 396                 version = $2
 397
 398         if (field ~ /serial:/)
 399                 $1 = "Epoch:"
 400
 401         # Use %{name} and %{version} in the filenames in "Source:"
 402         if (field ~ /^source/ || field ~ /patch/) {
 403                 n = split($2, url, /\//)
 404                 if (url[n] ~ /\.gz$/) {
 405                         url[n+1] = ".gz" url[n+1]
 406                         sub(/\.gz$/,"",url[n])
 407                 }
 408                 if (url[n] ~ /\.zip$/) {
 409                         url[n+1] = ".zip" url[n+1]
 410                         sub(/\.zip$/,"",url[n])
 411                 }
 412                 if (url[n] ~ /\.tar$/) {
 413                         url[n+1] = ".tar" url[n+1]
 414                         sub(/\.tar$/,"",url[n])
 415                 }
 416                 if (url[n] ~ /\.patch$/) {
 417                         url[n+1] = ".patch" url[n+1]
 418                         sub(/\.patch$/,"",url[n])
 419                 }
 420                 if (url[n] ~ /\.bz2$/) {
 421                         url[n+1] = ".bz2" url[n+1]
 422                         sub(/\.bz2$/,"",url[n])
 423                 }
 424                 if (url[n] ~ /\.logrotate$/) {
 425                         url[n+1] = ".logrotate" url[n+1]
 426                         sub(/\.logrotate$/,"",url[n])
 427                 }
 428                 if (url[n] ~ /\.pamd$/) {
 429                         url[n+1] = ".pamd" url[n+1]
 430                         sub(/\.pamd$/,"",url[n])
 431                 }
 432
 433                 filename = url[n]
 434                 url[n] = fixedsub(name, "%{name}", url[n])
 435                 if (field ~ /source/)
 436                         url[n] = fixedsub(version, "%{version}", url[n])
 437                 $2 = fixedsub(filename, url[n], $2)
 438         }
 439
 440         if (field ~ /^source:/)
 441                 $1 = "Source0:"
 442
 443         if (field ~ /patch:/)
 444                 $1 = "Patch0:"
 445
 446         format_preamble()
 447
 448         if ($1 ~ /%define/) {
 449                 # Do not add %define of _prefix if it already is.
 450                 if ($2 ~ /^_prefix/) {
 451                         sub("^"prefix, $3, bindir)
 452                         sub("^"prefix, $3, sbindir)
 453                         sub("^"prefix, $3, libdir)
 454                         sub("^"prefix, $3, datadir)
 455                         sub("^"prefix, $3, includedir)
 456                         prefix = $3
 457                         x11 = 2
 458                 }
 459                 if ($2 ~ /_bindir/ && !/_sbindir/)
 460                         bindir = $3
 461                 if ($2 ~ /_sbindir/)
 462                         sbindir = $3
 463                 if ($2 ~ /_libdir/)
 464                         libdir = $3
 465                 if ($2 ~ /_sysconfdir/)
 466                         sysconfdir = $3
 467                 if ($2 ~ /_datadir/)
 468                         datadir = $3
 469                 if ($2 ~ /_includedir/)
 470                         includedir = $3
 471                 if ($2 ~ /_mandir/)
 472                         mandir = $3
 473                 if ($2 ~ /_infodir/)
 474                         infodir = $3
 475         }
 476 }
 477
 478
 479 # main()  ;-)
 480 {
 481         preamble = 1
 482
 483         sub(/[ \t]+$/, "")
 484         print
 485 }
 486
 487
 488 END {
 489         if (do_not_touch_anything)
 490                 exit 0
 491
 492         close(changelog_file)
 493         while ((getline < changelog_file) > 0)
 494                 print
 495         system("rm -f " changelog_file)
 496
 497         if (did_clean == 0) {
 498                 print ""
 499                 print "%clean"
 500                 print "rm -rf $RPM_BUILD_ROOT"
 501         }
 502
 503         if (date == 0) {
 504                 print ""
 505                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
 506         }
 507
 508         if (has_changelog == 0)
 509                 print "%changelog"
 510
 511         if (boc > 2)
 512                 print "* %{date} PLD Team <feedback@pld-linux.org>"
 513         if (boc > 1) {
 514                 printf "All persons listed below can be reached at "
 515                 print "<cvs_login>@pld-linux.org\n"
 516         }
 517         if (boc > 0)
 518                 print "$" "Log:$"
 519 }
 520
 521 function fixedsub(s1,s2,t,      ind) {
 522 # substitutes fixed strings (not regexps)
 523         if (ind = index(t,s1))
 524                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
 525         return t
 526 }
 527
 528 # There should be one or two tabs after the colon.
 529 function format_preamble()
 530 {
 531         sub(/:[ \t]*/, ":")
 532         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
 533                 if (RLENGTH < 8)
 534                         sub(/:/, ":\t\t")
 535                 else
 536                         sub(/:/, ":\t")
 537         }
 538 }
 539
 540 # Replace directly specified directories with macros
 541 function use_macros()
 542 {
 543         gsub(bindir, "%{_bindir}")
 544         gsub("%{prefix}/bin", "%{_bindir}")
 545         if(prefix"/bin" == bindir)
 546                 gsub("%{_prefix}/bin", "%{_bindir}")
 547
 548         for (c = 1; c <= NF; c++) {
 549                 if ($c ~ sbindir "/fix-info-dir")
 550                         continue;
 551                 gsub(sbindir, "%{_sbindir}", $c)
 552         }
 553
 554         gsub("%{prefix}/sbin", "%{_sbindir}")
 555         if(prefix"/sbin" == sbindir)
 556                 gsub("%{_prefix}/sbin", "%{_sbindir}")
 557
 558 #       gsub(libdir, "%{_libdir}")
 559 #       gsub("%{prefix}/lib", "%{_libdir}")
 560 #       if(prefix"/lib" == libdir)
 561 #               gsub("%{_prefix}/lib", "%{_libdir}")
 562
 563         for (c = 1; c <= NF; c++) {
 564                 if ($c ~ sysconfdir "/{?cron.")
 565                         continue;
 566                 if ($c ~ sysconfdir "/{?crontab.d")
 567                         continue;
 568                 if ($c ~ sysconfdir "/{?logrotate.d")
 569                         continue;
 570                 if ($c ~ sysconfdir "/{?pam.d")
 571                         continue;
 572                 if ($c ~ sysconfdir "/{?profile.d")
 573                         continue;
 574                 if ($c ~ sysconfdir "/{?rc.d")
 575                         continue;
 576                 if ($c ~ sysconfdir "/{?security")
 577                         continue;
 578                 if ($c ~ sysconfdir "/{?skel")
 579                         continue;
 580                 if ($c ~ sysconfdir "/{?sysconfig")
 581                         continue;
 582                 gsub(sysconfdir, "%{_sysconfdir}", $c)
 583         }
 584
 585         gsub(datadir, "%{_datadir}")
 586         gsub("%{prefix}/share", "%{_datadir}")
 587         if(prefix"/share" == datadir)
 588                 gsub("%{_prefix}/share", "%{_datadir}")
 589
 590         gsub(includedir, "%{_includedir}")
 591         gsub("%{prefix}/include", "%{_includedir}")
 592         if(prefix"/include" == includedir)
 593                 gsub("%{_prefix}/include", "%{_includedir}")
 594
 595         gsub(mandir, "%{_mandir}")
 596         if ($0 !~ "%{_datadir}/manual")
 597                 gsub("%{_datadir}/man", "%{_mandir}")
 598         gsub("%{_prefix}/share/man", "%{_mandir}")
 599         gsub("%{prefix}/share/man", "%{_mandir}")
 600         gsub("%{prefix}/man", "%{_mandir}")
 601         gsub("%{_prefix}/man", "%{_mandir}")
 602
 603         gsub(infodir, "%{_infodir}")
 604         gsub("%{prefix}/info", "%{_infodir}")
 605         gsub("%{_prefix}/info", "%{_infodir}")
 606
 607         if (prefix !~ "/X11R6") {
 608                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
 609         }
 610
 611         if (prefix != "/") {
 612                 for (c = 1; c <= NF; c++) {
 613                         if ($c ~ prefix "/sbin/fix-info-dir")
 614                                 continue;
 615                         gsub(prefix, "%{_prefix}", $c)
 616                 }
 617                 gsub("%{prefix}", "%{_prefix}")
 618         }
 619
 620         gsub("%{PACKAGE_VERSION}", "%{version}")
 621         gsub("%{PACKAGE_NAME}", "%{name}")
 622
 623         # we can move files between tge dirs below
 624         if ($0 !~ "%{_applnkdir}") {
 625                 gsub("%{_datadir}/gnome/apps", "%{_applnkdir}")
 626                 gsub("%{_datadir}/applnk", "%{_applnkdir}")
 627         }
 628
 629         gsub("^make$", "%{__make}")
 630         gsub("^make ", "%{__make} ")
 631
 632         gsub("/usr/src/linux", "%{_kernelsrcdir}")
 633         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
 634 }
 635
 636 function use_files_macros()
 637 {
 638         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
 639         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
 640 }
 641
 642 function fill(ch, n, i) {
 643         for (i = 0; i < n; i++)
 644                 printf("%c", ch)
 645 }
 646
 647 function format_flush(line, indent, newline, word, first_word) {
 648         first_word = 1
 649         if (format_indent == -1)
 650                 newline = ""
 651         else
 652                 newline = fill(" ", format_indent) "- "
 653
 654         while (match(line, /[^\t ]+/)) {
 655                 word = substr(line, RSTART, RLENGTH)
 656                 if (length(newline) + length(word) + 1 > tw) {
 657                         print newline
 658
 659                         if (format_indent == -1)
 660                                 newline = ""
 661                         else
 662                                 newline = fill(" ", format_indent + 2)
 663                         first_word = 1
 664                 }
 665
 666                 if (first_word) {
 667                         newline = newline word
 668                         first_word = 0
 669                 } else
 670                         newline = newline " " word
 671
 672                 line = substr(line, RSTART + RLENGTH)
 673         }
 674         if (newline ~ /[^\t ]/) {
 675                 print newline
 676         }
 677 }
 678
 679 function cflags(var)
 680 {
 681         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
 682                 removed[var] = 1
 683                 return 0
 684         }
 685
 686         if (!/!\?debug/)
 687                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
 688         return 1
 689 }
 690