adapter.awk

   1 #!/bin/awk -f
   2 #
   3 # This is adapter v0.28. Adapter adapts .spec files for PLD Linux.
   4 # $Id$
   5 #
   6 # Copyright (C) 1999-2006 PLD-Team <feedback@pld-linux.org>
   7 # Authors:
   8 #       Micha³ Kuratczyk <kura@pld.org.pl>
   9 #       Sebastian Zagrodzki <s.zagrodzki@mimuw.edu.pl>
  10 #       Tomasz K³oczko <kloczek@rudy.mif.pg.gda.pl>
  11 #       Artur Frysiak <wiget@pld-linux.org>
  12 #       Michal Kochanowicz <mkochano@pld.org.pl>
  13 #       Elan Ruusamä¤e <glen@pld-linux.org>
  14 #
  15 # See cvs log adapter{,.awk} for list of contributors
  16 #
  17 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
  18
  19 # TODO
  20 # - parse ../PLD-doc/BuildRequires.txt and setup proper BR epoches?
  21 # - add "-nc" option to skip CVS interaction
  22 # - sort Summary(XX)
  23 # - sort Requires, BuildRequires
  24 # - check if %description (lang=C) contains 8bit
  25 # - desc wrapping is totally fucked up on global.spec,1.25, dosemu.spec,1.115-
  26
  27 BEGIN {
  28         RPM_SECTIONS = "package|build|changelog|clean|description|install|post|posttrans|postun|pre|prep|pretrans|preun|triggerin|triggerpostun|triggerun|verifyscript|check"
  29         SECTIONS = "^%(" RPM_SECTIONS ")"
  30
  31         PREAMBLE_TAGS = "(Summary|Name|Version|Release|Epoch|License|Group|URL|BuildArch|BuildRoot|Obsoletes|Conflicts|Provides|ExclusiveArch|ExcludeArch|Pre[Rr]eq|(Build)?Requires)"
  32
  33         preamble = 1    # Is it part of preamble? Default - yes
  34         boc = 4                 # Beginning of %changelog
  35         bod = 0                 # Beginning of %description
  36         tw = 70                 # Descriptions width
  37
  38         b_idx = 0               # index of BR/R arrays
  39     BR_count = 0   # number of additional BuildRequires
  40
  41         # If variable removed, then 1 (for removing it from export)
  42         removed["LDFLAGS"] = 0
  43         removed["CFLAGS"] = 0
  44         removed["CXXFLAGS"] = 0
  45
  46         # get cvsaddress for changelog section
  47         # using rpm macros as too lazy to add ~/.adapterrc parsing support.
  48         "rpm --eval '%{?_cvsmaildomain}%{!?_cvsmaildomain:@pld-linux.org}'" | getline _cvsmaildomain
  49         "rpm --eval '%{?_cvsmailfeedback}%{!?_cvsmailfeedback:PLD Team <feedback@pld-linux.org>}'" | getline _cvsmailfeedback
  50
  51         # If 1, we are inside of comment block (started with /^#%/)
  52         comment_block = 0
  53
  54         # File with rpm groups
  55         "rpm --eval %_sourcedir" | getline groups_file
  56         groups_file = groups_file "/rpm.groups"
  57         system("cd `rpm --eval %_sourcedir`; [ -f rpm.groups ] || cvs up rpm.groups >/dev/null")
  58         system("[ -d ../PLD-doc ] && cd ../PLD-doc && ([ -f BuildRequires.txt ] || cvs up BuildRequires.txt >/dev/null)");
  59
  60         # Temporary file for changelog section
  61         changelog_file = ENVIRON["HOME"] "/tmp/adapter.changelog"
  62
  63         # Load rpm macros
  64         "rpm --eval %_prefix"   | getline prefix
  65         "rpm --eval %_bindir"   | getline bindir
  66         "rpm --eval %_sbindir"  | getline sbindir
  67         "rpm --eval %_libdir"   | getline libdir
  68         "rpm --eval %_sysconfdir" | getline sysconfdir
  69         "rpm --eval %_datadir"  | getline datadir
  70         "rpm --eval %_includedir" | getline includedir
  71         "rpm --eval %_mandir"   | getline mandir
  72         "rpm --eval %_infodir"  | getline infodir
  73         "rpm --eval %_examplesdir"      | getline examplesdir
  74         "rpm --eval %_defaultdocdir"    | getline docdir
  75         "rpm --eval %_desktopdir" | getline desktopdir
  76         "rpm --eval %_pixmapsdir" | getline pixmapsdir
  77
  78         "rpm --eval %perl_sitearch" | getline perl_sitearch
  79         "rpm --eval %perl_archlib" | getline perl_archlib
  80         "rpm --eval %perl_privlib" | getline perl_privlib
  81         "rpm --eval %perl_vendorlib" | getline perl_vendorlib
  82         "rpm --eval %perl_vendorarch" | getline perl_vendorarch
  83         "rpm --eval %perl_sitelib" | getline perl_sitelib
  84
  85         "rpm --eval %py_sitescriptdir 2>/dev/null" | getline py_sitescriptdir
  86         "rpm --eval %py_sitedir 2>/dev/null" | getline py_sitedir
  87         "rpm --eval %py_scriptdir 2>/dev/null" | getline py_scriptdir
  88
  89         "rpm --eval %ruby_archdir" | getline ruby_archdir
  90         "rpm --eval %ruby_ridir" | getline ruby_ridir
  91         "rpm --eval %ruby_rubylibdir" | getline ruby_rubylibdir
  92         "rpm --eval %ruby_sitearchdir" | getline ruby_sitearchdir
  93         "rpm --eval %ruby_sitelibdir" | getline ruby_sitelibdir
  94
  95         "rpm --eval %php_pear_dir" | getline php_pear_dir
  96         "rpm --eval %tmpdir" | getline tmpdir
  97 }
  98
  99 # There should be a comment with CVS keywords on the first line of file.
 100 FNR == 1 {
 101         if (!/# \$Revision:/)   # If this line is already OK?
 102                 print "# $" "Revision:$, " "$" "Date:$" # No
 103         else {
 104                 print $0                                # Yes
 105                 next            # It is enough for first line
 106         }
 107 }
 108
 109 # If the latest line matched /%files/
 110 defattr == 1 {
 111         if (ENVIRON["SKIP_DEFATTR"] != 1) {
 112                 if ($0 !~ /defattr/) {  # If no %defattr
 113                         print "%defattr(644,root,root,755)"     # Add it
 114                 } else {
 115                         $0 = "%defattr(644,root,root,755)"      # Correct mistakes (if any)
 116                 }
 117         }
 118         defattr = 0
 119 }
 120
 121 function b_makekey(a, b,        s) {
 122         s = a "" b;
 123         # kill bcond
 124     gsub(/[#%]+{[!?]+[_a-zA-Z0-9]+:/, "", s);
 125
 126         # kill commented out items
 127     gsub(/^#[ \t]*/, "", s);
 128
 129         # force order
 130     gsub(/^Summary\(/, "11Summary(", s);
 131     gsub(/^Summary/, "10Summary", s);
 132     gsub(/^Name/, "2Name", s);
 133     gsub(/^Version/, "3Version", s);
 134     gsub(/^Release/, "4Release", s);
 135     gsub(/^Epoch/, "5Epoch", s);
 136     gsub(/^License/, "5License", s);
 137     gsub(/^Group/, "6Group", s);
 138     gsub(/^URL/, "7URL", s);
 139
 140     gsub(/^BuildRequires/, "B1BuildRequires", s);
 141     gsub(/^BuildConflicts/, "B2BuildConflicts", s);
 142     gsub(/^Provides/, "X1Provides", s);
 143     gsub(/^Obsoletes/, "X2Obsoletes", s);
 144     gsub(/^Conflicts/, "X3Conflicts", s);
 145     gsub(/^BuildArch/, "X4BuildArch", s);
 146     gsub(/^ExclusiveArch/, "X6ExclusiveArch", s);
 147     gsub(/^ExcludeArch/, "X7ExcludeArch", s);
 148     gsub(/^BuildRoot/, "X9BuildRoot", s);
 149
 150 #       printf("%s -> %s\n", a""b, s);
 151         return s;
 152 }
 153
 154 # Comments
 155 /^#/ && (description == 0) {
 156         if (/This file does not like to be adapterized!/) {
 157                 print                   # print this message
 158                 while (getline)         # print the rest of spec as it is
 159                         print
 160                 do_not_touch_anything = 1 # do not touch anything in END()
 161                 exit 0
 162         }
 163
 164         # Generally, comments are printed without touching
 165         sub(/[ \t]+$/, "")
 166
 167         if (/Source.*md5/) {
 168                 print $0
 169                 next
 170         }
 171 }
 172
 173 /^%define/ {
 174         # Remove defining _applnkdir (this macro has been included in rpm-3.0.4)
 175         if ($2 == "_applnkdir") {
 176                 next
 177         }
 178         if ($2 == "date") {
 179                 date = 1
 180                 if (did_files == 0) {
 181                         print "%files"
 182                         print ""
 183                         did_files = 1
 184                 }
 185         }
 186
 187         # Do not add %define of _prefix if it already is.
 188         if ($2 ~ /^_prefix/) {
 189                 sub("^"prefix, $3, bindir)
 190                 sub("^"prefix, $3, sbindir)
 191                 sub("^"prefix, $3, libdir)
 192                 sub("^"prefix, $3, datadir)
 193                 sub("^"prefix, $3, includedir)
 194                 prefix = $3
 195         }
 196
 197         if ($2 ~ /_bindir/ && !/_sbindir/)
 198                 bindir = $3
 199         if ($2 ~ /_sbindir/)
 200                 sbindir = $3
 201         if ($2 ~ /_libdir/) {
 202                 if ($3 ~ /^%\(/) {
 203                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 204                         libdir = "%%%%%%%%%%%%%%"
 205                 } else {
 206                         libdir = $3
 207                 }
 208         }
 209         if ($2 ~ /_sysconfdir/) {
 210                 if ($3 ~ /^%\(/) {
 211                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 212                         sysconfdir = "%%%%%%%%%%%%%%"
 213                 } else {
 214                         sysconfdir = $3
 215                 }
 216         }
 217         if ($2 ~ /_datadir/) {
 218                 if ($3 ~ /^%\(/) {
 219                         # TODO: should escape for latter checks like: ($c ~ sysconfdir "/{?cron.")
 220                         datadir = "%%%%%%%%%%%%%%"
 221                 } else {
 222                         datadir = $3
 223                 }
 224         }
 225         if ($2 ~ /_includedir/)
 226                 includedir = $3
 227         if ($2 ~ /_mandir/)
 228                 mandir = $3
 229         if ($2 ~ /_infodir/)
 230                 infodir = $3
 231         if ($2 ~ /_docdir/)
 232                 docdir = $3
 233
 234         # version related macros
 235         if ($2 ~ /^_beta$/)
 236                 _beta = $3
 237         if ($2 ~ /^_rc$/)
 238                 _rc = $3
 239         if ($2 ~ /^_pre$/)
 240                 _pre = $3
 241         if ($2 ~ /^_snap$/)
 242                 _snap = $3
 243
 244         # these are used usually when adapterizing external spec
 245         if ($2 ~ /^name$/)
 246                 name = $3
 247         if ($2 ~ /^version$/)
 248                 version = $3
 249         if ($2 ~ /^release$/)
 250                 release = $3
 251
 252         if ($2 ~ /^mod_name$/)
 253                 mod_name = $3
 254
 255         sub(/[ \t]+$/, "");
 256         # do nothing further, otherwise adapter thinks we're at preamble
 257         print
 258         next
 259 }
 260
 261 # Obsolete
 262 /^%include.*\/usr\/lib\/rpm\/macros\.python$/ {
 263         next
 264 }
 265
 266 ################
 267 # %description #
 268 ################
 269 /^%description/, (!/^%description/ && $0 ~ SECTIONS) {
 270         preamble = 0
 271
 272         if (/^%description/) {
 273                 bod++
 274                 format_line = ""
 275                 format_indent = -1
 276         }
 277
 278         # Format description
 279         if (ENVIRON["SKIP_DESC"] != 1 && description == 1 && !/^%[a-z]+/ && !/^%description/) {
 280                 if (/^[ \t]*$/) {
 281                         format_flush(format_line, format_indent)
 282                         print ""
 283                         format_line = ""
 284                         format_indent = -1
 285                 } else if (/^[ \t]*[-\*][ \t]*/) {
 286                         format_flush(format_line, format_indent)
 287                         match($0, /^[ \t]*/)
 288                         format_indent = RLENGTH
 289                         match($0, /^[ \t]*[-\*][ \t]/)
 290                         format_line = substr($0, RLENGTH)
 291                 } else
 292                         format_line = format_line " " $0
 293                 next
 294         }
 295
 296         if (/^%[a-z]+/ && (!/^%description/ || bod == 2)) {
 297                 if (NF > 3 && $2 == "-l") {
 298                         ll = $1
 299                         for (i = 4; i <= NF; i++)
 300                                 ll = ll " " $i
 301                         $0 = ll " -l " $3
 302                 }
 303                 format_flush(format_line, format_indent)
 304                 if (bod == 2) {
 305                         bod = 1
 306                         description = 1
 307                 } else {
 308                         bod = 0
 309                         description = 0
 310                 }
 311         } else
 312                 description = 1
 313 }
 314
 315 #########
 316 # %prep #
 317 #########
 318 /^%prep/, (!/^%prep/ && $0 ~ SECTIONS) {
 319         preamble = 0
 320         did_prep = 1
 321
 322         use_macros()
 323
 324         # Add '-q' to %setup
 325         if (/^%setup/ && !/-q/) {
 326                 sub(/^%setup/, "%setup -q")
 327         }
 328
 329         if (/^%setup/ && name != "setup") {
 330                 $0 = fixedsub(name, "%{name}", $0);
 331                 $0 = fixedsub(version, "%{version}", $0);
 332                 if (_beta) {
 333                         $0 = fixedsub(_beta, "%{_beta}", $0);
 334                 }
 335                 if (_rc) {
 336                         $0 = fixedsub(_rc, "%{_rc}", $0);
 337                 }
 338                 if (_pre) {
 339                         $0 = fixedsub(_pre, "%{_pre}", $0);
 340                 }
 341                 if (_snap) {
 342                         $0 = fixedsub(_snap, "%{_snap}", $0);
 343                 }
 344         }
 345
 346         if (/^%setup/ && /-n %{name}-%{version}( |$)/) {
 347                 $0 = fixedsub(" -n %{name}-%{version}", "", $0)
 348         }
 349     sub("^%patch ", "%patch0 ");
 350
 351         # invalid in %prep
 352         sub("^rm -rf \$RPM_BUILD_ROOT.*", "");
 353 }
 354
 355 ##########
 356 # %build #
 357 ##########
 358 /^%build/, (!/^%build/ && $0 ~ SECTIONS) {
 359         preamble = 0
 360
 361         if (did_prep == 0) {
 362                 print "%prep"
 363                 print ""
 364                 did_prep = 1
 365         }
 366
 367         use_macros()
 368         use_tabs()
 369
 370         if (/^automake$/)
 371                 sub(/$/, " -a -c")
 372
 373         if (/LDFLAGS/) {
 374                 if (/LDFLAGS="-s"/) {
 375                         removed["LDFLAGS"] = 1
 376                         next
 377                 } else {
 378                         split($0, tmp, "LDFLAGS=")
 379                         count = split(tmp[2], flags, "\"")
 380                         if (flags[1] != "" && flags[1] !~ "!?debug") {
 381                                 sub(/-s[" ]?/, "%{rpmldflags} ", flags[1])
 382                                 $0 = tmp[1] line[1] "LDFLAGS=" flags[1] "\""
 383                                 for (i = 2; i < count; i++)
 384                                         $0 = $0 flags[i] "\""
 385                         }
 386                 }
 387         }
 388
 389         if (/CFLAGS=/)
 390                 if (cflags("CFLAGS") == 0)
 391                         next
 392
 393         if (/CXXFLAGS=/)
 394                 if (cflags("CXXFLAGS") == 0)
 395                         next
 396
 397         if (/^export /) {
 398                 if (removed["LDFLAGS"])
 399                         sub(" LDFLAGS", "")
 400                 if (removed["CFLAGS"])
 401                         sub(" CFLAGS", "")
 402                 if (removed["CXXFLAGS"])
 403                         sub(" CXXFLAGS", "")
 404                 # Is there still something?
 405                 if (/^export[ ]*$/)
 406                         next
 407         }
 408
 409         # quote CC
 410         if (/CC=%{__cc} /) {
 411                 sub("CC=%{__cc}", "CC=\"%{__cc}\"")
 412         }
 413
 414         # use PLD Linux macros
 415         $0 = fixedsub("glib-gettextize --copy --force","%{__glib_gettextize}", $0);
 416         $0 = fixedsub("intltoolize --copy --force", "%{__intltoolize}", $0);
 417         $0 = fixedsub("automake --add-missing --copy", "%{__automake}", $0);
 418         $0 = fixedsub("automake -a --foreign --copy", "%{__automake}", $0);
 419         $0 = fixedsub("automake -a -c --foreign", "%{__automake}", $0);
 420         $0 = fixedsub("libtoolize --force --automake --copy", "%{__libtoolize}", $0);
 421         $0 = fixedsub("libtoolize -c -f --automake", "%{__libtoolize}", $0);
 422
 423         sub(/^aclocal$/, "%{__aclocal}");
 424         sub(/^autoheader$/, "%{__autoheader}");
 425         sub(/^autoconf$/, "%{__autoconf}");
 426         sub(/^automake$/, "%{__automake}");
 427
 428         # atrpms
 429         $0 = fixedsub("%perl_configure", "%{__perl} Makefile.PL \\\n\tINSTALLDIRS=vendor", $0);
 430         $0 = fixedsub("%perl_makecheck", "%{?with_tests:%{__make} test}", $0);
 431 }
 432
 433 ##########
 434 # %clean #
 435 ##########
 436 /^%clean/, (!/^%clean/ && $0 ~ SECTIONS) {
 437         did_clean = 1
 438
 439     use_macros()
 440 }
 441
 442 ############
 443 # %install #
 444 ############
 445 /^%install/, (!/^%install/ && $0 ~ SECTIONS) {
 446
 447         preamble = 0
 448
 449         # foreign rpms
 450         sub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
 451     sub("%buildroot", "$RPM_BUILD_ROOT");
 452     sub("%{buildroot}", "$RPM_BUILD_ROOT");
 453
 454         if (/^[ \t]*rm([ \t]+-[rf]+)*[ \t]+(\${?RPM_BUILD_ROOT}?|%{?buildroot}?)/ && did_rmroot==0) {
 455                 did_rmroot=1
 456                 print "rm -rf $RPM_BUILD_ROOT"
 457                 next
 458         }
 459
 460         if (!/^(#?[ \t]*)$/ && !/^%install/ && did_rmroot==0) {
 461                 print "rm -rf $RPM_BUILD_ROOT"
 462                 did_rmroot=1
 463         }
 464
 465     if (tmpdir) {
 466         buildroot = tmpdir "/" name "-" version "-root-" ENVIRON["USER"]
 467                 gsub(buildroot, "$RPM_BUILD_ROOT")
 468     }
 469
 470     if (!/%{_lib}/) {
 471         sub("\$RPM_BUILD_ROOT/%", "$RPM_BUILD_ROOT%")
 472     }
 473
 474         use_macros()
 475
 476         # 'install -d' instead 'mkdir -p'
 477         if (/mkdir -p/)
 478                 sub(/mkdir -p/, "install -d")
 479
 480         # cp -a already implies cp -r
 481     sub(/^cp -ar/, "cp -a")
 482
 483         # No '-u root' or '-g root' for 'install'
 484         if (/^install/ && /-[ug][ \t]*root/)
 485                 gsub(/-[ug][ \t]*root /, "")
 486
 487         if (/^install/ && /-m[ \t]*[0-9]+/)
 488                 gsub(/-m[ \t]*[0-9]+ /, "")
 489
 490         # No lines contain 'chown' or 'chgrp' if owner/group is 'root'
 491         if (($1 ~ /chown/ && $2 ~ /root\.root/) || ($1 ~ /chgrp/ && $2 ~ /root/))
 492                 next
 493
 494         # No lines contain 'chmod' if it sets the modes to '644'
 495         if ($1 ~ /chmod/ && $2 ~ /644/)
 496                 next
 497
 498         # atrpms
 499         $0 = fixedsub("%perl_makeinstall", "%{__make} pure_install \\\n\tDESTDIR=$RPM_BUILD_ROOT", $0);
 500 }
 501
 502 ##########
 503 # %files #
 504 ##########
 505 /^%files/, (!/^%files/ && $0 ~ SECTIONS) {
 506         preamble = 0
 507         did_files = 1
 508
 509         if ($0 ~ /^%files/)
 510                 defattr = 1
 511
 512         use_files_macros()
 513 }
 514
 515 ##############
 516 # %changelog #
 517 ##############
 518 /^%changelog/, (!/^%changelog/ && $0 ~ SECTIONS) {
 519         preamble = 0
 520         has_changelog = 1
 521         skip = 0
 522         # There should be some CVS keywords on the first line of %changelog.
 523         if (boc == 3) {
 524                 if ($0 !~ _cvsmailfeedback)
 525                         print "* %{date} " _cvsmailfeedback > changelog_file
 526                 else
 527                         skip = 1
 528                 boc = 2
 529         }
 530         if (boc == 2 && !skip) {
 531                 if (!/All persons listed below/) {
 532                         printf "All persons listed below can be reached at " > changelog_file
 533                         print "<cvs_login>" _cvsmaildomain "\n" > changelog_file
 534                 } else
 535                         skip = 1
 536                 boc = 1
 537         }
 538         if (boc == 1 && !skip) {
 539                 if (!/^$/) {
 540                         if (!/\$.*Log:.*\$/)
 541                                 print "$" "Log:$" > changelog_file
 542                         boc = 0
 543                 }
 544         }
 545         # Define date macro.
 546         if (boc == 4) {
 547                 if (date == 0) {
 548                         printf "%%define date\t%%(echo `LC_ALL=\"C\"" > changelog_file
 549                         print " date +\"%a %b %d %Y\"`)" > changelog_file
 550                         date = 1
 551                 }
 552                 boc = 3
 553         }
 554
 555         sub(/[ \t]+$/, "")
 556         if (!/^%[a-z]+$/ || /changelog/)
 557                 print > changelog_file
 558         else
 559                 print
 560         next
 561 }
 562
 563 ###########
 564 # SCRIPTS #
 565 ###########
 566 /^%pre/, (!/^%pre/ && $0 ~ SECTIONS) {
 567         preamble = 0
 568
 569         if (gsub("/usr/sbin/useradd", "%useradd")) {
 570                 sub(" 2> /dev/null \|\| :", "");
 571                 sub(" >/dev/null 2>&1 \|\|:", "");
 572         }
 573
 574         # %useradd and %groupadd may not be wrapped
 575         if (/%(useradd|groupadd).*\\$/) {
 576                 a = $0; getline;
 577                 sub(/^[\s\t]*/, "");
 578                 $0 = substr(a, 1, length(a) - 1) $0;
 579         }
 580         use_script_macros()
 581 }
 582
 583 /^%post/, (!/^%post/ && $0 ~ SECTIONS) {
 584         preamble = 0
 585         use_macros()
 586 }
 587 /^%preun/, (!/^%preun/ && $0 ~ SECTIONS) {
 588         preamble = 0
 589         use_script_macros()
 590 }
 591 /^%postun/, (!/^%postun/ && $0 ~ SECTIONS) {
 592         preamble = 0
 593         use_script_macros()
 594 }
 595 /^%triggerin/, (!/^%triggerin/ && $0 ~ SECTIONS) {
 596         preamble = 0
 597         use_script_macros()
 598 }
 599 /^%triggerun/, (!/^%triggerun/ && $0 ~ SECTIONS) {
 600         preamble = 0
 601         use_script_macros()
 602 }
 603 /^%triggerpostun/, (!/^%triggerpostun/ && $0 ~ SECTIONS) {
 604         preamble = 0
 605         use_script_macros()
 606 }
 607 /^%pretrans/, (!/^%pretrans/ && $0 ~ SECTIONS) {
 608         preamble = 0
 609         use_script_macros()
 610 }
 611 /^%posttrans/, (!/^%posttrans/ && $0 ~ SECTIONS) {
 612         preamble = 0
 613         use_script_macros()
 614 }
 615 /^%verifyscript/, (!/^%verifyscript/ && $0 ~ SECTIONS) {
 616         preamble = 0
 617         use_script_macros()
 618 }
 619 /^%check/, (!/^%check/ && $0 ~ SECTIONS) {
 620         preamble = 0
 621         use_script_macros()
 622 }
 623
 624 #############
 625 # PREAMBLES #
 626 #############
 627 preamble == 1 {
 628         # There should not be a space after the name of field
 629         # and before the colon.
 630         sub(/[ \t]*:/, ":")
 631
 632         if (/^%perl_module_wo_prefix/) {
 633                 name = $2
 634                 version = $3
 635                 release = "0." fixedsub(".%{disttag}.at", "", $4)
 636         }
 637
 638         field = tolower($1)
 639         fieldnlower = $1
 640         if (field ~ /summary:/ && !/etc\.$/) {
 641                 sub(/\.$/, "", $0);
 642         }
 643         if (field ~ /group(\([^)]+\)):/)
 644                 next
 645         if (field ~ /group:/) {
 646                 format_preamble()
 647                 group = $0;
 648                 sub(/^[^ \t]*[ \t]*/, "", group);
 649
 650                 sub(/^Utilities\//,"Applications/", group)
 651                 sub(/^Games/,"Applications/Games", group)
 652                 sub(/^X11\/Games/,"X11/Applications/Games", group)
 653                 sub(/^X11\/GNOME\/Development\/Libraries/,"X11/Development/Libraries", group)
 654                 sub(/^X11\/GNOME\/Applications/,"X11/Applications", group)
 655                 sub(/^X11\/GNOME/,"X11/Applications", group)
 656                 sub(/^X11\/Utilities/,"X11/Applications", group)
 657                 sub(/^X11\/Games\/Strategy/,"X11/Applications/Games/Strategy", group)
 658                 sub(/^X11\/Library/,"X11/Libraries", group)
 659                 sub(/^Shells/,"Applications/Shells", group)
 660                 sub(/^System Environment\/Libraries$/, "Libraries", group)
 661                 sub(/^Library\/Development$/, "Development/Libraries", group)
 662                 sub(/^System Environment\/Daemons$/, "Daemons", group)
 663                 sub(/^Applications\/Internet$/, "Applications/Networking", group)
 664                 sub(/^Applications\/Daemons$/, "Daemons", group)
 665                 sub(/^Application\/Multimedia$/, "Applications/Multimedia", group)
 666                 sub(/^System\/Servers$/, "Daemons", group)
 667                 sub(/^X11\/Xserver$/, "X11/Servers", group)
 668                 sub(/^X11\/XFree86/, "X11", group)
 669                 sub(/^Applications\/Compilers$/, "Development/Languages", group)
 670                 sub(/^Applications\/Internet\/Peer to Peer/, "Applications/Networking", group)
 671                 sub(/^Networking\/Deamons$/, "Networking/Daemons", group)
 672                 sub(/^Development\/Docs$/, "Documentation", group)
 673                 sub(/^Development\/Documentation$/, "Documentation", group)
 674                 sub(/^System Environment\/Kernel$/, "Base/Kernel", group)
 675                 sub(/^Development\/Libraries\/Java$/, "Development/Languages/Java", group)
 676                 sub(/^Development\/Java/, "Development/Languages/Java", group)
 677                 sub(/^Development\/Testing$/, "Development", group)
 678                 sub(/^Text Processing\/Markup\/HTML$/, "Applications/Text", group)
 679                 sub(/^Text Processing\/Markup\/XML$/, "Applications/Text", group)
 680                 sub(/^Web\/Database$/, "Applications/WWW", group)
 681                 sub(/^System Environment\/Base$/, "Base", group)
 682
 683                 $0 = "Group:\t\t" group
 684
 685                 if (group ~ /^X11/ && x11 == 0) # Is it X11 application?
 686                         x11 = 1
 687
 688                 byl_plik_z_groupmi = 0
 689                 byl_opis_grupy = 0
 690                 while ((getline linia_grup < groups_file) > 0) {
 691                         byl_plik_z_groupmi = 1
 692                         if (linia_grup == group) {
 693                                 byl_opis_grupy = 1
 694                                 break
 695                         }
 696                 }
 697
 698                 if (!byl_plik_z_groupmi)
 699                         print "######\t\t" groups_file ": no such file"
 700                 else if (!byl_opis_grupy)
 701                         print "######\t\t" "Unknown group!"
 702
 703                 close(groups_file)
 704                 did_groups = 1
 705         }
 706
 707         if (field ~ /prereq:/) {
 708                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 709         }
 710
 711         # split (build)requires, obsoletes on commas
 712         if (field ~ /(obsoletes|requires|provides|conflicts):/ && NF > 2) {
 713                 value = substr($0, index($0, $2));
 714                 $0 = format_requires($1, value);
 715         }
 716
 717         # BR: tar (and others) is to common (rpm-build requires it)
 718         if (field ~ /^buildrequires:/) {
 719                 l = substr($0, index($0, $2));
 720                 if (l == "awk" ||
 721                         l == "binutils" ||
 722                         l == "bzip2" ||
 723                         l == "cpio" ||
 724                         l == "diffutils" ||
 725                         l == "elfutils" ||
 726                         l == "fileutils" ||
 727                         l == "findutils" ||
 728                         l == "glibc-devel" ||
 729                         l == "grep" ||
 730                         l == "gzip" ||
 731                         l == "make" ||
 732                         l == "patch" ||
 733                         l == "sed" ||
 734                         l == "sh-utils" ||
 735                         l == "tar" ||
 736                         l == "textutils") {
 737                         next
 738                 }
 739
 740         # perhaps we have common known name?
 741
 742         # jpackages
 743                 sub(/^java-devel$/, "jdk", $2);
 744                 sub(/^log4j$/, "jakarta-log4j", $2);
 745                 sub(/^oro$/, "jakarta-oro", $2);
 746                 sub(/^xerces-j2$/, "xerces-j", $2);
 747                 sub(/^ant-junit$/, "jakarta-ant", $2);
 748                 sub(/^ldapjdk$/, "ldapsdk", $2);
 749                 sub(/^saxon-scripts$/, "saxon", $2);
 750
 751         replace_php_virtual_deps();
 752         }
 753
 754         if (field ~ /^requires:/) {
 755         replace_php_virtual_deps();
 756     }
 757
 758
 759         # obsolete/unwanted tags
 760         if (field ~ /vendor:|packager:|distribution:|docdir:|prefix:|icon:|author:|author-email:|metadata-version:/) {
 761                 next
 762         }
 763
 764         if (field ~ /buildroot:/) {
 765                 $0 = $1 "%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 766                 did_build_root = 1
 767         }
 768
 769         # Use "License" instead of "Copyright" if it is (L)GPL or BSD
 770         if (field ~ /copyright:/ && $2 ~ /GPL|BSD/) {
 771                 $1 = "License:"
 772         }
 773
 774         if (field ~ /license:/) {
 775                 l = substr($0, index($0, $2));
 776                 if (l == "Python Software Foundation License") {
 777                         l = "PSF"
 778                 }
 779                 $0 = "License:\t" l;
 780         }
 781
 782
 783         if (field ~ /name:/) {
 784                 if ($2 == "%{name}" && name) {
 785                         $2 = name
 786                 }
 787                 name = $2
 788                 name_seen = 1;
 789         }
 790
 791         if (field ~ /version:/) {
 792                 if ($2 == "%{version}" && version) {
 793                         $2 = version
 794                 }
 795                 version = $2
 796                 version_seen = 1;
 797         }
 798
 799         if (field ~ /release:/) {
 800                 if ($2 == "%{release}" && release) {
 801                         $2 = release
 802                 }
 803                 sub(/%atrelease /, "0.", $0)
 804                 release = $2
 805                 release_seen = 1;
 806         }
 807
 808
 809         if (field ~ /serial:/)
 810                 $1 = "Epoch:"
 811
 812         if (field ~ /home-page:/)
 813                 $1 = "URL:"
 814
 815         # proper caps
 816         if (field ~ /^url:$/)
 817                 $1 = "URL:"
 818
 819         if (field ~ /^description:$/)
 820                 $1 = "\n%description\n"
 821
 822         # Use %{name} and %{version} in the filenames in "Source:"
 823         if (field ~ /^source/ || field ~ /patch/) {
 824                 n = split($2, url, /\//)
 825                 if (url[n] ~ /\.gz$/) {
 826                         url[n+1] = ".gz" url[n+1]
 827                         sub(/\.gz$/,"",url[n])
 828                 }
 829                 if (url[n] ~ /\.zip$/) {
 830                         url[n+1] = ".zip" url[n+1]
 831                         sub(/\.zip$/,"",url[n])
 832                 }
 833                 if (url[n] ~ /\.tar$/) {
 834                         url[n+1] = ".tar" url[n+1]
 835                         sub(/\.tar$/,"",url[n])
 836                 }
 837                 if (url[n] ~ /\.patch$/) {
 838                         url[n+1] = ".patch" url[n+1]
 839                         sub(/\.patch$/,"",url[n])
 840                 }
 841                 if (url[n] ~ /\.bz2$/) {
 842                         url[n+1] = ".bz2" url[n+1]
 843                         sub(/\.bz2$/,"",url[n])
 844                 }
 845                 if (url[n] ~ /\.logrotate$/) {
 846                         url[n+1] = ".logrotate" url[n+1]
 847                         sub(/\.logrotate$/,"",url[n])
 848                 }
 849                 if (url[n] ~ /\.pamd$/) {
 850                         url[n+1] = ".pamd" url[n+1]
 851                         sub(/\.pamd$/,"",url[n])
 852                 }
 853
 854                 # allow %{name} only in last url component
 855                 s = ""
 856                 for (i = 1; i <= n; i++) {
 857                         url[i] = fixedsub("%{name}", name, url[i])
 858                         if (s) {
 859                                 s = s "/" url[i]
 860                         } else {
 861                                 s = url[i]
 862                         }
 863                 }
 864                 $2 = s url[n+1]
 865
 866                 filename = url[n]
 867                 if (name) {
 868                         url[n] = fixedsub(name, "%{name}", url[n])
 869                 }
 870                 if (field ~ /source/) {
 871                         if (version) {
 872                                 url[n] = fixedsub(version, "%{version}", url[n])
 873                         }
 874                         if (_beta) {
 875                                 url[n] = fixedsub(_beta, "%{_beta}", url[n])
 876                         }
 877                         if (_rc) {
 878                                 url[n] = fixedsub(_rc, "%{_rc}", url[n])
 879                         }
 880                         if (_pre) {
 881                                 url[n] = fixedsub(_pre, "%{_pre}", url[n])
 882                         }
 883                         if (_snap) {
 884                                 url[n] = fixedsub(_snap, "%{_snap}", url[n])
 885                         }
 886                 }
 887                 # assigning to $2 kills preamble formatting
 888                 $2 = fixedsub(filename, url[n], $2)
 889
 890                 # sourceforge urls
 891                 sub("[?&]big_mirror=.*$", "", $2);
 892                 sub("[?&]modtime=.*$", "", $2);
 893
 894                 sub("[?]use_mirror=.*$", "", $2);
 895                 sub("[?]download$", "", $2);
 896
 897                 sub("^http://prdownloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 898                 sub("^http://download\.sf\.net/", "http://dl.sourceforge.net/", $2)
 899                 sub("^http://downloads\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 900
 901                 sub("^http://.*\.dl\.sourceforge\.net/", "http://dl.sourceforge.net/", $2)
 902                 sub("^http://dl\.sourceforge\.net/sourceforge/", "http://dl.sourceforge.net/", $2)
 903                 sub("^http://dl\.sf\.net/", "http://dl.sourceforge.net/", $2)
 904         }
 905
 906
 907         if (field ~ /^source:/)
 908                 $1 = "Source0:"
 909
 910         if (field ~ /^patch:/)
 911                 $1 = "Patch0:"
 912
 913         kill_preamble_macros();
 914         format_preamble()
 915
 916         if (field ~ /requires/) {
 917                 # atrpms
 918                 $0 = fixedsub("%{eversion}", "%{epoch}:%{version}-%{release}", $0);
 919         }
 920 }
 921
 922 /^%bcond_/ {
 923         # do nothing
 924         print
 925         next
 926 }
 927
 928 # sort BR/R!
 929 #
 930 # NOTES:
 931 # - mixing BR/R and anything else confuses this (all will be sorted together)
 932 #   so don't do that.
 933 # - comments leading the BR/R can not be associated,
 934 #   so don't adapterize when the BR/R are mixed with comments
 935 ENVIRON["SKIP_SORTBR"] != 1 && preamble == 1 && $0 ~ PREAMBLE_TAGS, $0 ~ PREAMBLE_TAGS {
 936         if ($1 ~ /Pre[Rr]eq:/) {
 937                 sub(/Pre[Rr]eq:/, "Requires:", $1);
 938         }
 939         format_preamble()
 940 #       kill_preamble_macros(); # breaks tabbing
 941
 942         b_idx++;
 943         l = substr($0, index($0, $2));
 944         b_ktmp = b_makekey($1, l);
 945         b_key[b_idx] = b_ktmp;
 946         b_val[b_ktmp] = $0;
 947
 948         next;
 949 }
 950
 951 preamble == 1 {
 952         if (b_idx > 0) {
 953                 isort(b_key, b_idx);
 954                 for (i = 1; i <= b_idx; i++) {
 955                         v = b_val[b_key[i]];
 956                         sub(/[ \t]+$/, "", v);
 957                         print "" v;
 958                 }
 959                 b_idx = 0
 960         }
 961 }
 962
 963 # main() ;-)
 964 {
 965         preamble = 1
 966
 967         sub(/[ \t]+$/, "")
 968         print
 969
 970         if (name_seen == 0 && name) {
 971                 print "Name:\t\t" name
 972                 name_seen = 1
 973         }
 974
 975         if (version_seen == 0 && version) {
 976                 print "Version:\t" version
 977                 version_seen = 1
 978         }
 979
 980         if (release_seen == 0 && release) {
 981                 print "Release:\t" release
 982                 release_seen = 1
 983         }
 984
 985         if (did_build_root == 0) {
 986 #               print "BuildRoot:\t%{tmpdir}/%{name}-%{version}-root-%(id -u -n)"
 987                 did_build_root = 1
 988         }
 989         if (did_groups == 0) {
 990 #               print "Group:\t\tunknown"
 991                 did_groups = 1
 992         }
 993 }
 994
 995
 996 END {
 997         if (do_not_touch_anything)
 998                 exit 0
 999
1000     # TODO: need to output these in proper place
1001     if (BR_count > 0) {
1002         for (i = 0; i <= BR_count; i++) {
1003             print BR[i];
1004         }
1005     }
1006
1007         close(changelog_file)
1008         while ((getline < changelog_file) > 0)
1009                 print
1010         system("rm -f " changelog_file)
1011
1012         if (did_clean == 0) {
1013                 print ""
1014                 print "%clean"
1015                 print "rm -rf $RPM_BUILD_ROOT"
1016         }
1017
1018         if (date == 0) {
1019                 print ""
1020                 print "%define date\t%(echo `LC_ALL=\"C\" date +\"%a %b %d %Y\"`)"
1021         }
1022
1023         if (has_changelog == 0) {
1024                 print "%changelog"
1025     }
1026
1027         if (boc > 2) {
1028                 print "* %{date} PLD Team <feedback@pld-linux.org>"
1029     }
1030         if (boc > 1) {
1031                 printf "All persons listed below can be reached at "
1032                 print "<cvs_login>@pld-linux.org\n"
1033         }
1034         if (boc > 0) {
1035                 print "$" "Log:$"
1036     }
1037 }
1038
1039 function fixedsub(s1,s2,t, ind) {
1040 # substitutes fixed strings (not regexps)
1041         if (ind = index(t,s1))
1042                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
1043         return t
1044 }
1045
1046 # There should be one or two tabs after the colon.
1047 function format_preamble()
1048 {
1049         if (/^#/ || /^%bcond_with/) {
1050                 return;
1051         }
1052         sub(/:[ \t]*/, ":")
1053         if (match($0, /[A-Za-z0-9(),#_ \t]+[ \t]*:[ \t]*/) == 1) {
1054                 if (RLENGTH < 8)
1055                         sub(/:/, ":\t\t")
1056                 else
1057                         sub(/:/, ":\t")
1058         }
1059 }
1060
1061 # Replace directly specified directories with macros
1062 function use_macros()
1063 {
1064         # -m, --skip-macros, --no-macros -- skip macros subst
1065         if (ENVIRON["SKIP_MACROS"]) {
1066                 return
1067         }
1068
1069         # leave inline sed lines alone
1070         if (/(%{__sed}|sed) -i -e/) {
1071                 return;
1072         }
1073
1074     sub("%{_defaultdocdir}", "%{_docdir}");
1075     sub("%{_bindir}/perl", "%{__perl}");
1076     sub("%{_bindir}/python", "%{__python}");
1077
1078         gsub(infodir, "%{_infodir}")
1079
1080         gsub(perl_sitearch, "%{perl_sitearch}")
1081         gsub(perl_archlib, "%{perl_archlib}")
1082         gsub(perl_privlib, "%{perl_privlib}")
1083         gsub(perl_vendorlib, "%{perl_vendorlib}")
1084         gsub(perl_vendorarch, "%{perl_vendorarch}")
1085         gsub(perl_sitelib, "%{perl_sitelib}")
1086
1087         gsub(py_sitescriptdir, "%{py_sitescriptdir}")
1088         gsub(py_sitedir, "%{py_sitedir}")
1089         gsub(py_scriptdir, "%{py_scriptdir}")
1090         gsub("%{_libdir}/python2.4/site-packages", "%{py_sitedir}")
1091         gsub("%{python_sitelib}", "%{py_sitedir}")
1092
1093         gsub(ruby_archdir, "%{ruby_archdir}")
1094         gsub(ruby_ridir, "%{ruby_ridir}")
1095         gsub(ruby_rubylibdir, "%{ruby_rubylibdir}")
1096         gsub(ruby_sitearchdir, "%{ruby_sitearchdir}")
1097         gsub(ruby_sitelibdir, "%{ruby_sitelibdir}")
1098
1099         gsub("%{_datadir}/applications", "%{_desktopdir}")
1100         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}")
1101
1102         gsub(bindir, "%{_bindir}")
1103         gsub("%{prefix}/bin", "%{_bindir}")
1104         if (prefix"/bin" == bindir)
1105                 gsub("%{_prefix}/bin", "%{_bindir}")
1106
1107         for (c = 1; c <= NF; c++) {
1108                 if ($c ~ sbindir "/fix-info-dir")
1109                         continue;
1110                 if ($c ~ sbindir "/webapp")
1111                         continue;
1112                 if ($c ~ sbindir "/ldconfig")
1113                         continue;
1114                 if ($c ~ sbindir "/chsh")
1115                         continue;
1116                 if ($c ~ sbindir "/usermod")
1117                         continue;
1118                 if ($c ~ sbindir "/chkconfig")
1119                         continue;
1120                 if ($c ~ sbindir "/installzope(product|3package)")
1121                         continue;
1122                 gsub(sbindir, "%{_sbindir}", $c)
1123         }
1124
1125         gsub("%{prefix}/sbin", "%{_sbindir}")
1126         if (prefix"/sbin" == sbindir) {
1127                 gsub("%{_prefix}/sbin", "%{_sbindir}")
1128         }
1129
1130         for (c = 1; c <= NF; c++) {
1131                 if ($c ~ sysconfdir "/{?cron.")
1132                         continue;
1133                 if ($c ~ sysconfdir "/{?crontab.d")
1134                         continue;
1135                 if ($c ~ sysconfdir "/{?env.d")
1136                         continue;
1137                 if ($c ~ sysconfdir "/{?modprobe.(d|conf)")
1138                         continue;
1139                 if ($c ~ sysconfdir "/{?udev/rules.d")
1140                         continue;
1141                 if ($c ~ sysconfdir "/{?logrotate.d")
1142                         continue;
1143                 if ($c ~ sysconfdir "/{?pam.d")
1144                         continue;
1145                 if ($c ~ sysconfdir "/{?profile.d")
1146                         continue;
1147                 if ($c ~ sysconfdir "/{?rc.d")
1148                         continue;
1149                 if ($c ~ sysconfdir "/{?security")
1150                         continue;
1151                 if ($c ~ sysconfdir "/{?skel")
1152                         continue;
1153                 if ($c ~ sysconfdir "/{?sysconfig")
1154                         continue;
1155                 if ($c ~ sysconfdir "/{?shrc.d")
1156                         continue;
1157                 if ($c ~ sysconfdir "/{?certs")
1158                         continue;
1159                 if ($c ~ sysconfdir "/{?X11")
1160                         continue;
1161                 if ($c ~ sysconfdir "/{?ld.so.conf.d")
1162                         continue;
1163                 if ($c ~ sysconfdir "/{?rpm")
1164                         continue;
1165                 if ($c ~ sysconfdir "/{?bash_completion.d")
1166                         continue;
1167                 if ($c ~ sysconfdir "/{?samba")
1168                         continue;
1169                 if ($c ~ sysconfdir "/shells")
1170                         continue;
1171                 gsub(sysconfdir, "%{_sysconfdir}", $c)
1172         }
1173
1174         gsub(docdir, "%{_docdir}")
1175         gsub(php_pear_dir, "%{php_pear_dir}")
1176
1177         for (c = 1; c <= NF; c++) {
1178                 if ($c ~ datadir "/automake")
1179                         continue;
1180                 if ($c ~ datadir "/unsermake")
1181                         continue;
1182                 if ($c ~ datadir "/file/magic.mime")
1183                         continue;
1184                 gsub(datadir, "%{_datadir}", $c)
1185         }
1186
1187         gsub("%{prefix}/share", "%{_datadir}")
1188         if (prefix"/share" == datadir)
1189                 gsub("%{_prefix}/share", "%{_datadir}")
1190
1191         # CFLAGS="-I/usr/include/ncurses is usually correct.
1192         if (!/-I\/usr\/include/) {
1193                 gsub(includedir, "%{_includedir}")
1194         }
1195
1196         gsub("%{prefix}/include", "%{_includedir}")
1197         if (prefix"/include" == includedir) {
1198                 gsub("%{_prefix}/include", "%{_includedir}")
1199         }
1200
1201         gsub(mandir, "%{_mandir}")
1202         if ($0 !~ "%{_datadir}/manual") {
1203                 gsub("%{_datadir}/man", "%{_mandir}")
1204         }
1205         gsub("%{_prefix}/share/man", "%{_mandir}")
1206         gsub("%{prefix}/share/man", "%{_mandir}")
1207         gsub("%{prefix}/man", "%{_mandir}")
1208         gsub("%{_prefix}/man", "%{_mandir}")
1209
1210         gsub(infodir, "%{_infodir}")
1211         gsub("%{prefix}/info", "%{_infodir}")
1212         gsub("%{_prefix}/info", "%{_infodir}")
1213
1214         if (prefix !~ "/X11R6") {
1215                 gsub("%{_datadir}/aclocal", "%{_aclocaldir}")
1216         }
1217
1218         gsub(examplesdir, "%{_examplesdir}")
1219
1220         if (prefix != "/") {
1221                 # leave --with-foo=/usr alone
1222                 if ($0 !~ "--with.*=.*" prefix) {
1223                         for (c = 1; c <= NF; c++) {
1224                                 if ($c ~ prefix "/sbin/fix-info-dir")
1225                                         continue;
1226                                 if ($c ~ prefix "/sbin/webapp")
1227                                         continue;
1228                                 if ($c ~ prefix "/sbin/chsh")
1229                                         continue;
1230                                 if ($c ~ prefix "/sbin/usermod")
1231                                         continue;
1232                                 if ($c ~ prefix "/sbin/installzope(product|3package)")
1233                                         continue;
1234                                 if ($c ~ prefix "/share/automake")
1235                                         continue;
1236                                 if ($c ~ prefix "/share/unsermake")
1237                                         continue;
1238                                 if ($c ~ prefix "/lib/sendmail")
1239                                         continue;
1240                                 if ($c ~ prefix "/lib/pkgconfig")
1241                                         continue;
1242
1243                                 # CFLAGS="-I/usr..." is usually correct.
1244                                 if (/-I\/usr/)
1245                                         continue;
1246                                 # same for LDFLAGS="-L/usr..."
1247                                 if (/-L\/usr/)
1248                                         continue;
1249
1250                                 gsub(prefix, "%{_prefix}", $c)
1251                         }
1252                 }
1253                 gsub("%{prefix}", "%{_prefix}")
1254         }
1255
1256         # replace back
1257         gsub("%{_includedir}/ncurses", "/usr/include/ncurses")
1258         gsub("%{_includedir}/freetype", "/usr/include/freetype")
1259
1260         gsub("%{PACKAGE_VERSION}", "%{version}")
1261         gsub("%{PACKAGE_NAME}", "%{name}")
1262
1263         gsub("^make$", "%{__make}")
1264         gsub("^make ", "%{__make} ")
1265         gsub("^gcc ", "%{__cc} ")
1266
1267         # mandrake specs
1268         gsub("^%make$", "%{__make}")
1269         gsub("^%make ", "%{__make} ")
1270         gsub("^%makeinstall_std", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1271         gsub("^%{makeinstall}", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1272         gsub("^%makeinstall", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1273         gsub("^%{__rm} -rf %{buildroot}", "rm -rf $RPM_BUILD_ROOT")
1274         gsub("^%{__install}", "install")
1275         gsub("^%{__rm}", "rm")
1276         gsub("%optflags", "%{rpmcflags}")
1277         gsub("%{compat_perl_vendorarch}", "%{perl_vendorarch}")
1278
1279         gsub("^%{__make} install DESTDIR=\$RPM_BUILD_ROOT", "%{__make} install \\\n\tDESTDIR=$RPM_BUILD_ROOT")
1280         gsub("^fix-info-dir$", "[ ! -x /usr/sbin/fix-info-dir ] || /usr/sbin/fix-info-dir -c %{_infodir} >/dev/null 2>\&1")
1281         $0 = fixedsub("%buildroot", "$RPM_BUILD_ROOT", $0)
1282         $0 = fixedsub("%{buildroot}", "$RPM_BUILD_ROOT", $0)
1283         $0 = fixedsub("CXXFLAGS=%{rpmcflags} %configure", "CXXFLAGS=%{rpmcflags}\n%configure", $0);
1284
1285         # split configure line to multiple lines
1286         if (/%configure / && !/\\$/) {
1287                 $0 = format_configure($0);
1288         }
1289
1290         gsub("%_bindir", "%{_bindir}")
1291         gsub("%_datadir", "%{_datadir}")
1292         gsub("%_iconsdir", "%{_iconsdir}")
1293         gsub("%_sbindir", "%{_sbindir}")
1294         gsub("%_mandir", "%{_mandir}")
1295         gsub("%name", "%{name}")
1296     gsub(/%__rm/, "rm");
1297     gsub(/%__mkdir_p/, "install -d");
1298     gsub(/%__cp/, "cp");
1299     gsub(/%__ln_s/, "ln -s");
1300     gsub(/%__sed/, "%{__sed}");
1301     gsub(/%__cat/, "cat");
1302     gsub(/%__chmod/, "chmod");
1303
1304         gsub("/usr/src/linux", "%{_kernelsrcdir}")
1305         gsub("%{_prefix}/src/linux", "%{_kernelsrcdir}")
1306
1307         if (/^ant /) {
1308                 sub(/^ant/, "%ant")
1309         add_br("BuildRequires:  jpackage-utils");
1310         add_br("BuildRequires:  rpmbuild(macros) >= 1.294");
1311     }
1312
1313 }
1314
1315 function format_configure(line,         n, a, s) {
1316         n = split(line, a, / /);
1317         s = a[1] " \\\n";
1318         for (i = 2; i <= n; i++) {
1319                 s = s "\t" a[i] " \\\n"
1320         }
1321         return s
1322 }
1323
1324
1325 # insertion sort of A[1..n]
1326 # copied from mawk manual
1327 function isort(A,n,             i,j,hold) {
1328         for (i = 2; i <= n; i++) {
1329                 hold = A[j = i]
1330                 while (A[j-1] > hold) {
1331                         j-- ; A[j+1] = A[j]
1332                 }
1333                 A[j] = hold
1334         }
1335         # sentinel A[0] = "" will be created if needed
1336 }
1337
1338
1339 function use_files_macros(      i, n, t, a)
1340 {
1341         use_macros()
1342
1343         # skip comments
1344         if (/^#/) {
1345                 return;
1346         }
1347
1348         sub("^%doc %{_mandir}", "%{_mandir}")
1349
1350         gsub("^%{_sbindir}", "%attr(755,root,root) %{_sbindir}")
1351         gsub("^%{_bindir}", "%attr(755,root,root) %{_bindir}")
1352
1353         # uid/gid nobody is not valid in %files
1354         if (/%attr([^)]*nobody[^)]*)/ && !/FIXME/) {
1355                 $0 = $0 " # FIXME nobody user/group can't own files! -adapter.awk"
1356         }
1357
1358         # s[gu]id programs with globs are evil
1359         if (/%attr\([246]...,.*\*/ && !/FIXME/) {
1360                 $0 = $0 " # FIXME no globs for suid/sgid files"
1361         }
1362
1363         # replace back
1364         gsub("%{_sysconfdir}/cron\.d", "/etc/cron.d")
1365         gsub("%{_sysconfdir}/crontab\.d", "/etc/crontab.d")
1366         gsub("%{_sysconfdir}/logrotate\.d", "/etc/logrotate.d")
1367         gsub("%{_sysconfdir}/pam\.d", "/etc/pam.d")
1368         gsub("%{_sysconfdir}/profile\.d", "/etc/profile.d")
1369         gsub("%{_sysconfdir}/rc\.d", "/etc/rc.d")
1370         gsub("%{_sysconfdir}/security", "/etc/security")
1371         gsub("%{_sysconfdir}/skel", "/etc/skel")
1372         gsub("%{_sysconfdir}/sysconfig", "/etc/sysconfig")
1373         gsub("%{_sysconfdir}/certs", "/etc/certs")
1374         gsub("%{_sysconfdir}/init.d", "/etc/init.d")
1375
1376         # /etc/init.d -> /etc/rc.d/init.d
1377         if (!/^\/etc\/init\.d$/) {
1378                  gsub("/etc/init.d", "/etc/rc.d/init.d")
1379         }
1380
1381         if (/\/etc\/rc\.d\/init\.d\// && !/functions/) {
1382                 if (!/%attr.*\/etc\/rc\.d\/init\.d/) {
1383                         $0 = "%attr(754,root,root) " $0
1384                 }
1385                 if (/^%attr.*\/etc\/rc\.d\/init\.d/ && !/^%attr\(754 *,/) {
1386                         gsub("^%attr\\(... *,", "%attr(754,");
1387                 }
1388         }
1389
1390         if (/lib.+\.so/ && !/\.so$/ && !/^%attr.*/ && !/%exclude/) {
1391                 $0 = "%attr(755,root,root) " $0
1392         }
1393
1394         if (/%{perl_vendorarch}.*\.so$/ && !/^%attr.*/) {
1395                 $0 = "%attr(755,root,root) " $0
1396         }
1397
1398         # /etc/sysconfig files
1399         # %attr(640,root,root) %config(noreplace) %verify(not size mtime md5) /etc/sysconfig/*
1400         # attr not required, allow default 644 attr
1401         if (!/network-scripts/ && !/%dir/ && !/\.d$/ && !/functions/ && !/\/etc\/sysconfig\/wmstyle/) {
1402                 if (/\/etc\/sysconfig\// && /%config/ && !/%config\(noreplace/) {
1403                         gsub("%config", "%config(noreplace)")
1404                 }
1405
1406                 if (/\/etc\/sysconfig\// && !/%config\(noreplace/) {
1407                         $NF = "%config(noreplace) " $NF
1408                 }
1409
1410                 if (/\/etc\/sysconfig\// && /%attr\(755/) {
1411                         gsub("^%attr\\(... *,", "%attr(640,");
1412                 }
1413
1414                 if (/\/etc\/sysconfig\// && !/%verify/) {
1415                         gsub("/etc/sysconfig", "%verify(not size mtime md5) /etc/sysconfig");
1416                 }
1417         }
1418
1419         # kill leading zeros
1420         if (/%attr\(0[1-9]/) {
1421                 gsub("%attr\\(0", "%attr(")
1422         }
1423
1424     # kill default attrs
1425     gsub(/%dir %attr\(755,root,root\)/, "%dir");
1426     if (!/%dir/) {
1427         gsub(/%attr\(644,root,root\) /, "");
1428     }
1429
1430         # sort %verify attrs
1431         if (match($0, /%verify\(not([^)]+)\)/)) {
1432                 t = substr($0, RSTART, RLENGTH)
1433                 # kill commas: %verify(not,md5,size,mtime)
1434                 gsub(/,/, " ", t);
1435
1436                 gsub(/^%verify\(not |\)$/, "", t)
1437                 n = split(t, a, / /)
1438                 isort(a, n)
1439
1440                 s = "%verify(not"
1441                 for (i = 1 ; i <= n; i++) {
1442                         s = s " " a[i]
1443                 }
1444                 s = s ")"
1445
1446                 gsub(/%verify\(not[^)]+\)/, s)
1447         }
1448
1449         if (/%{_mandir}/) {
1450                 gsub("\.gz$", "*")
1451         }
1452
1453         # locale dir and no %lang -> bad
1454         if (/%{_datadir}\/locale\/.*\// && !/%(dir|lang)/) {
1455                 $(NF + 1) = "# FIXME consider using %find_lang"
1456         }
1457
1458         # atrpms
1459         $0 = fixedsub("%{perl_man1dir}", "%{_mandir}/man1", $0);
1460         $0 = fixedsub("%{perl_man3dir}", "%{_mandir}/man3", $0);
1461         $0 = fixedsub("%{perl_bin}", "%{_bindir}", $0);
1462
1463         gsub(libdir "/pkgconfig", "%{_pkgconfigdir}");
1464         gsub("%{_libdir}/pkgconfig", "%{_pkgconfigdir}");
1465         gsub("%{_prefix}/lib/pkgconfig", "%{_pkgconfigdir}");
1466
1467         gsub("%{_datadir}/applications", "%{_desktopdir}");
1468         gsub("%{_datadir}/icons", "%{_iconsdir}");
1469         gsub("%{_datadir}/pixmaps", "%{_pixmapsdir}");
1470 }
1471
1472 function use_script_macros()
1473 {
1474         if (gsub("/sbin/service", "%service")) {
1475                 sub(" >/dev/null 2>&1 \|\|:", "");
1476                 sub(" 2> /dev/null \|\| :", "");
1477         }
1478 }
1479
1480 function fill(ch, n, i) {
1481         for (i = 0; i < n; i++)
1482                 printf("%c", ch)
1483 }
1484
1485 function format_flush(line, indent, newline, word, first_word) {
1486         first_word = 1
1487         if (format_indent == -1)
1488                 newline = ""
1489         else
1490                 newline = fill(" ", format_indent) "- "
1491
1492         while (match(line, /[^\t ]+/)) {
1493                 word = substr(line, RSTART, RLENGTH)
1494                 if (length(newline) + length(word) + 1 > tw) {
1495                         print newline
1496
1497                         if (format_indent == -1)
1498                                 newline = ""
1499                         else
1500                                 newline = fill(" ", format_indent + 2)
1501                         first_word = 1
1502                 }
1503
1504                 if (first_word) {
1505                         newline = newline word
1506                         first_word = 0
1507                 } else
1508                         newline = newline " " word
1509
1510                 line = substr(line, RSTART + RLENGTH)
1511         }
1512         if (newline ~ /[^\t ]/) {
1513                 print newline
1514         }
1515 }
1516
1517 function cflags(var)
1518 {
1519         if ($0 == var "=\"$RPM_OPT_FLAGS\"") {
1520                 removed[var] = 1
1521                 return 0
1522         }
1523
1524         if (!/!\?debug/)
1525                 sub("\$RPM_OPT_FLAGS", "%{rpmcflags}")
1526         return 1
1527 }
1528
1529 function demacroize(str)
1530 {
1531         if (mod_name) {
1532                 sub("%{mod_name}", mod_name, str);
1533         }
1534         if (name) {
1535                 sub("%{name}", name, str);
1536         }
1537         if (version) {
1538                 sub("%{version}", version, str);
1539         }
1540         if (_beta) {
1541                 sub("%{_beta}", _beta, str);
1542         }
1543         if (_rc) {
1544                 sub("%{_rc}", _rc, str);
1545         }
1546         if (_pre) {
1547                 sub("%{_pre}", _pre, str);
1548         }
1549         if (_snap) {
1550                 sub("%{_snap}", _snap, str);
1551         }
1552         return str;
1553 }
1554
1555 function kill_preamble_macros()
1556 {
1557         if ($1 ~ /^URL:/ || $1 ~ /^Obsoletes:/) {
1558                 # NB! assigning $2 a value breaks tabbing
1559                 $2 = demacroize($2);
1560                 # unify sourceforge url
1561                 sub("\.sf\.net/$", ".sourceforge.net/", $2);
1562         }
1563 }
1564
1565 function get_epoch(pkg, ver,    epoch)
1566 {
1567         return
1568 # should parse the BR lines more adequately:
1569 #       freetype = 2.0.0 -> correct
1570 #       freetype = 2.1.9 -> with epoch 1, as epoch 1 was added in 2.1.7
1571
1572         shell = "grep -o '^" pkg ":[^:]\+' ../PLD-doc/BuildRequires.txt | awk '{print $NF}'";
1573         shell | getline epoch;
1574         return epoch;
1575 }
1576
1577 function format_requires(tag, value,    n, p, i, deps, ndeps) {
1578         # skip any formatting for commented out items or some weird macros
1579         if (/^#/ || /%\(/) {
1580                 return tag "\t" value
1581         }
1582         n = split(value, p, / *,? */);
1583         for (i = 1; i <= n; i++) {
1584                 if (p[i+1] ~ /[<=>]/) {
1585                         # add epoch if the version doesn't have it but BuildRequires.txt has
1586                         if (p[i] ~ /^[a-z]/ && p[i+2] !~ /^[0-9]+:/) {
1587                                 epoch = get_epoch(p[i], p[i+2])
1588                                 if (epoch) {
1589                                         p[i+2] = epoch ":" p[i+2];
1590                                 }
1591                         }
1592                         deps[ndeps++] = p[i] " " p[i+1] " " p[i+2];
1593                         i += 2;
1594                 } else {
1595                         deps[ndeps++] = p[i];
1596                 }
1597         }
1598         s = ""
1599         for (i in deps) {
1600                 s = s sprintf("%s\t%s\n", tag, deps[i]);
1601         }
1602         return substr(s, 1, length(s)-1);
1603 }
1604
1605 function use_tabs()
1606 {
1607         # reverse vim: ts=4 sw=4 et
1608         gsub(/    /, "\t");
1609 }
1610
1611 function add_br(br)
1612 {
1613     BR[BR_count++] = br
1614 }
1615
1616 # php virtual deps as discussed in devel-en
1617 function replace_php_virtual_deps()
1618 {
1619     pkg = $2
1620 #    if (pkg == "php-program") {
1621 #        $0 = $1 "\t/usr/bin/php"
1622 #        return
1623 #    }
1624
1625     if (pkg ~ /^php-/ && pkg !~ /^php-(pear|common|cli|devel|fcgi|cgi|dirs|program|ZendOptimizer|pecl-)/) {
1626         sub(/^php-/, "php(", pkg);
1627         sub(/$/, ")", pkg);
1628         $2 = pkg
1629     }
1630
1631     if (pkg ~/^php$/) {
1632         $2 = "webserver(php)";
1633         if ($4 ~ /^[0-9]:/) {
1634             $4 = substr($4, 3);
1635         }
1636     }
1637
1638     if (pkg ~/^php4$/) {
1639         $2 = "webserver(php)";
1640         if ($4 ~ /^[0-9]:/) {
1641             $4 = substr($4, 3);
1642         }
1643     }
1644 }
1645
1646 # vim:ts=4:sw=4:et