pldnotify.awk

   1 #!/bin/awk -f
   2 #
   3 # Copyright (C) 2000-2013 PLD-Team <feedback@pld-linux.org>
   4 # Authors:
   5 #       Sebastian Zagrodzki <zagrodzki@pld-linux.org>
   6 #       Jacek Konieczny <jajcus@pld-linux.org>
   7 #       Andrzej Krzysztofowicz <ankry@pld-linux.org>
   8 #       Jakub Bogusz <qboosh@pld-linux.org>
   9 #       Elan Ruusamäe <glen@pld-linux.org>
  10 #
  11 # See cvs log pldnotify.awk for list of contributors
  12 #
  13 # TODO:
  14 # - "SourceXDownload" support (use given URLs if present instead of cut-down SourceX URLs)
  15 # - "SourceXActiveFTP" support
  16 # - support debian/watch http://wiki.debian.org/debian/watch/
  17
  18 # NOTE:
  19 # to test run this, run:
  20 # $ awk -vDEBUG=1 pldnotify.awk < specfile
  21 #
  22 # To get full out of it, you need to have following tools installed:
  23 # - perl, sed, wget, coreutils, util-linux
  24 # - perl-HTML-Tree (HTML::TreeBuilder module) for better links parser (-vUSE_PERL=0 to disable)
  25 # - pear (php-pear-PEAR) for php-pear package updates
  26 # - npm for nodejs packages
  27 # - gem (ruby-rubygems) for ruby/rubygem packages
  28 #
  29 # Additionally "mirrors" file in current dir, controls local mirrors you prefer
  30
  31 function d(s) {
  32         if (!DEBUG) {
  33                 return
  34         }
  35
  36 #       print strftime("%Y-%m-%d %H:%M:%S ") s >> "/dev/stderr"
  37         print s >> "/dev/stderr"
  38 }
  39
  40 function fixedsub(s1,s2,t,      ind) {
  41 # substitutes fixed strings (not regexps)
  42         if (ind = index(t,s1)) {
  43                 t = substr(t, 1, ind-1) s2 substr(t, ind+length(s1))
  44         }
  45         return t
  46 }
  47
  48 function ispre(s) {
  49         if ((s~"pre")||(s~"PRE")||(s~"beta")||(s~"BETA")||(s~"alpha")||(s~"ALPHA")||(s~"rc")||(s~"RC")) {
  50                 d("pre-version")
  51                 return 1
  52         } else {
  53                 return 0
  54         }
  55 }
  56
  57 function compare_ver(v1,v2) {
  58 # compares version numbers
  59         while (match(v1,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  60                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
  61         while (match(v2,/[a-zA-Z][0-9]|[0-9][a-zA-Z]/))
  62                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
  63         sub("^0*","",v1)
  64         sub("^0*","",v2)
  65         gsub("\.0*",".",v1)
  66         gsub("\.0*",".",v2)
  67         d("v1 == " v1)
  68         d("v2 == " v2)
  69         count=split(v1,v1a,"\.")
  70         count2=split(v2,v2a,"\.")
  71
  72         if (count<count2) mincount=count
  73         else mincount=count2
  74
  75         for (i=1; i<=mincount; i++) {
  76                 if (v1a[i]=="") v1a[i]=0
  77                 if (v2a[i]=="") v2a[i]=0
  78                 d("i == " i)
  79                 d("v1[i] == " v1a[i])
  80                 d("v2[i] == " v2a[i])
  81                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
  82                         if (length(v2a[i])>length(v1a[i]))
  83                                 return 1
  84                         else if (v2a[i]>v1a[i])
  85                                 return 1
  86                         else if (length(v1a[i])>length(v2a[i]))
  87                                 return 0
  88                         else if (v1a[i]>v2a[i])
  89                                 return 0
  90                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
  91                         if (v2a[i]>v1a[i])
  92                                 return 1
  93                         else if (v1a[i]>v2a[i])
  94                                 return 0
  95                 } else if (ispre(v1a[i]) == 1)
  96                         return 1
  97                 else
  98                         return 0
  99         }
 100         if ((count2==mincount)&&(count!=count2)) {
 101                 for (i=count2+1; i<=count; i++)
 102                         if (ispre(v1a[i]) == 1)
 103                                 return 1
 104                 return 0
 105         } else if (count!=count2) {
 106                 for (i=count+1; i<=count2; i++)
 107                         if (ispre(v2a[i]) == 1)
 108                                 return 0
 109                 return 1
 110         }
 111         return 0
 112 }
 113
 114 function compare_ver_dec(v1,v2) {
 115 # compares version numbers as decimal floats
 116         while (match(v1,/[0-9][a-zA-Z]/))
 117                 v1=(substr(v1,1,RSTART) "." substr(v1,RSTART+RLENGTH-1))
 118         while (match(v2,/[0-9][a-zA-Z]/))
 119                 v2=(substr(v2,1,RSTART) "." substr(v2,RSTART+RLENGTH-1))
 120         sub("^0*","",v1)
 121         sub("^0*","",v2)
 122         d("v1 == " v1)
 123         d("v2 == " v2)
 124         count=split(v1,v1a,"\.")
 125         count2=split(v2,v2a,"\.")
 126
 127         if (count<count2) mincount=count
 128         else mincount=count2
 129
 130         for (i=1; i<=mincount; i++) {
 131                 if (v1a[i]=="") v1a[i]=0
 132                 if (v2a[i]=="") v2a[i]=0
 133                 d("i == " i)
 134                 d("v1[i] == " v1a[i])
 135                 d("v2[i] == " v2a[i])
 136                 if ((v1a[i]~/[0-9]/)&&(v2a[i]~/[0-9]/)) {
 137                         if (i==2) {
 138                                 if (0+("." v2a[i])>0+("." v1a[i]))
 139                                         return 1
 140                                 else if (0+("." v1a[i])>0+("." v2a[i]))
 141                                         return 0
 142                         } else {
 143                                 if (length(v2a[i])>length(v1a[i]))
 144                                         return 1
 145                                 else if (v2a[i]>v1a[i])
 146                                         return 1
 147                                 else if (length(v1a[i])>length(v2a[i]))
 148                                         return 0
 149                                 else if (v1a[i]>v2a[i])
 150                                         return 0
 151                         }
 152                 } else if ((v1a[i]~/[A-Za-z]/)&&(v2a[i]~/[A-Za-z]/)) {
 153                         if (v2a[i]>v1a[i])
 154                                 return 1
 155                         else if (v1a[i]>v2a[i])
 156                                 return 0
 157                 } else if (ispre(v1a[i]) == 1)
 158                         return 1
 159                 else
 160                         return 0
 161         }
 162         if ((count2==mincount)&&(count!=count2)) {
 163                 for (i=count2+1; i<=count; i++)
 164                         if (ispre(v1a[i]) == 1)
 165                                 return 1
 166                 return 0
 167         } else if (count!=count2) {
 168                 for (i=count+1; i<=count2; i++)
 169                         if (ispre(v2a[i]) == 1)
 170                                 return 0
 171                 return 1
 172         }
 173         return 0
 174 }
 175
 176 function link_seen(link) {
 177         for (seenlink in frameseen) {
 178                 if (seenlink == link) {
 179                         d("Link: [" link "] seen already, skipping...")
 180                         return 1
 181                 }
 182         }
 183         frameseen[link]=1
 184         return 0
 185 }
 186
 187 function mktemp(   _cmd, _tmpfile) {
 188         _cmd = "mktemp /tmp/XXXXXX"
 189         _cmd | getline _tmpfile
 190         close(_cmd)
 191         return _tmpfile
 192 }
 193
 194 # fix link to artificial one that will be recognized rest of this script
 195 function postfix_link(url, link,   oldlink) {
 196         oldlink = link
 197         if ((url ~/^(http|https):\/\/github.com\//) && (link ~ /.*\/tarball\//)) {
 198                 gsub(".*\/tarball\/", "", link)
 199                 link = link ".tar.gz"
 200         }
 201         if (oldlink != link) {
 202                 d("POST FIXED URL [ " oldlink " ] to [ " link " ]")
 203         }
 204         return link
 205 }
 206
 207 # use perl HTML::TreeBuilder module to extract links from html
 208 # it returns TAGNAME LINK in output which is pretty stright forward to parse in awk
 209 function extract_links_cmd(tmpfile) {
 210         return "perl -MHTML::TreeBuilder -e ' \
 211         my $content = join q//, <>; \
 212         my $root = new HTML::TreeBuilder; \
 213         $root->parse($content); \
 214         \
 215         my %links = (); \
 216         for (@{$root->extract_links(qw(a iframe))}) { \
 217                 my($link, $element, $attr, $tag) = @$_; \
 218                 $links{$link} = $tag; \
 219         } \
 220         \
 221         while (my($link, $tag) = each %links) { \
 222                 print $tag, q/ /, $link, $/; \
 223         } \
 224         ' " tmpfile
 225 }
 226
 227 # get all <A HREF=..> tags from specified URL
 228 function get_links(url,filename,   errno,link,oneline,retval,odp,wholeodp,lowerodp,tmpfile,cmd) {
 229
 230         wholeerr=""
 231
 232         tmpfile = mktemp()
 233         tmpfileerr = mktemp()
 234
 235         if (url ~ /^http:\/\/(download|dl)\.(sf|sourceforge)\.net\//) {
 236                 # http://downloads.sourceforge.net/project/mediainfo/source/mediainfo/
 237                 gsub("^http://(download|dl)\.(sf|sourceforge)\.net/", "", url)
 238
 239                 gsub("/.*", "", url)
 240                 url = "http://sourceforge.net/projects/" url "/files/"
 241                 d("sf url, mungled url to: " url)
 242         }
 243
 244         if (url ~ /^http:\/\/(.*)\.googlecode\.com\/files\//) {
 245                 gsub("^http://", "", url)
 246                 gsub("\..*", "", url)
 247                 url = "http://code.google.com/p/" url "/downloads/list"
 248                 d("googlecode url, mungled url to: " url)
 249         }
 250
 251         if (url ~ /^http:\/\/pecl.php.net\/get\//) {
 252                 gsub("-.*", "", filename)
 253                 url = "http://pecl.php.net/package/" filename
 254                 d("pecl.php.net url, mungled url to: " url)
 255         }
 256
 257         if (url ~ /^(http|ftp):\/\/mysql.*\/Downloads\/MySQL-5.1\//) {
 258                 url = "http://dev.mysql.com/downloads/mysql/5.1.html#source"
 259                  d("mysql 5.1 url, mungled url to: " url)
 260         }
 261
 262         if (url ~/^(http|https):\/\/launchpad\.net\/(.*)\//) {
 263                 gsub("^(http|https):\/\/launchpad\.net\/", "", url)
 264                 gsub("\/.*/", "", url)
 265                 url = "https://code.launchpad.net/" url "/+download"
 266                 d("main launchpad url, mungled url to: " url)
 267         }
 268
 269         if (url ~/^(http|https):\/\/edge\.launchpad\.net\/(.*)\//) {
 270                 gsub("^(http|https):\/\/edge\.launchpad\.net\/", "", url)
 271                 gsub("\/.*/", "", url)
 272                 url = "https://edge.launchpad.net/" url "/+download"
 273                 d("edge launchpad url, mungled url to: " url)
 274         }
 275
 276         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/tarball\//) {
 277                 gsub("\/tarball\/.*", "/downloads", url)
 278                 d("github tarball url, mungled url to: " url)
 279         }
 280
 281         if (url ~/^(http|https):\/\/github.com\/.*\/(.*)\/archive\//) {
 282                 gsub("\/archive\/.*", "/tags", url)
 283                 d("github archive url, mungled url to: " url)
 284         }
 285
 286         # https://bitbucket.org/logilab/pylint/get/tip.tar.bz2 -> https://bitbucket.org/logilab/pylint/downloads
 287         if (url ~/^(http|https):\/\/bitbucket.org\/.*\/get\/.*/) {
 288                 gsub("\/get\/.*", "/downloads", url)
 289                 d("github bitbucket url, mungled url to: " url)
 290         }
 291
 292         if (url ~/^(http|https):\/\/cgit\..*\/(.*)\/snapshot\//) {
 293                 gsub("\/snapshot\/.*", "/", url)
 294                 d("cgit snapshot tarball url, mungled url to: " url)
 295         }
 296
 297         if (url ~/^(http|https):\/\/www2\.aquamaniac\.de\/sites\/download\//) {
 298                 url = "http://www2.aquamaniac.de/sites/download/packages.php"
 299                 d("aquamaniac.de tarball url, mungled url to: " url)
 300         }
 301
 302         if (url ~/^(http|https):\/\/www.process-one.net\/downloads\/ejabberd\//) {
 303                 url = "http://www.process-one.net/en/ejabberd/archive/"
 304                 d("ejabberd tarball url, mungled url to: " url)
 305         }
 306
 307         if (url ~/^(http|https):\/\/llvm.org\/releases\//) {
 308                 url = "http://llvm.org/releases/download.html"
 309                 d("llvm tarball url, mungled url to: " url)
 310         }
 311
 312         if (url ~/^(http|https):\/\/download\.owncloud\.org\/community\//) {
 313                 url = "http://owncloud.org/changelog/"
 314                 d("owncloud tarball url, mungled url to: " url)
 315         }
 316
 317         d("Retrieving: " url)
 318         user_agent = "Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.9.2) Gecko/20100129 PLD/3.0 (Th) Iceweasel/3.6"
 319         cmd = "wget -t 2 -T 45 --user-agent \"" user_agent "\" -nv -O - \"" url "\" --passive-ftp --no-check-certificate > " tmpfile " 2> " tmpfileerr
 320         d("Execute: " cmd)
 321         errno = system(cmd)
 322         d("Execute done")
 323
 324         if (errno != 0) {
 325                 d("Reading failure response...")
 326                 wholeerr = ""
 327                 while (getline oneline < tmpfileerr)
 328                         wholeerr = (wholeerr " " oneline)
 329                 d("Error Response: " wholeerr)
 330
 331                 system("rm -f " tmpfile)
 332                 system("rm -f " tmpfileerr)
 333                 retval = ("WGET ERROR: " errno ": " wholeerr)
 334                 return retval
 335         }
 336         system("rm -f " tmpfileerr)
 337
 338         urldir = url;
 339         sub(/[^\/]+$/, "", urldir)
 340
 341 if (USE_PERL) {
 342         cmd = extract_links_cmd(tmpfile)
 343         while (cmd | getline) {
 344                 tag = $1
 345                 link = substr($0, length(tag) + 2)
 346
 347                 if (tag == "iframe") {
 348                         d("Frame: " link)
 349                         if (url !~ /\//) {
 350                                 link = (urldir link)
 351                                 d("Frame->: " link)
 352                         }
 353
 354                         if (link_seen(link)) {
 355                                 continue
 356                         }
 357                         retval = (retval " " get_links(link))
 358                 }
 359
 360                 if (link_seen(link)) {
 361                         continue
 362                 }
 363
 364                 retval = (retval " " link)
 365                 d("href(): " link)
 366         }
 367         close(cmd)
 368         system("rm -f " tmpfile)
 369
 370         d("Returning: [" retval "]")
 371         return retval
 372 }
 373
 374         wholeodp = ""
 375         d("Reading success response...")
 376         while (getline oneline < tmpfile) {
 377                 wholeodp = (wholeodp " " oneline)
 378 #               d("Response: " wholeodp)
 379         }
 380         d("Reponse read done...")
 381         system("rm -f " tmpfile)
 382
 383         while (match(wholeodp, /<([aA]|[fF][rR][aA][mM][eE])[ \t][^>]*>/) > 0) {
 384                 d("Processing links...")
 385                 odp = substr(wholeodp,RSTART,RLENGTH);
 386                 wholeodp = substr(wholeodp,RSTART+RLENGTH);
 387
 388                 lowerodp = tolower(odp);
 389                 if (lowerodp ~ /<frame[ \t]/) {
 390                         sub(/[sS][rR][cC]=[ \t]*/, "src=", odp);
 391                         match(odp, /src="[^"]+"/)
 392                         newurl = substr(odp, RSTART+5, RLENGTH-6)
 393                         d("Frame: " newurl)
 394                         if (newurl !~ /\//) {
 395                                 newurl=(urldir newurl)
 396                                 d("Frame->: " newurl)
 397                         }
 398
 399                         if (link_seen(newurl)) {
 400                                 newurl = ""
 401                                 continue
 402                         }
 403
 404                         retval = (retval " " get_links(newurl))
 405                 } else if (lowerodp ~ /href=[ \t]*"[^"]*"/) {
 406                         sub(/[hH][rR][eE][fF]=[ \t]*"/,"href=\"",odp)
 407                         match(odp,/href="[^"]*"/)
 408                         link=substr(odp,RSTART,RLENGTH)
 409                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 410                         link=substr(link,7,length(link)-7)
 411                         link=postfix_link(url, link)
 412
 413                         if (link_seen(link)) {
 414                                 link=""
 415                                 continue
 416                         }
 417
 418                         # link ends with at least 2 digit version
 419                         mlink = ""
 420                         if (link ~ /^.*\/[v]*[0-9\.]+[0-9]\/$/)
 421                                 mlink = get_links(link)
 422
 423                         retval = (retval " " link " " mlink)
 424                         d("href(\"\"): " link)
 425                 } else if (lowerodp ~ /href=[ \t]*'[^']*'/) {
 426                         sub(/[hH][rR][eE][fF]=[ \t]*'/,"href='",odp)
 427                         match(odp,/href='[^']*'/)
 428                         link=substr(odp,RSTART,RLENGTH)
 429                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 430                         link=substr(link,7,length(link)-7)
 431                         link=postfix_link(url, link)
 432
 433                         if (link_seen(link)) {
 434                                 link=""
 435                                 continue
 436                         }
 437
 438                         retval = (retval " " link)
 439                         d("href(''): " link)
 440                 } else if (lowerodp ~ /href=[ \t]*[^ \t>]*/) {
 441                         sub(/[hH][rR][eE][fF]=[ \t]*/,"href=",odp)
 442                         match(odp,/href=[^ \t>]*/)
 443                         link=substr(odp,RSTART,RLENGTH)
 444                         odp=substr(odp,1,RSTART) substr(odp,RSTART+RLENGTH)
 445                         link=substr(link,6,length(link)-5)
 446
 447                         if (link_seen(link)) {
 448                                 link=""
 449                                 continue
 450                         }
 451
 452                         retval = (retval " " link)
 453                         d("href(): " link)
 454                 } else {
 455                         # <a ...> but not href - skip
 456                         d("skipping <a > without href: " odp)
 457                 }
 458         }
 459
 460         d("Returning: [" retval "]")
 461         return retval
 462 }
 463
 464 function subst_defines(var,defs) {
 465 # substitute all possible RPM macros
 466         while ((var ~ /%{.*}/) || (var ~ /%[A-Za-z0-9_]+/)) {
 467                 oldvar=var
 468                 for (j in defs) {
 469                         gsub("%{" j "}", defs[j], var)
 470                         gsub("%" j , defs[j], var)
 471                 }
 472                 if (var==oldvar) {
 473                         if (DEBUG) {
 474                                 for (i in defs) {
 475                                         d(i " == " defs[i])
 476                                 }
 477                         }
 478                         return var
 479                 }
 480         }
 481         return var
 482 }
 483
 484 function find_mirror(url) {
 485
 486         while (succ = (getline line < "mirrors")) {
 487             if (succ==-1) { return url }
 488                 nf=split(line,fields,"|")
 489                 if (nf>1){
 490                         origin=fields[1]
 491                         mirror=fields[2]
 492                         mname=fields[3]
 493                         prefix=substr(url,1,length(origin))
 494                         if (prefix==origin){
 495                                 d("Mirror found at " mname)
 496                                 close("mirrors")
 497                                 return mirror substr(url,length(origin)+1)
 498                         }
 499                 }
 500         }
 501
 502         return url
 503 }
 504
 505 # fetches file list, and compares version numbers
 506 function process_source(number, lurl, name, version) {
 507         d("Processing " lurl)
 508
 509         if (index(lurl, version) == 0) {
 510                 d("There is no version number ["version"] in ["lurl"]")
 511                 return 0
 512         }
 513
 514         sub("://",":",lurl)
 515         sub("/",":/",lurl)
 516         gsub("[^/]*$",":&",lurl)
 517         split(lurl,url,":")
 518         acc=url[1]
 519         host=url[2]
 520         dir=url[3]
 521         filename=url[4]
 522
 523         if (index(dir,version)) {
 524                 # directory name as version maching mode:
 525                 # if /something/version/name-version.tarball then check
 526                 # in /something/ looking for newer directory
 527                 dir=substr(dir,1,index(dir,version)-1)
 528                 sub("[^/]*$","",dir)
 529                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",filename)
 530         }
 531
 532         d("Will check a directory: " dir)
 533         d("and a file: " filename)
 534
 535         filenameexp=filename
 536         gsub("[+]","\\+",filenameexp)
 537         sub(version,"[A-Za-z0-9.]+",filenameexp)
 538         gsub("[.]","\\.",filenameexp)
 539         sub("\.(bz|bz2|gz|lzma|xz|zip)$",".(bz|bz2|gz|lzma|xz|zip)",filenameexp)
 540         d("Expression: " filenameexp)
 541         match(filename,version)
 542         prever=substr(filename,1,RSTART-1)
 543         postver=substr(filename,RSTART+RLENGTH)
 544         d("Before number: " prever)
 545         d("and after: " postver)
 546         newurl=find_mirror(acc "://" host dir)
 547         #print acc "://" host dir
 548         #newurl=url[1]"://"url[2]url[3]url[4]
 549         #newurl=acc "://" host dir filename
 550         d("Looking at " newurl)
 551
 552         references=0
 553         finished=0
 554         oldversion=version
 555         odp = get_links(newurl, filename)
 556         if( odp ~ "ERROR: ") {
 557                 print name "(" number ") " odp
 558         } else {
 559                 d("WebPage downloaded")
 560                 c=split(odp,linki)
 561                 for (nr=1; nr<=c; nr++) {
 562                         addr=linki[nr]
 563
 564                         d("Found link: " addr)
 565
 566                         # github has very different tarball links that clash with this safe check
 567                         if (!(newurl ~/^(http|https):\/\/github.com\/.*\/tarball/)) {
 568                                 if (addr ~ "[-_.0-9A-Za-z~]" filenameexp) {
 569                                         continue
 570                                 }
 571                         }
 572
 573                         if (addr ~ filenameexp) {
 574                                 match(addr,filenameexp)
 575                                 newfilename=substr(addr,RSTART,RLENGTH)
 576                                 d("Hypothetical new: " newfilename)
 577                                 newfilename=fixedsub(prever,"",newfilename)
 578                                 newfilename=fixedsub(postver,"",newfilename)
 579                                 d("Version: " newfilename)
 580                                 if (newfilename ~ /\.(asc|sig|pkg|bin|binary|built)$/) continue
 581                                 # strip ending (happens when in directiory name as version matching mode)
 582                                 sub("(\.tar\.(bz|bz2|gz|lzma|xz)|zip)$","",newfilename)
 583                                 if (NUMERIC) {
 584                                         if ( compare_ver_dec(version, newfilename)==1 ) {
 585                                                 d("Yes, there is new one")
 586                                                 version=newfilename
 587                                                 finished=1
 588                                         }
 589                                 } else if ( compare_ver(version, newfilename)==1 ) {
 590                                         d("Yes, there is new one")
 591                                         version=newfilename
 592                                         finished=1
 593                                 }
 594                         }
 595                 }
 596                 if (finished == 0)
 597                         print name "(" number ") seems ok: " oldversion
 598                 else
 599                         print name "(" number ") [OLD] " oldversion " [NEW] " version
 600         }
 601 }
 602
 603 function rss_upgrade(name, ver, url, regex, cmd) {
 604         regex = "s/.*<title>" regex "<\/title>.*/\\1/p"
 605         cmd = "wget -t 2 -T 45 -q -O - " url " | sed -nre '" regex "' | head -n1"
 606
 607         d("rss_upgrade_cmd: " cmd)
 608         cmd | getline ver
 609         close(cmd)
 610
 611         return ver
 612 }
 613
 614 # check for ZF upgrade from rss
 615 function zf_upgrade(name, ver) {
 616         return rss_upgrade(name, ver, \
 617                 "http://devzone.zend.com/tag/Zend_Framework_Management/format/rss2.0", \
 618                 "Zend Framework ([^\\s]+) Released" \
 619         );
 620 }
 621
 622 function hudson_upgrade(name, ver) {
 623         return rss_upgrade(name, ver, \
 624                 "https://hudson.dev.java.net/servlets/ProjectRSS?type=news", \
 625                 "Hudson ([0-9.]+) released" \
 626         );
 627 }
 628
 629 # upgrade check for pear package using PEAR CLI
 630 function pear_upgrade(name, ver,    cmd) {
 631         sub(/^php-pear-/, "", name);
 632
 633         cmd = "pear remote-info " name " | awk '/^Latest/{print $NF}'"
 634         d("PEAR: " cmd)
 635         cmd | getline ver
 636         close(cmd)
 637
 638         return ver
 639 }
 640
 641 function vim_upgrade(name, ver,     cmd) {
 642         # %patchset_source -f ftp://ftp.vim.org/pub/editors/vim/patches/7.2/7.2.%03g 1 %{patchlevel}
 643         cmd = "wget -q -O - ftp://ftp.vim.org/pub/editors/vim/patches/" DEFS["ver"] "/MD5SUMS|grep -vF .gz|tail -n1|awk '{print $2}'"
 644         d("VIM: " cmd)
 645         cmd | getline ver
 646         close(cmd)
 647         return ver
 648 }
 649
 650 function nodejs_upgrade(name, ver,   cmd) {
 651         d("NODEJS " name " (as " DEFS["pkg"] ") " ver);
 652         if (DEFS["pkg"]) {
 653                 cmd = "npm info " DEFS["pkg"] " dist-tags.latest"
 654         } else {
 655                 cmd = "npm info " name " dist-tags.latest"
 656         }
 657         cmd | getline ver
 658         close(cmd)
 659
 660         return ver
 661 }
 662
 663 function rubygem_upgrade(name, ver,   cmd, pkg) {
 664         if (DEFS["gem_name"]) {
 665                 pkg = DEFS["gem_name"];
 666
 667         } else if (DEFS["gemname"]) {
 668                 pkg = DEFS["gemname"];
 669
 670         } else if (DEFS["pkgname"]) {
 671                 pkg = DEFS["pkgname"];
 672
 673         } else {
 674                 pkg = name;
 675                 gsub(/^ruby-/, "", pkg);
 676         }
 677
 678         cmd = "gem list --remote '^" pkg "$' | awk '/" pkg "/ {v=$2; sub(/\(/, \"\", v); print v}'"
 679         d("RUBYGEM " name " (as " pkg ") " ver ": " cmd);
 680         cmd | getline ver
 681
 682         close(cmd)
 683
 684         return ver
 685 }
 686
 687 function chrome_upgrade(name, ver,   cmd, sourceurl) {
 688         sourceurl = "http://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/primary.xml.gz"
 689         cmd = "curl -s " sourceurl " | zcat | perl -ne 'm{<name>google-chrome-" DEFS["state"] "</name>} and m{<version .*ver=.([\d.]+)} and print $1'"
 690         d("CHROME " cmd);
 691         cmd | getline ver
 692         close(cmd)
 693
 694         return ver
 695 }
 696
 697 function process_data(name, ver, rel, src,   nver) {
 698         if (name ~ /^php-pear-/) {
 699                 nver = pear_upgrade(name, ver);
 700         } else if (name == "ZendFramework") {
 701                 nver = zf_upgrade(name, ver);
 702         } else if (name == "hudson") {
 703                 nver = hudson_upgrade(name, ver);
 704         } else if (name == "vim") {
 705                 nver = vim_upgrade(name, ver);
 706         } else if (name == "google-chrome") {
 707                 nver = chrome_upgrade(name, ver);
 708         } else if (name ~ "^nodejs-") {
 709                 nver = nodejs_upgrade(name, ver);
 710         } else if (name ~ "^ruby-") {
 711                 nver = rubygem_upgrade(name, ver);
 712         }
 713
 714         if (nver) {
 715                 if (compare_ver(ver, nver)) {
 716                         print name " [OLD] " ver " [NEW] " nver
 717                 } else {
 718                         print name " seems ok: " ver
 719                 }
 720                 return;
 721         }
 722
 723         if (name == "xulrunner") {
 724                 ver = subst_defines(DEFS["firefox_ver"], DEFS)
 725                 d("package xulrunner, change version to firefox ["ver"]")
 726         }
 727
 728 # this function checks if substitutions were valid, and if true:
 729 # processes each URL and tries to get current file list
 730         for (i in src) {
 731                 if (src[i] ~ /%{nil}/) {
 732                         gsub(/\%\{nil\}/, "", src[i])
 733                 }
 734                 if ( src[i] !~ /%{.*}/ && src[i] !~ /%[A-Za-z0-9_]/ )  {
 735                         d("Source: " src[i])
 736                         process_source(i, src[i], name, ver)
 737                 } else {
 738                         print FNAME ":" i ": impossible substitution: " src[i]
 739                 }
 740         }
 741 }
 742
 743 BEGIN {
 744         # if you want to use DEBUG, run script with "-v DEBUG=1"
 745         # or uncomment the line below
 746         # DEBUG = 1
 747
 748         errno=system("wget --help > /dev/null 2>&1")
 749         if (errno && errno != 3) {
 750                 print "No wget installed!"
 751                 exit 1
 752         }
 753         if (ARGC>=3 && ARGV[2]=="-n") {
 754                 NUMERIC=1
 755                 for (i=3; i<ARGC; i++) ARGV[i-1]=ARGV[i]
 756                 ARGC=ARGC-1
 757         }
 758 }
 759
 760 FNR==1 {
 761         if ( ARGIND != 1 ) {
 762                 # clean frameseen for each ARG
 763                 for (i in frameseen) {
 764                         delete frameseen[i]
 765                 }
 766                 frameseen[0] = 1
 767
 768                 process_data(NAME,VER,REL,SRC)
 769                 NAME="" ; VER="" ; REL=""
 770                 for (i in DEFS) delete DEFS[i]
 771                 for (i in SRC) delete SRC[i]
 772         }
 773         FNAME=FILENAME
 774         DEFS["_alt_kernel"]=""
 775         DEFS["20"]="\\ "
 776         DEFS["nil"]=""
 777 }
 778
 779 /^[Uu][Rr][Ll]:/&&(URL=="") { URL=subst_defines($2,DEFS) ; DEFS["url"]=URL }
 780 /^[Nn]ame:/&&(NAME=="") { NAME=subst_defines($2,DEFS) ; DEFS["name"]=NAME }
 781 /^[Vv]ersion:/&&(VER=="") { VER=subst_defines($2,DEFS) ; DEFS["version"]=VER }
 782 /^[Rr]elease:/&&(REL=="") { REL=subst_defines($2,DEFS) ; DEFS["release"]=REL }
 783 /^[Ss]ource[0-9]*:/ { if (/(ftp|http|https):\/\//) SRC[FNR]=subst_defines($2,DEFS) }
 784 /%define/ { DEFS[$2]=subst_defines($3,DEFS) }
 785
 786 END {
 787         process_data(NAME,VER,REL,SRC)
 788 }