--- exiv2-0.17.1/acinclude.m4.orig	1970-01-01 01:00:00.000000000 +0100
+++ exiv2-0.17.1/acinclude.m4	2008-07-21 13:52:55.923794430 +0200
@@ -0,0 +1,90 @@
+dnl @synopsis CHECK_ZLIB()
+dnl
+dnl This macro searches for an installed zlib library. If nothing
+dnl was specified when calling configure, it searches first in /usr/local
+dnl and then in /usr. If the --with-zlib=DIR is specified, it will try
+dnl to find it in DIR/include/zlib.h and DIR/lib/libz.a. If --without-zlib
+dnl is specified, the library is not searched at all.
+dnl
+dnl If either the header file (zlib.h) or the library (libz) is not
+dnl found, the configuration exits on error, asking for a valid
+dnl zlib installation directory or --without-zlib.
+dnl
+dnl The macro defines the symbol HAVE_LIBZ if the library is found. You should
+dnl use autoheader to include a definition for this symbol in a config.h
+dnl file. Sample usage in a C/C++ source is as follows:
+dnl
+dnl   #ifdef HAVE_LIBZ
+dnl   #include <zlib.h>
+dnl   #endif /* HAVE_LIBZ */
+dnl
+dnl @version $Id$
+dnl @author Loic Dachary <loic@senga.org>
+dnl with modifications by Andreas Huggel <ahuggel@gmx.net>
+dnl
+AC_DEFUN([CHECK_ZLIB],
+#
+# Handle user hints
+#
+[AC_MSG_CHECKING(if zlib is wanted)
+AC_ARG_WITH(zlib,
+[  --with-zlib=DIR root directory path of zlib installation [defaults to
+		    /usr/local or /usr if not found in /usr/local]
+  --without-zlib to disable zlib usage completely],
+[if test "$withval" != no ; then
+  AC_MSG_RESULT(yes)
+  ZLIB_HOME="$withval"
+else
+  AC_MSG_RESULT(no)
+fi], [
+AC_MSG_RESULT(yes)
+ZLIB_HOME=/usr/local
+if test ! -f "${ZLIB_HOME}/include/zlib.h"
+then
+	ZLIB_HOME=/usr
+fi
+])
+#
+# Locate zlib, if wanted
+#
+if test -n "${ZLIB_HOME}"
+then
+	ZLIB_OLD_LDFLAGS=$LDFLAGS
+	ZLIB_OLD_CPPFLAGS=$CPPFLAGS
+	#
+	# Adding /usr/lib or /usr/include to the flags/libs may
+	# hurt if using a compiler not installed in the standard 
+	# place.
+	#
+        if test "${ZLIB_HOME}" != "/usr"
+	then
+		LDFLAGS="$LDFLAGS -L${ZLIB_HOME}/lib"
+		CPPFLAGS="$CPPFLAGS -I${ZLIB_HOME}/include"
+	fi
+        AC_LANG_SAVE
+        AC_LANG_C
+	AC_CHECK_LIB(z, inflateEnd, [zlib_cv_libz=yes], [zlib_cv_libz=no])
+        AC_CHECK_HEADER(zlib.h, [zlib_cv_zlib_h=yes], [zlib_cv_zlib_h=no])
+        AC_LANG_RESTORE
+	if test "$zlib_cv_libz" = "yes" -a "$zlib_cv_zlib_h" = "yes"
+	then
+		#
+		# If both library and header were found, use them
+		#
+		AC_CHECK_LIB(z, inflateEnd)
+		AC_MSG_CHECKING(zlib in ${ZLIB_HOME})
+		AC_MSG_RESULT(ok)
+		HAVE_LIBZ=1
+	else
+		#
+		# If either header or library was not found, revert and bomb
+		#
+		AC_MSG_CHECKING(zlib in ${ZLIB_HOME})
+		LDFLAGS="$ZLIB_OLD_LDFLAGS"
+		CPPFLAGS="$ZLIB_OLD_CPPFLAGS"
+		AC_MSG_RESULT(failed)
+		AC_MSG_ERROR(either specify a valid zlib installation with --with-zlib=DIR or disable zlib usage with --without-zlib)
+	fi
+fi
+
+])