spec.vim

   1 " Filename:    spec.vim
   2 " Purpose:     Vim syntax file
   3 " Language:    SPEC: Build/install scripts for Linux RPM packages
   4 " Maintainer:  Donovan Rebbechi elflord@pegasus.rutgers.edu
   5 " URL:         http://pegasus.rutgers.edu/~elflord/vim/syntax/spec.vim
   6 " Last Change: Tue Oct  3 17:35:15 BRST 2000 <aurelio@conectiva.com.br>
   7
   8 " For version 5.x: Clear all syntax items
   9 " For version 6.x: Quit when a syntax file was already loaded
  10 if version < 600
  11   syntax clear
  12 elseif exists("b:current_syntax")
  13   finish
  14 endif
  15
  16 syn sync minlines=1000
  17
  18 syn match specSpecialChar contained '[][!$()\\|>^;:]'
  19 syn match specColon       contained ':'
  20 syn match specPercent     contained '%'
  21
  22 syn match specVariables   contained '\$\h\w*' contains=specSpecialVariablesNames,specSpecialChar
  23 syn match specVariables   contained '\${\w*}' contains=specSpecialVariablesNames,specSpecialChar
  24
  25 syn match specMacroIdentifier contained '%\h\w*' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  26 "syn match specMacroIdentifier contained '%{\w*}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  27 syn region specMacroIdentifier oneline matchgroup=Special start='%{' skip='\\}' end='}' contains=specMacroNameLocal,specMacroNameOther,specPercent,specSpecialChar
  28 syn match specBcond contained '%{with\(out\)\?\s\+[a-zA-Z0-9_-]\+}'
  29
  30 syn match specSpecialVariables contained '\$[0-9]\|\${[0-9]}'
  31 syn match specCommandOpts      contained '\s\(-\w\+\|--\w[a-zA-Z0-9_-]\+\)'ms=s+1
  32 syn match specComment '^\s*#.*$'
  33
  34
  35 syn case match
  36
  37
  38 " matches with no highlight
  39 syn match specNoNumberHilite 'X11\|X11R6\|[a-zA-Z]*\.\d\|[a-zA-Z][-/]\d'
  40 syn match specManpageFile '[a-zA-Z]\.1'
  41
  42 " Day, Month and most used license acronyms
  43 syn keyword specLicense contained GPL LGPL BSD MIT GNU Apache PHP
  44 syn keyword specWeekday contained Mon Tue Wed Thu Fri Sat Sun
  45 syn keyword specMonth   contained Jan Feb Mar Apr Jun Jul Aug Sep Oct Nov Dec
  46 syn keyword specMonth   contained January February March April May June July August September October November December
  47
  48 " #, @, www
  49 syn match specNumber '\(^-\=\|[ \t]-\=\|-\)[0-9.-]*[0-9]'
  50 syn match specEmail contained "<\=\<[A-Za-z0-9_.-]\+@\([A-Za-z0-9_-]\+\.\)\+[A-Za-z]\+\>>\="
  51 syn match specURL      contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#?=-]\+\>'
  52 syn match specURLMacro contained '\<\(\(https\{0,1}\|ftp\)://\|\(www[23]\{0,1}\.\|ftp\.\)\)[A-Za-z0-9._/~:,#%{}-]\+\>' contains=specMacroIdentifier
  53
  54 " TODO take specSpecialVariables out of the cluster for the sh* contains (ALLBUT)
  55 " Special system directories
  56 syn match specListedFilesPrefix contained '/\(usr\|local\|opt\|X11R6\|X11\)/'me=e-1
  57 syn match specListedFilesBin    contained '/s\=bin/'me=e-1
  58 syn match specListedFilesLib    contained '/\(lib\|include\)/'me=e-1
  59 syn match specListedFilesDoc    contained '/\(man\d*\|doc\|info\)\>'
  60 syn match specListedFilesEtc    contained '/etc/'me=e-1
  61 syn match specListedFilesShare  contained '/share/'me=e-1
  62 syn cluster specListedFiles contains=specListedFilesBin,specListedFilesLib,specListedFilesDoc,specListedFilesEtc,specListedFilesShare,specListedFilesPrefix,specVariables,specSpecialChar
  63
  64 " specComands
  65 syn match   specConfigure  contained '\./configure'
  66 syn match   specTarCommand contained '\<tar\s\+[cxvpzjf]\{,5}\s*'
  67
  68 " XXX don't forget to update specScriptArea when updating specMacro
  69 syn match   specMacro contained '%\(group\|user\)\(add\|remove\)'
  70 syn match   specMacro contained '%\(depmod\|banner\|service\|addusertogroup\)'
  71 syn match   specMacro contained '%\(\(nsplugin\|apache_config\)_\(un\)\?install\)'
  72 syn match   specMacro contained '%\(webapp_\(un\)\?register\)'
  73 syn match   specMacro contained '%\(pear_package_\(setup\|install\)\)'
  74 syn match   specMacro contained '%\(py_o\?comp\|py_postclean\)'
  75
  76 syn keyword specCommandSpecial contained root
  77 syn keyword specCommand         contained make xmkmf mkdir chmod find sed rm strip moc echo grep ls rm mv mkdir chown install cp pwd cat tail then else elif cd gzip rmdir ln eval export touch unzip bzip2
  78 syn cluster specCommands contains=specCommand,specTarCommand,specConfigure,specCommandSpecial,specMacro
  79
  80 " frequently used rpm env vars
  81 syn keyword specSpecialVariablesNames contained RPM_BUILD_ROOT RPM_BUILD_DIR RPM_SOURCE_DIR RPM_OPT_FLAGS LDFLAGS CC CC_FLAGS CPPNAME CFLAGS CXX CXXFLAGS CPPFLAGS
  82
  83 " valid macro names from /usr/lib/rpm/macros
  84 syn keyword specMacroNameOther contained buildroot buildsubdir distribution disturl ix86 name nil optflags perl_sitearch release requires_eq vendor version
  85 syn keyword specMacroNameOther contained __kernel_ver date debugcflags debuginfocflags epoch kgcc kgcc_package packager
  86 syn keyword specMacroNameOther contained pear_package_install pear_package_setup perl_archlib perl_privlib perl_sitelib
  87 syn keyword specMacroNameOther contained perl_vendorarch perl_vendorlib php_pear_dir py_sitedir py_scriptdir py_sitescriptdir releq_kernel_smp
  88 syn keyword specMacroNameOther contained releq_kernel_up requires_php_extension requires_releq_kernel_smp requires_releq_kernel_up
  89 syn keyword specMacroNameOther contained requires_zend_extension ruby_mod_ver_requires_eq rpmcflags rpmcxxflags rpmldflags tmpdir x8664
  90 syn keyword specMacroNameOther contained ruby_archdir ruby_rubylibdir ruby_ridir ruby_sitearchdir ruby_sitelibdir ruby_version
  91 syn keyword specMacroNameOther contained apache_modules_api
  92
  93 syn match   specMacroNameOther contained '\<\(PATCH\|SOURCE\)\d*\>'
  94
  95 " valid _macro names from /usr/lib/rpm/macros
  96 syn keyword specMacroNameLocal contained _aclocaldir _applnkdir _arch _binary_payload _bindir _build _build_arch _build_alias
  97 syn keyword specMacroNameLocal contained _build_cpu _builddir _build_os _buildshell _buildsubdir _build_vendor _bzip2bin _datadir
  98 syn keyword specMacroNameLocal contained _dbpath _dbpath_rebuild _defaultdocdir _desktopdir _docdir _examplesdir _excludedocs _kdedocdir
  99 syn keyword specMacroNameLocal contained _exec_prefix _fixgroup _fixowner _fixperms _fontsdir _ftpport _ftpproxy _gnu _gpg_name
 100 syn keyword specMacroNameLocal contained _gpg_path _gtkdocdir _gzipbin _host _host_alias _host_cpu _host_os _host_vendor
 101 syn keyword specMacroNameLocal contained _httpport _httpproxy _iconsdir _includedir _infodir _initrddir _install_langs
 102 syn keyword specMacroNameLocal contained _install_script_path _instchangelog _javaclasspath _javadir _javadocdir _kernelsrcdir
 103 syn keyword specMacroNameLocal contained _kernel_ver _kernel_ver_str _langpatt _lib _libdir _libexecdir _localstatedir _mandir
 104 syn keyword specMacroNameLocal contained _netsharedpath _oldincludedir _omf_dest_dir _os _package_version _pgpbin _pgp_name
 105 syn keyword specMacroNameLocal contained _pgp_path _pixmapsdir _pkgconfigdir _prefix _preScriptEnvironment _provides _rpmdir
 106 syn keyword specMacroNameLocal contained _rpmfilename _sbindir _sharedstatedir _signature _smp_mflags _sourcedir _source_payload
 107 syn keyword specMacroNameLocal contained _specdir _srcrpmdir _sysconfdir _target _target_alias _target_cpu _target_os _target_platform
 108 syn keyword specMacroNameLocal contained _target_vendor _target_base_arch _timecheck _tmppath _topdir _usr _usrsrc _var _vendor
 109 syn keyword specMacroNameLocal contained __cxx __cc __libtoolize __autopoint __aclocal __autoconf __automake __autoheader
 110 syn keyword specMacroNameLocal contained __gettextize __glib_gettextize __intltoolize
 111 syn keyword specMacroNameLocal contained __bzip2 __cat __chgrp __chmod __chown __cp   __cpio __file __gpg __grep __gzip
 112 syn keyword specMacroNameLocal contained __id  __install __ld   __make   __mkdir __mkdir_p __mv __nm  __objcopy __objdump
 113 syn keyword specMacroNameLocal contained __patch __perl __pgp __python __rm __rsh  __sed __ssh __strip  __tar __unzip
 114
 115
 116
 117 " ------------------------------------------------------------------------------
 118 " here's is all the spec sections definitions: PreAmble, Description, Package,
 119 "   Scripts, Files and Changelog
 120
 121 " One line macros - valid in all ScriptAreas
 122 " tip: remember do include new items on specScriptArea's skip section
 123 syn region specSectionMacroArea oneline matchgroup=specSectionMacro start='^%\(\(un\)\?define\|dump\|trace\|patch\d*\|setup\|configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\|bcond_with\(out\)\?\|include\)\>' end='$' contains=specCommandOpts,specMacroIdentifier,specSectionMacroBcondArea
 124 syn region specSectionMacroBracketArea oneline matchgroup=specSectionMacro start='^%{\(configure2_13\|configure\|GNUconfigure\|find_lang\|makeinstall\|cmake\)}' end='$' contains=specCommandOpts,specMacroIdentifier
 125 syn region specSectionMacroBcondArea oneline matchgroup=specBlock start='%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):' skip='\\}' end='}' contains=ALLBUT,shCase
 126
 127 " %% Files Section %%
 128 " TODO %config valid parameters: missingok\|noreplace
 129 " TODO %verify valid parameters: \(not\)\= \(md5\|atime\|...\)
 130 syn region specFilesArea matchgroup=specSection start='^%[Ff][Ii][Ll][Ee][Ss]\>'
 131         \ skip='%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\|if\|else\|endif\)\>'
 132         \ end='^%[a-zA-Z]'me=e-2
 133         \ contains=specFilesOpts,specFilesDirective,@specListedFiles,specComment,specCommandSpecial,specMacroIdentifier,specSectionMacroBcondArea,specIf
 134
 135 " tip: remember to include new items in specFilesArea above
 136 syn match  specFilesDirective contained '%\(attrib\|defattr\|attr\|dir\|config\|docdir\|doc\|lang\|verify\|ghost\|exclude\|dev\)\>'
 137
 138 " valid options for certain section headers
 139 syn match specDescriptionOpts contained '\s-[ln]\s*\a'ms=s+1,me=e-1
 140 syn match specPackageOpts     contained    '\s-n\s*\w'ms=s+1,me=e-1
 141 syn match specFilesOpts       contained    '\s-f\s*\w'ms=s+1,me=e-1
 142
 143
 144 syn case ignore
 145
 146
 147 " %% PreAmble Section %%
 148 " Copyright and Serial were deprecated by License and Epoch
 149 " PreReq and BuildPreReq deprecated by Requires ans BuildRequires
 150 syn region specPreAmbleDeprecated oneline matchgroup=specError start='^\(Copyright\|Serial\|PreReq\|BuildPreReq\(uires\)\?\)' end='$' contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier
 151 syn region specPreAmble oneline matchgroup=specCommand
 152         \ start='\(^\|\(^%{!\??\(with\(out\)\?_[a-zA-Z0-9_]\+\|debug\):\)\@<=\)\(Summary\|Name\|Version\|Packager\|Requires\|Icon\|URL\|Source\d*\|Patch\d*\|Prefix\|Packager\|Group\|License\|Release\|BuildRoot\|Distribution\|Vendor\|Provides\|ExclusiveArch\|ExcludeArch\|ExclusiveOS\|Obsoletes\|BuildArch\|BuildArchitectures\|BuildRequires\|BuildConflicts\|Conflicts\|AutoRequires\|AutoReqProv\|AutoReq\|AutoProv\|Epoch\|NoSource\)'
 153         \ end='$\|}\@='
 154         \ contains=specEmail,specURL,specURLMacro,specLicense,specColon,specVariables,specSpecialChar,specMacroIdentifier,specSectionMacroBcondArea
 155
 156 " %% Description Section %%
 157 syn region specDescriptionArea matchgroup=specSection start='^%description' end='^%'me=e-1
 158         \ contains=specDescriptionOpts,specEmail,specURL,specNumber,specMacroIdentifier,specComment
 159
 160 " %% Package Section %%
 161 syn region specPackageArea matchgroup=specSection start='^%package' end='^%'me=e-1
 162         \ contains=specPackageOpts,specPreAmble,specComment,specMacroNameOther
 163
 164 " %% Scripts Section %%
 165 syn region specScriptArea matchgroup=specSection
 166         \ start='^%\(prep\|build\|install\|clean\|pre\|postun\|preun\|post\|triggerin\|triggerun\|triggerpostun\|pretrans\|posttrans\|verifyscript\|check\)\>'
 167         \ skip='^%{\|^%\(define\|patch\d*\|configure2_13\|configure\|GNUconfigure\|setup\|find_lang\|makeinstall\|cmake\|useradd\|groupadd\|addusertogroup\|banner\|service\|py_o\?comp\|py_postclean\|\(\(nsplugin\|apache_config\)_\(un\)\?install\)\|webapp_\(un\)\?register\|depmod\|pear_package_\(setup\|install\)\)\>'
 168         \ end='^%'me=e-1
 169         \ contains=specSpecialVariables,specVariables,@specCommands,specVariables,shDo,shFor,shCaseEsac,specNoNumberHilite,specCommandOpts,shComment,shIf,specSpecialChar,specMacroIdentifier,specSectionMacroArea,specSectionMacroBracketArea,shOperator,shQuote1,shQuote2,specSectionMacroBcondArea
 170 " XXX don't forget to update specMacro when updating specScriptArea skip definition
 171
 172 " %% Changelog Section %%
 173 syn region specChangelogArea matchgroup=specSection start='^%changelog' end='^%'me=e-1
 174         \ contains=specEmail,specURL,specWeekday,specMonth,specNumber,specComment,specLicense,specRevision,specLogMessage,specLogError
 175
 176 syn match specRevision contained "^Revision [.0-9]\+  [/0-9]\+ [:0-9]\+  [a-zA-Z0-9]\+$"
 177 syn region specLogMessage contained start="^[- ] " end="$" contains=specLogError,specURL,specEmail
 178 syn match specLogError contained "%%"
 179
 180 " ------------------------------------------------------------------------------
 181 " here's the shell syntax for all the Script Sections
 182
 183
 184 syn case match
 185
 186
 187 " sh-like comment style, only valid in script part
 188 syn match shComment contained '#.*$'
 189
 190 syn region shQuote1 contained matchgroup=shQuoteDelim start=+'+ skip=+\\'+ end=+'+ contains=specMacroIdentifier
 191 syn region shQuote2 contained matchgroup=shQuoteDelim start=+"+ skip=+\\"+ end=+"+ contains=specVariables,specMacroIdentifier,specSectionMacroBcondArea
 192
 193 syn match shOperator contained '[><|!&;]\|[!=]='
 194 syn region shDo transparent matchgroup=specBlock start="\<do\>" end="\<done\>" contains=ALLBUT,shFunction,shDoError,shCase,specPreAmble,@specListedFiles
 195
 196 syn region specIf  matchgroup=specBlock start="%ifosf\|%ifos\|%ifnos\|%ifarch\|%ifnarch\|ifdef\|ifndef\|%if\|%else"  end='%endif'  contains=ALLBUT, specIfError, shCase, shComment
 197
 198 syn region shIf transparent matchgroup=specBlock start="\<if\>" end="\<fi\>" contains=ALLBUT,shFunction,shIfError,shCase,@specListedFiles
 199
 200 syn region shFor  matchgroup=specBlock start="\<for\>" end="\<in\>" contains=ALLBUT,shFunction,shInError,shCase,@specListedFiles
 201
 202 syn region shCaseEsac transparent matchgroup=specBlock start="\<case\>" matchgroup=NONE end="\<in\>"me=s-1 contains=ALLBUT,shFunction,shCaseError,@specListedFiles nextgroup=shCaseEsac
 203 syn region shCaseEsac matchgroup=specBlock start="\<in\>" end="\<esac\>" contains=ALLBUT,shFunction,shCaseError,@specListedFilesBin
 204 syn region shCase matchgroup=specBlock contained start=")"  end=";;" contains=ALLBUT,shFunction,shCaseError,shCase,@specListedFiles
 205
 206 syn sync match shDoSync       grouphere  shDo       "\<do\>"
 207 syn sync match shDoSync       groupthere shDo       "\<done\>"
 208 syn sync match shIfSync       grouphere  shIf       "\<if\>"
 209 syn sync match shIfSync       groupthere shIf       "\<fi\>"
 210 syn sync match specIfSync     grouphere  specIf     "%ifarch\|%ifos\|%ifnos"
 211 syn sync match specIfSync     groupthere specIf     "%endIf"
 212 syn sync match shForSync      grouphere  shFor      "\<for\>"
 213 syn sync match shForSync      groupthere shFor      "\<in\>"
 214 syn sync match shCaseEsacSync grouphere  shCaseEsac "\<case\>"
 215 syn sync match shCaseEsacSync groupthere shCaseEsac "\<esac\>"
 216
 217 " Define the default highlighting.
 218 " For version 5.7 and earlier: only when not done already
 219 " For version 5.8 and later: only when an item doesn't have highlighting yet
 220 if version >= 508 || !exists("did_spec_syntax_inits")
 221   if version < 508
 222     let did_spec_syntax_inits = 1
 223     command -nargs=+ HiLink hi link <args>
 224   else
 225     command -nargs=+ HiLink hi def link <args>
 226   endif
 227
 228   "main types color definitions
 229   HiLink specSection                    Structure
 230   HiLink specSectionMacro               Macro
 231   HiLink specWWWlink                    PreProc
 232   HiLink specOpts                       Operator
 233
 234   "yes, it's ugly, but white is sooo cool
 235   if &background == "dark"
 236     hi def specGlobalMacro              ctermfg=white
 237   else
 238     HiLink specGlobalMacro              Identifier
 239   endif
 240
 241   "sh colors
 242   HiLink shComment                      Comment
 243   HiLink shIf                           Statement
 244   HiLink shOperator                     Special
 245   HiLink shQuote1                       String
 246   HiLink shQuote2                       String
 247   HiLink shQuoteDelim                   Statement
 248
 249   " spec colors
 250   HiLink specBlock                      Function
 251   HiLink specBcond                      Function
 252   HiLink specColon                      Special
 253   HiLink specCommand                    Statement
 254   HiLink specCommandOpts                specOpts
 255   HiLink specCommandSpecial             Special
 256   HiLink specComment                    Comment
 257   HiLink specConfigure                  specCommand
 258   HiLink specDate                       String
 259   HiLink specDescriptionOpts            specOpts
 260   HiLink specEmail                      specWWWlink
 261   HiLink specError                      Error
 262   HiLink specFilesDirective             specSectionMacro
 263   HiLink specFilesOpts                  specOpts
 264   HiLink specLicense                    String
 265   HiLink specMacroNameLocal             specGlobalMacro
 266   HiLink specMacroNameOther             specGlobalMacro
 267   HiLink specManpageFile                NONE
 268   HiLink specMonth                      specDate
 269   HiLink specNoNumberHilite             NONE
 270   HiLink specNumber                     Number
 271   HiLink specPackageOpts                specOpts
 272   HiLink specPercent                    Special
 273   HiLink specSpecialChar                Special
 274   HiLink specSpecialVariables           specGlobalMacro
 275   HiLink specSpecialVariablesNames      specGlobalMacro
 276   HiLink specTarCommand                 specCommand
 277   HiLink specMacro                      Macro
 278   HiLink specURL                        specWWWlink
 279   HiLink specURLMacro                   specWWWlink
 280   HiLink specVariables                  Identifier
 281   HiLink specWeekday                    specDate
 282   HiLink specListedFilesBin             Statement
 283   HiLink specListedFilesDoc             Statement
 284   HiLink specListedFilesEtc             Statement
 285   HiLink specListedFilesLib             Statement
 286   HiLink specListedFilesPrefix          Statement
 287   HiLink specListedFilesShare           Statement
 288
 289   HiLink specRevision                   Number
 290   HiLink specLogMessage                 Identifier
 291   HiLink specLogError                   Error
 292
 293   delcommand HiLink
 294 endif
 295
 296 let b:current_syntax = "spec"
 297
 298 " vim: ts=8